core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs byte-arrays byte-vectors continuations
   4 continuations.private kernel kernel.private math namespaces
   5 sequences ;
   6 USE: init ! required but does not reference words
   7 IN: alien
   8
   9 BUILTIN: alien { underlying c-ptr read-only initial: f } expired ;
  10 BUILTIN: dll { path byte-array read-only initial: B{ } } ;
  11
  12 PRIMITIVE: <callback> ( word return-rewind -- alien )
  13 PRIMITIVE: <displaced-alien> ( displacement c-ptr -- alien )
  14 PRIMITIVE: alien-address ( c-ptr -- addr )
  15 PRIMITIVE: free-callback ( alien -- )
  16
  17 <PRIVATE
  18 PRIMITIVE: current-callback ( -- n )
  19 PRIVATE>
  20
  21 PREDICATE: pinned-alien < alien underlying>> not ;
  22
  23 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  24
  25 GENERIC: element-size ( seq -- n ) flushable
  26
  27 M: byte-array element-size drop 1 ; inline
  28
  29 M: byte-vector element-size drop 1 ; inline
  30
  31 M: slice element-size seq>> element-size ; inline
  32
  33 M: f element-size drop 1 ; inline
  34
  35 GENERIC: byte-length ( obj -- n ) flushable
  36
  37 M: object byte-length [ length ] [ element-size ] bi * ; inline
  38
  39 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  40
  41 M: c-ptr >c-ptr ; inline
  42
  43 M: slice >c-ptr
  44     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  45     <displaced-alien> ; inline
  46
  47 SLOT: underlying
  48
  49 M: object >c-ptr underlying>> ; inline
  50
  51 : binary-object ( obj -- c-ptr n )
  52     [ >c-ptr ] [ byte-length ] bi ; inline
  53
  54 GENERIC: expired? ( c-ptr -- ? ) flushable
  55
  56 M: alien expired? expired>> ;
  57
  58 M: f expired? drop t ;
  59
  60 : <alien> ( address -- alien )
  61     f <displaced-alien> { pinned-c-ptr } declare ; inline
  62
  63 : <bad-alien> ( -- alien )
  64     -1 <alien> t >>expired ; inline
  65
  66 M: alien equal?
  67     over alien? [
  68         2dup [ expired? ] either? [
  69             [ expired? ] both?
  70         ] [
  71             [ alien-address ] same?
  72         ] if
  73     ] [
  74         2drop f
  75     ] if ;
  76
  77 M: pinned-alien hashcode*
  78     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  79
  80 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  81
  82 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  83
  84 : callee-cleanup? ( abi -- ? )
  85     { stdcall fastcall thiscall } member? ;
  86
  87 ERROR: callsite-not-compiled word ;
  88
  89 : alien-assembly ( args... return parameters abi quot -- return... )
  90     \ alien-assembly callsite-not-compiled ;
  91
  92 : alien-callback ( return parameters abi quot -- alien )
  93     \ alien-callback callsite-not-compiled ;
  94
  95 : alien-indirect ( args... funcptr return parameters abi -- return... )
  96     \ alien-indirect callsite-not-compiled ;
  97
  98 : alien-invoke ( args... return library function parameters varargs? -- return... )
  99     \ alien-invoke callsite-not-compiled ;
 100
 101 <PRIVATE
 102
 103 ! Callbacks are registered in a global hashtable. Note that they
 104 ! are also pinned in a special callback area, so clearing this
 105 ! hashtable will not reclaim callbacks. It should only be
 106 ! cleared on startup.
 107 SYMBOL: callbacks
 108
 109 STARTUP-HOOK: [ H{ } clone callbacks set-global ]
 110
 111 ! Used by compiler.codegen to wrap callback bodies
 112 : do-callback ( callback-quot wait-quot: ( callback -- ) -- )
 113     t CONTEXT-OBJ-IN-CALLBACK-P set-context-object
 114     init-namestack
 115     init-catchstack
 116     current-callback
 117     [ 2drop call ] [ swap call( callback -- ) drop ] 3bi ; inline
 118
 119 ! A utility for defining global variables that are recompiled in
 120 ! every session
 121 TUPLE: expiry-check object alien ;
 122
 123 : recompute-value? ( check -- ? )
 124     [ alien>> expired? ] [ t ] if* ;
 125
 126 : delete-values ( value assoc -- )
 127     [ rot drop = ] with assoc-reject! drop ;
 128
 129 PRIVATE>
 130
 131 : unregister-and-free-callback ( alien -- )
 132     [ callbacks get delete-values ] [ free-callback ] bi ;
 133
 134 : with-callback ( alien quot -- )
 135     over [ unregister-and-free-callback ] curry finally ; inline
 136
 137 : initialize-alien ( symbol quot -- )
 138     swap dup get-global dup recompute-value?
 139     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 140     [ 2nip object>> ] if ; inline