core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors byte-arrays byte-vectors continuations.private
   4 init kernel kernel.private math namespaces sequences ;
   5 IN: alien
   6
   7 BUILTIN: alien { underlying c-ptr read-only initial: f } expired ;
   8 BUILTIN: dll { path byte-array read-only initial: B{ } } ;
   9
  10 PREDICATE: pinned-alien < alien underlying>> not ;
  11
  12 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  13
  14 GENERIC: element-size ( seq -- n ) flushable
  15
  16 M: byte-array element-size drop 1 ; inline
  17
  18 M: byte-vector element-size drop 1 ; inline
  19
  20 M: slice element-size seq>> element-size ; inline
  21
  22 M: f element-size drop 1 ; inline
  23
  24 GENERIC: byte-length ( obj -- n ) flushable
  25
  26 M: object byte-length [ length ] [ element-size ] bi * ; inline
  27
  28 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  29
  30 M: c-ptr >c-ptr ; inline
  31
  32 M: slice >c-ptr
  33     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  34     <displaced-alien> ; inline
  35
  36 SLOT: underlying
  37
  38 M: object >c-ptr underlying>> ; inline
  39
  40 : binary-object ( obj -- c-ptr n )
  41     [ >c-ptr ] [ byte-length ] bi ; inline
  42
  43 GENERIC: expired? ( c-ptr -- ? ) flushable
  44
  45 M: alien expired? expired>> ;
  46
  47 M: f expired? drop t ;
  48
  49 : <alien> ( address -- alien )
  50     f <displaced-alien> { pinned-c-ptr } declare ; inline
  51
  52 : <bad-alien> ( -- alien )
  53     -1 <alien> t >>expired ; inline
  54
  55 M: alien equal?
  56     over alien? [
  57         2dup [ expired? ] either? [
  58             [ expired? ] both?
  59         ] [
  60             [ alien-address ] same?
  61         ] if
  62     ] [
  63         2drop f
  64     ] if ;
  65
  66 M: pinned-alien hashcode*
  67     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  68
  69 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  70
  71 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  72
  73 : callee-cleanup? ( abi -- ? )
  74     { stdcall fastcall thiscall } member? ;
  75
  76 ERROR: alien-callback-error ;
  77
  78 : alien-callback ( return parameters abi quot -- alien )
  79     alien-callback-error ;
  80
  81 ERROR: alien-indirect-error ;
  82
  83 : alien-indirect ( args... funcptr return parameters abi -- return... )
  84     alien-indirect-error ;
  85
  86 ERROR: alien-invoke-error library symbol ;
  87
  88 : alien-invoke ( args... return library function parameters -- return... )
  89     2over alien-invoke-error ;
  90
  91 ERROR: alien-assembly-error code ;
  92
  93 : alien-assembly ( args... return parameters abi quot -- return... )
  94     dup alien-assembly-error ;
  95
  96 <PRIVATE
  97
  98 ! Callbacks are registered in a global hashtable. Note that they
  99 ! are also pinned in a special callback area, so clearing this
 100 ! hashtable will not reclaim callbacks. It should only be
 101 ! cleared on startup.
 102 SYMBOL: callbacks
 103
 104 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 105
 106 ! Used by compiler.codegen to wrap callback bodies
 107 : do-callback ( callback-quot wait-quot: ( callback -- ) -- )
 108     t CONTEXT-OBJ-IN-CALLBACK-P set-context-object
 109     init-namespaces
 110     init-catchstack
 111     current-callback
 112     [ 2drop call ] [ swap call( callback -- ) drop ] 3bi ; inline
 113
 114 ! A utility for defining global variables that are recompiled in
 115 ! every session
 116 TUPLE: expiry-check object alien ;
 117
 118 : recompute-value? ( check -- ? )
 119     dup [ alien>> expired? ] [ drop t ] if ;
 120
 121 PRIVATE>
 122
 123 : initialize-alien ( symbol quot -- )
 124     swap dup get-global dup recompute-value?
 125     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 126     [ 2nip object>> ] if ; inline