core/alien/alien.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays arrays init ;
   5 IN: alien
   6
   7 PREDICATE: pinned-alien < alien underlying>> not ;
   8
   9 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  10
  11 GENERIC: >c-ptr ( obj -- c-ptr )
  12
  13 M: c-ptr >c-ptr ; inline
  14
  15 SLOT: underlying
  16
  17 M: object >c-ptr underlying>> ; inline
  18
  19 GENERIC: expired? ( c-ptr -- ? ) flushable
  20
  21 M: alien expired? expired>> ;
  22
  23 M: f expired? drop t ;
  24
  25 : <alien> ( address -- alien )
  26     f <displaced-alien> { pinned-c-ptr } declare ; inline
  27
  28 : <bad-alien> ( -- alien )
  29     -1 <alien> t >>expired ; inline
  30
  31 M: alien equal?
  32     over alien? [
  33         2dup [ expired? ] either? [
  34             [ expired? ] both?
  35         ] [
  36             [ alien-address ] bi@ =
  37         ] if
  38     ] [
  39         2drop f
  40     ] if ;
  41
  42 M: pinned-alien hashcode*
  43     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  44
  45 ERROR: alien-callback-error ;
  46
  47 : alien-callback ( return parameters abi quot -- alien )
  48     alien-callback-error ;
  49
  50 ERROR: alien-indirect-error ;
  51
  52 : alien-indirect ( ... funcptr return parameters abi -- )
  53     alien-indirect-error ;
  54
  55 ERROR: alien-invoke-error library symbol ;
  56
  57 : alien-invoke ( ... return library function parameters -- ... )
  58     2over alien-invoke-error ;
  59
  60 ! Callbacks are registered in a global hashtable. Note that they
  61 ! are also pinned in a special callback area, so clearing this
  62 ! hashtable will not reclaim callbacks. It should only be
  63 ! cleared on startup.
  64 SYMBOL: callbacks
  65
  66 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
  67
  68 <PRIVATE
  69
  70 TUPLE: expiry-check object alien ;
  71
  72 : recompute-value? ( check -- ? )
  73     dup [ alien>> expired? ] [ drop t ] if ;
  74
  75 PRIVATE>
  76
  77 : initialize-alien ( symbol quot -- )
  78     swap dup get-global dup recompute-value?
  79     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
  80     [ 2nip object>> ] if ; inline