core/alien/alien.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays arrays init ;
   5 IN: alien
   6
   7 ! Some predicate classes used by the compiler for optimization
   8 ! purposes
   9 PREDICATE: simple-alien < alien underlying>> not ;
  10
  11 UNION: simple-c-ptr
  12 simple-alien POSTPONE: f byte-array ;
  13
  14 DEFER: pinned-c-ptr?
  15
  16 PREDICATE: pinned-alien < alien underlying>> pinned-c-ptr? ;
  17
  18 UNION: pinned-c-ptr
  19     pinned-alien POSTPONE: f ;
  20
  21 GENERIC: >c-ptr ( obj -- c-ptr )
  22
  23 M: c-ptr >c-ptr ;
  24
  25 SLOT: underlying
  26
  27 M: object >c-ptr underlying>> ;
  28
  29 GENERIC: expired? ( c-ptr -- ? ) flushable
  30
  31 M: alien expired? expired>> ;
  32
  33 M: f expired? drop t ;
  34
  35 : <alien> ( address -- alien )
  36     f <displaced-alien> { simple-c-ptr } declare ; inline
  37
  38 : <bad-alien> ( -- alien )
  39     -1 <alien> t >>expired ; inline
  40
  41 M: alien equal?
  42     over alien? [
  43         2dup [ expired? ] either? [
  44             [ expired? ] both?
  45         ] [
  46             [ alien-address ] bi@ =
  47         ] if
  48     ] [
  49         2drop f
  50     ] if ;
  51
  52 SYMBOL: libraries
  53
  54 libraries [ H{ } clone ] initialize
  55
  56 TUPLE: library path abi dll ;
  57
  58 : library ( name -- library ) libraries get at ;
  59
  60 : <library> ( path abi -- library )
  61     over dup [ dlopen ] when \ library boa ;
  62
  63 : load-library ( name -- dll )
  64     library dup [ dll>> ] when ;
  65
  66 : add-library ( name path abi -- )
  67     <library> swap libraries get set-at ;
  68
  69 ERROR: alien-callback-error ;
  70
  71 : alien-callback ( return parameters abi quot -- alien )
  72     alien-callback-error ;
  73
  74 ERROR: alien-indirect-error ;
  75
  76 : alien-indirect ( ... funcptr return parameters abi -- )
  77     alien-indirect-error ;
  78
  79 ERROR: alien-invoke-error library symbol ;
  80
  81 : alien-invoke ( ... return library function parameters -- ... )
  82     2over alien-invoke-error ;
  83
  84 ! Callbacks are registered in a global hashtable. If you clear
  85 ! this hashtable, they will all be blown away by code GC, beware.
  86 SYMBOL: callbacks
  87
  88 [ H{ } clone callbacks set-global ] "alien" add-init-hook
  89
  90 <PRIVATE
  91
  92 TUPLE: expiry-check object alien ;
  93
  94 : recompute-value? ( check -- ? )
  95     dup [ alien>> expired? ] [ drop t ] if ;
  96
  97 PRIVATE>
  98
  99 : initialize-alien ( symbol quot -- )
 100     swap dup get-global dup recompute-value?
 101     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 102     [ 2nip object>> ] if ; inline