core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays byte-vectors arrays init ;
   5 IN: alien
   6
   7 PREDICATE: pinned-alien < alien underlying>> not ;
   8
   9 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  10
  11 GENERIC: element-size ( seq -- n ) flushable
  12
  13 M: byte-array element-size drop 1 ; inline
  14
  15 M: byte-vector element-size drop 1 ; inline
  16
  17 M: slice element-size seq>> element-size ; inline
  18
  19 M: f element-size drop 1 ; inline
  20
  21 GENERIC: byte-length ( obj -- n ) flushable
  22
  23 M: object byte-length [ length ] [ element-size ] bi * ; inline
  24
  25 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  26
  27 M: c-ptr >c-ptr ; inline
  28
  29 M: slice >c-ptr
  30     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  31     <displaced-alien> ; inline
  32
  33 SLOT: underlying
  34
  35 M: object >c-ptr underlying>> ; inline
  36
  37 : binary-object ( obj -- c-ptr n )
  38     [ >c-ptr ] [ byte-length ] bi ; inline
  39
  40 GENERIC: expired? ( c-ptr -- ? ) flushable
  41
  42 M: alien expired? expired>> ;
  43
  44 M: f expired? drop t ;
  45
  46 : <alien> ( address -- alien )
  47     f <displaced-alien> { pinned-c-ptr } declare ; inline
  48
  49 : <bad-alien> ( -- alien )
  50     -1 <alien> t >>expired ; inline
  51
  52 M: alien equal?
  53     over alien? [
  54         2dup [ expired? ] either? [
  55             [ expired? ] both?
  56         ] [
  57             [ alien-address ] bi@ =
  58         ] if
  59     ] [
  60         2drop f
  61     ] if ;
  62
  63 M: pinned-alien hashcode*
  64     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  65
  66 ERROR: alien-callback-error ;
  67
  68 : alien-callback ( return parameters abi quot -- alien )
  69     alien-callback-error ;
  70
  71 ERROR: alien-indirect-error ;
  72
  73 : alien-indirect ( ... funcptr return parameters abi -- ... )
  74     alien-indirect-error ;
  75
  76 ERROR: alien-invoke-error library symbol ;
  77
  78 : alien-invoke ( ... return library function parameters -- ... )
  79     2over alien-invoke-error ;
  80
  81 ERROR: alien-assembly-error code ;
  82
  83 : alien-assembly ( ... return parameters abi quot -- ... )
  84     dup alien-assembly-error ;
  85
  86 ! Callbacks are registered in a global hashtable. Note that they
  87 ! are also pinned in a special callback area, so clearing this
  88 ! hashtable will not reclaim callbacks. It should only be
  89 ! cleared on startup.
  90 SYMBOL: callbacks
  91
  92 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
  93
  94 <PRIVATE
  95
  96 TUPLE: expiry-check object alien ;
  97
  98 : recompute-value? ( check -- ? )
  99     dup [ alien>> expired? ] [ drop t ] if ;
 100
 101 PRIVATE>
 102
 103 : initialize-alien ( symbol quot -- )
 104     swap dup get-global dup recompute-value?
 105     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 106     [ 2nip object>> ] if ; inline