core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays byte-vectors arrays init
   5 continuations.private ;
   6 IN: alien
   7
   8 PREDICATE: pinned-alien < alien underlying>> not ;
   9
  10 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  11
  12 GENERIC: element-size ( seq -- n ) flushable
  13
  14 M: byte-array element-size drop 1 ; inline
  15
  16 M: byte-vector element-size drop 1 ; inline
  17
  18 M: slice element-size seq>> element-size ; inline
  19
  20 M: f element-size drop 1 ; inline
  21
  22 GENERIC: byte-length ( obj -- n ) flushable
  23
  24 M: object byte-length [ length ] [ element-size ] bi * ; inline
  25
  26 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  27
  28 M: c-ptr >c-ptr ; inline
  29
  30 M: slice >c-ptr
  31     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  32     <displaced-alien> ; inline
  33
  34 SLOT: underlying
  35
  36 M: object >c-ptr underlying>> ; inline
  37
  38 : binary-object ( obj -- c-ptr n )
  39     [ >c-ptr ] [ byte-length ] bi ; inline
  40
  41 GENERIC: expired? ( c-ptr -- ? ) flushable
  42
  43 M: alien expired? expired>> ;
  44
  45 M: f expired? drop t ;
  46
  47 : <alien> ( address -- alien )
  48     f <displaced-alien> { pinned-c-ptr } declare ; inline
  49
  50 : <bad-alien> ( -- alien )
  51     -1 <alien> t >>expired ; inline
  52
  53 M: alien equal?
  54     over alien? [
  55         2dup [ expired? ] either? [
  56             [ expired? ] both?
  57         ] [
  58             [ alien-address ] bi@ =
  59         ] if
  60     ] [
  61         2drop f
  62     ] if ;
  63
  64 M: pinned-alien hashcode*
  65     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  66
  67 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  68
  69 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  70
  71 : callee-cleanup? ( abi -- ? )
  72     { stdcall fastcall thiscall } member? ;
  73
  74 ERROR: alien-callback-error ;
  75
  76 : alien-callback ( return parameters abi quot -- alien )
  77     alien-callback-error ;
  78
  79 ERROR: alien-indirect-error ;
  80
  81 : alien-indirect ( args... funcptr return parameters abi -- return... )
  82     alien-indirect-error ;
  83
  84 ERROR: alien-invoke-error library symbol ;
  85
  86 : alien-invoke ( args... return library function parameters -- return... )
  87     2over alien-invoke-error ;
  88
  89 ERROR: alien-assembly-error code ;
  90
  91 : alien-assembly ( args... return parameters abi quot -- return... )
  92     dup alien-assembly-error ;
  93
  94 <PRIVATE
  95
  96 ! Callbacks are registered in a global hashtable. Note that they
  97 ! are also pinned in a special callback area, so clearing this
  98 ! hashtable will not reclaim callbacks. It should only be
  99 ! cleared on startup.
 100 SYMBOL: callbacks
 101
 102 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 103
 104 ! Every callback invocation has a unique identifier in the VM.
 105 ! We make sure that the current callback is the right one before
 106 ! returning from it, to avoid a bad interaction between threads
 107 ! and callbacks. See basis/compiler/tests/alien.factor for a
 108 ! test case.
 109 : wait-to-return ( yield-quot callback-id -- )
 110     dup current-callback eq?
 111     [ 2drop ] [ over call( -- ) wait-to-return ] if ;
 112
 113 ! Used by compiler.codegen to wrap callback bodies
 114 : do-callback ( callback-quot yield-quot -- )
 115     init-namespaces
 116     init-catchstack
 117     current-callback
 118     [ 2drop call ] [ wait-to-return drop ] 3bi ; inline
 119
 120 ! A utility for defining global variables that are recompiled in
 121 ! every session
 122 TUPLE: expiry-check object alien ;
 123
 124 : recompute-value? ( check -- ? )
 125     dup [ alien>> expired? ] [ drop t ] if ;
 126
 127 PRIVATE>
 128
 129 : initialize-alien ( symbol quot -- )
 130     swap dup get-global dup recompute-value?
 131     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 132     [ 2nip object>> ] if ; inline