core/alien/alien.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays arrays init ;
   5 IN: alien
   6
   7 PREDICATE: pinned-alien < alien underlying>> not ;
   8
   9 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  10
  11 GENERIC: >c-ptr ( obj -- c-ptr )
  12
  13 M: c-ptr >c-ptr ; inline
  14
  15 SLOT: underlying
  16
  17 M: object >c-ptr underlying>> ; inline
  18
  19 GENERIC: expired? ( c-ptr -- ? ) flushable
  20
  21 M: alien expired? expired>> ;
  22
  23 M: f expired? drop t ;
  24
  25 : <alien> ( address -- alien )
  26     f <displaced-alien> { pinned-c-ptr } declare ; inline
  27
  28 : <bad-alien> ( -- alien )
  29     -1 <alien> t >>expired ; inline
  30
  31 M: alien equal?
  32     over alien? [
  33         2dup [ expired? ] either? [
  34             [ expired? ] both?
  35         ] [
  36             [ alien-address ] bi@ =
  37         ] if
  38     ] [
  39         2drop f
  40     ] if ;
  41
  42 M: simple-alien hashcode* nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  43
  44 ERROR: alien-callback-error ;
  45
  46 : alien-callback ( return parameters abi quot -- alien )
  47     alien-callback-error ;
  48
  49 ERROR: alien-indirect-error ;
  50
  51 : alien-indirect ( ... funcptr return parameters abi -- )
  52     alien-indirect-error ;
  53
  54 ERROR: alien-invoke-error library symbol ;
  55
  56 : alien-invoke ( ... return library function parameters -- ... )
  57     2over alien-invoke-error ;
  58
  59 ! Callbacks are registered in a global hashtable. Note that they
  60 ! are also pinned in a special callback area, so clearing this
  61 ! hashtable will not reclaim callbacks. It should only be
  62 ! cleared on startup.
  63 SYMBOL: callbacks
  64
  65 [ H{ } clone callbacks set-global ] "alien" add-init-hook
  66
  67 <PRIVATE
  68
  69 TUPLE: expiry-check object alien ;
  70
  71 : recompute-value? ( check -- ? )
  72     dup [ alien>> expired? ] [ drop t ] if ;
  73
  74 PRIVATE>
  75
  76 : initialize-alien ( symbol quot -- )
  77     swap dup get-global dup recompute-value?
  78     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
  79     [ 2nip object>> ] if ; inline