core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays arrays init ;
   5 IN: alien
   6
   7 PREDICATE: pinned-alien < alien underlying>> not ;
   8
   9 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  10
  11 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  12
  13 M: c-ptr >c-ptr ; inline
  14
  15 GENERIC: byte-length ( seq -- n ) flushable
  16
  17 M: byte-array byte-length length ; inline
  18
  19 M: f byte-length drop 0 ; inline
  20
  21 : binary-object ( obj -- c-ptr n )
  22     [ >c-ptr ] [ byte-length ] bi ; inline
  23
  24 SLOT: underlying
  25
  26 M: object >c-ptr underlying>> ; inline
  27
  28 GENERIC: expired? ( c-ptr -- ? ) flushable
  29
  30 M: alien expired? expired>> ;
  31
  32 M: f expired? drop t ;
  33
  34 : <alien> ( address -- alien )
  35     f <displaced-alien> { pinned-c-ptr } declare ; inline
  36
  37 : <bad-alien> ( -- alien )
  38     -1 <alien> t >>expired ; inline
  39
  40 M: alien equal?
  41     over alien? [
  42         2dup [ expired? ] either? [
  43             [ expired? ] both?
  44         ] [
  45             [ alien-address ] bi@ =
  46         ] if
  47     ] [
  48         2drop f
  49     ] if ;
  50
  51 M: pinned-alien hashcode*
  52     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  53
  54 ERROR: alien-callback-error ;
  55
  56 : alien-callback ( return parameters abi quot -- alien )
  57     alien-callback-error ;
  58
  59 ERROR: alien-indirect-error ;
  60
  61 : alien-indirect ( ... funcptr return parameters abi -- ... )
  62     alien-indirect-error ;
  63
  64 ERROR: alien-invoke-error library symbol ;
  65
  66 : alien-invoke ( ... return library function parameters -- ... )
  67     2over alien-invoke-error ;
  68
  69 ERROR: alien-assembly-error code ;
  70
  71 : alien-assembly ( ... return parameters abi quot -- ... )
  72     dup alien-assembly-error ;
  73
  74 ! Callbacks are registered in a global hashtable. Note that they
  75 ! are also pinned in a special callback area, so clearing this
  76 ! hashtable will not reclaim callbacks. It should only be
  77 ! cleared on startup.
  78 SYMBOL: callbacks
  79
  80 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
  81
  82 <PRIVATE
  83
  84 TUPLE: expiry-check object alien ;
  85
  86 : recompute-value? ( check -- ? )
  87     dup [ alien>> expired? ] [ drop t ] if ;
  88
  89 PRIVATE>
  90
  91 : initialize-alien ( symbol quot -- )
  92     swap dup get-global dup recompute-value?
  93     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
  94     [ 2nip object>> ] if ; inline