core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays byte-vectors arrays init
   5 continuations.private ;
   6 IN: alien
   7
   8 SINGLETONS: stdcall thiscall cdecl mingw ;
   9
  10 <PRIVATE
  11 SINGLETON: fastcall
  12 PRIVATE>
  13
  14 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  15
  16 PREDICATE: pinned-alien < alien underlying>> not ;
  17
  18 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  19
  20 GENERIC: element-size ( seq -- n ) flushable
  21
  22 M: byte-array element-size drop 1 ; inline
  23
  24 M: byte-vector element-size drop 1 ; inline
  25
  26 M: slice element-size seq>> element-size ; inline
  27
  28 M: f element-size drop 1 ; inline
  29
  30 GENERIC: byte-length ( obj -- n ) flushable
  31
  32 M: object byte-length [ length ] [ element-size ] bi * ; inline
  33
  34 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  35
  36 M: c-ptr >c-ptr ; inline
  37
  38 M: slice >c-ptr
  39     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  40     <displaced-alien> ; inline
  41
  42 SLOT: underlying
  43
  44 M: object >c-ptr underlying>> ; inline
  45
  46 : binary-object ( obj -- c-ptr n )
  47     [ >c-ptr ] [ byte-length ] bi ; inline
  48
  49 GENERIC: expired? ( c-ptr -- ? ) flushable
  50
  51 M: alien expired? expired>> ;
  52
  53 M: f expired? drop t ;
  54
  55 : <alien> ( address -- alien )
  56     f <displaced-alien> { pinned-c-ptr } declare ; inline
  57
  58 : <bad-alien> ( -- alien )
  59     -1 <alien> t >>expired ; inline
  60
  61 M: alien equal?
  62     over alien? [
  63         2dup [ expired? ] either? [
  64             [ expired? ] both?
  65         ] [
  66             [ alien-address ] bi@ =
  67         ] if
  68     ] [
  69         2drop f
  70     ] if ;
  71
  72 M: pinned-alien hashcode*
  73     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  74
  75 ERROR: alien-callback-error ;
  76
  77 : alien-callback ( return parameters abi quot -- alien )
  78     alien-callback-error ;
  79
  80 ERROR: alien-indirect-error ;
  81
  82 : alien-indirect ( args... funcptr return parameters abi -- return... )
  83     alien-indirect-error ;
  84
  85 ERROR: alien-invoke-error library symbol ;
  86
  87 : alien-invoke ( args... return library function parameters -- return... )
  88     2over alien-invoke-error ;
  89
  90 ERROR: alien-assembly-error code ;
  91
  92 : alien-assembly ( args... return parameters abi quot -- return... )
  93     dup alien-assembly-error ;
  94
  95 <PRIVATE
  96
  97 ! Callbacks are registered in a global hashtable. Note that they
  98 ! are also pinned in a special callback area, so clearing this
  99 ! hashtable will not reclaim callbacks. It should only be
 100 ! cleared on startup.
 101 SYMBOL: callbacks
 102
 103 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 104
 105 ! Every callback invocation has a unique identifier in the VM.
 106 ! We make sure that the current callback is the right one before
 107 ! returning from it, to avoid a bad interaction between threads
 108 ! and callbacks. See basis/compiler/tests/alien.factor for a
 109 ! test case.
 110 : wait-to-return ( yield-quot callback-id -- )
 111     dup current-callback eq?
 112     [ 2drop ] [ over call( -- ) wait-to-return ] if ;
 113
 114 ! Used by compiler.codegen to wrap callback bodies
 115 : do-callback ( callback-quot yield-quot -- )
 116     init-namespaces
 117     init-catchstack
 118     current-callback
 119     [ 2drop call ] [ wait-to-return drop ] 3bi ; inline
 120
 121 ! A utility for defining global variables that are recompiled in
 122 ! every session
 123 TUPLE: expiry-check object alien ;
 124
 125 : recompute-value? ( check -- ? )
 126     dup [ alien>> expired? ] [ drop t ] if ;
 127
 128 PRIVATE>
 129
 130 : initialize-alien ( symbol quot -- )
 131     swap dup get-global dup recompute-value?
 132     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 133     [ 2nip object>> ] if ; inline