core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors byte-arrays byte-vectors continuations.private
   4 init kernel kernel.private math namespaces sequences ;
   5 IN: alien
   6
   7 PREDICATE: pinned-alien < alien underlying>> not ;
   8
   9 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  10
  11 GENERIC: element-size ( seq -- n ) flushable
  12
  13 M: byte-array element-size drop 1 ; inline
  14
  15 M: byte-vector element-size drop 1 ; inline
  16
  17 M: slice element-size seq>> element-size ; inline
  18
  19 M: f element-size drop 1 ; inline
  20
  21 GENERIC: byte-length ( obj -- n ) flushable
  22
  23 M: object byte-length [ length ] [ element-size ] bi * ; inline
  24
  25 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  26
  27 M: c-ptr >c-ptr ; inline
  28
  29 M: slice >c-ptr
  30     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  31     <displaced-alien> ; inline
  32
  33 SLOT: underlying
  34
  35 M: object >c-ptr underlying>> ; inline
  36
  37 : binary-object ( obj -- c-ptr n )
  38     [ >c-ptr ] [ byte-length ] bi ; inline
  39
  40 GENERIC: expired? ( c-ptr -- ? ) flushable
  41
  42 M: alien expired? expired>> ;
  43
  44 M: f expired? drop t ;
  45
  46 : <alien> ( address -- alien )
  47     f <displaced-alien> { pinned-c-ptr } declare ; inline
  48
  49 : <bad-alien> ( -- alien )
  50     -1 <alien> t >>expired ; inline
  51
  52 M: alien equal?
  53     over alien? [
  54         2dup [ expired? ] either? [
  55             [ expired? ] both?
  56         ] [
  57             [ alien-address ] bi@ =
  58         ] if
  59     ] [
  60         2drop f
  61     ] if ;
  62
  63 M: pinned-alien hashcode*
  64     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  65
  66 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  67
  68 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  69
  70 : callee-cleanup? ( abi -- ? )
  71     { stdcall fastcall thiscall } member? ;
  72
  73 ERROR: alien-callback-error ;
  74
  75 : alien-callback ( return parameters abi quot -- alien )
  76     alien-callback-error ;
  77
  78 ERROR: alien-indirect-error ;
  79
  80 : alien-indirect ( args... funcptr return parameters abi -- return... )
  81     alien-indirect-error ;
  82
  83 ERROR: alien-invoke-error library symbol ;
  84
  85 : alien-invoke ( args... return library function parameters -- return... )
  86     2over alien-invoke-error ;
  87
  88 ERROR: alien-assembly-error code ;
  89
  90 : alien-assembly ( args... return parameters abi quot -- return... )
  91     dup alien-assembly-error ;
  92
  93 <PRIVATE
  94
  95 ! Callbacks are registered in a global hashtable. Note that they
  96 ! are also pinned in a special callback area, so clearing this
  97 ! hashtable will not reclaim callbacks. It should only be
  98 ! cleared on startup.
  99 SYMBOL: callbacks
 100
 101 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 102
 103 ! Used by compiler.codegen to wrap callback bodies
 104 : do-callback ( callback-quot wait-quot: ( callback -- ) -- )
 105     t CONTEXT-OBJ-IN-CALLBACK-P set-context-object
 106     init-namespaces
 107     init-catchstack
 108     current-callback
 109     [ 2drop call ] [ swap call( callback -- ) drop ] 3bi ; inline
 110
 111 ! A utility for defining global variables that are recompiled in
 112 ! every session
 113 TUPLE: expiry-check object alien ;
 114
 115 : recompute-value? ( check -- ? )
 116     dup [ alien>> expired? ] [ drop t ] if ;
 117
 118 PRIVATE>
 119
 120 : initialize-alien ( symbol quot -- )
 121     swap dup get-global dup recompute-value?
 122     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 123     [ 2nip object>> ] if ; inline