basis/xmode/loader/syntax/syntax.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors xmode.tokens xmode.rules xmode.keyword-map
   4 xml.data xml.traversal xml assocs kernel combinators sequences
   5 math.parser namespaces make parser lexer xmode.utilities
   6 parser-combinators.regexp io.files splitting arrays ;
   7 IN: xmode.loader.syntax
   8
   9 ! Rule tag parsing utilities
  10 : (parse-rule-tag) ( rule-set tag specs class -- )
  11     new swap init-from-tag swap add-rule ; inline
  12
  13 : RULE:
  14     scan scan-word
  15     parse-definition { } make
  16     swap [ (parse-rule-tag) ] 2curry (TAG:) ; parsing
  17
  18 ! Attribute utilities
  19 : string>boolean ( string -- ? ) "TRUE" = ;
  20
  21 : string>match-type ( string -- obj )
  22     {
  23         { "RULE" [ f ] }
  24         { "CONTEXT" [ t ] }
  25         [ string>token ]
  26     } case ;
  27
  28 : string>rule-set-name ( string -- name ) "MAIN" or ;
  29
  30 ! PROP, PROPS
  31 : parse-prop-tag ( tag -- key value )
  32     [ "NAME" attr ] [ "VALUE" attr ] bi ;
  33
  34 : parse-props-tag ( tag -- assoc )
  35     child-tags
  36     [ parse-prop-tag ] H{ } map>assoc ;
  37
  38 : position-attrs ( tag -- at-line-start? at-whitespace-end? at-word-start? )
  39     ! XXX Wrong logic!
  40     { "AT_LINE_START" "AT_WHITESPACE_END" "AT_WORD_START" }
  41     [ attr string>boolean ] with map first3 ;
  42
  43 : parse-literal-matcher ( tag -- matcher )
  44     dup children>string
  45     rule-set get ignore-case?>> <string-matcher>
  46     swap position-attrs <matcher> ;
  47
  48 : parse-regexp-matcher ( tag -- matcher )
  49     dup children>string rule-set get ignore-case?>> <regexp>
  50     swap position-attrs <matcher> ;
  51
  52 : shared-tag-attrs ( -- )
  53     { "TYPE" string>token (>>body-token) } , ; inline
  54
  55 : parse-delegate ( string -- pair )
  56     "::" split1 [ rule-set get swap ] unless* 2array ;
  57
  58 : delegate-attr ( -- )
  59     { "DELEGATE" f (>>delegate) } , ;
  60
  61 : regexp-attr ( -- )
  62     { "HASH_CHAR" f (>>chars) } , ;
  63
  64 : match-type-attr ( -- )
  65     { "MATCH_TYPE" string>match-type (>>match-token) } , ;
  66
  67 : span-attrs ( -- )
  68     { "NO_LINE_BREAK" string>boolean (>>no-line-break?) } ,
  69     { "NO_WORD_BREAK" string>boolean (>>no-word-break?) } ,
  70     { "NO_ESCAPE" string>boolean (>>no-escape?) } , ;
  71
  72 : literal-start ( -- )
  73     [ parse-literal-matcher >>start drop ] , ;
  74
  75 : regexp-start ( -- )
  76     [ parse-regexp-matcher >>start drop ] , ;
  77
  78 : literal-end ( -- )
  79     [ parse-literal-matcher >>end drop ] , ;
  80
  81 ! SPAN's children
  82 <TAGS: parse-begin/end-tag ( rule tag -- )
  83
  84 TAG: BEGIN
  85     ! XXX
  86     parse-literal-matcher >>start drop ;
  87
  88 TAG: END
  89     ! XXX
  90     parse-literal-matcher >>end drop ;
  91
  92 TAGS>
  93
  94 : parse-begin/end-tags ( -- )
  95     [
  96         ! XXX: handle position attrs on span tag itself
  97         child-tags [ parse-begin/end-tag ] with each
  98     ] , ;
  99
 100 : init-span-tag ( -- ) [ drop init-span ] , ;
 101
 102 : init-eol-span-tag ( -- ) [ drop init-eol-span ] , ;
 103
 104 : parse-keyword-tag ( tag keyword-map -- )
 105     [ dup main>> string>token swap children>string ] dip set-at ;