core/alien/alien.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays arrays init ;
   5 IN: alien
   6
   7 ! Some predicate classes used by the compiler for optimization
   8 ! purposes
   9 PREDICATE: simple-alien < alien underlying>> not ;
  10
  11 UNION: simple-c-ptr
  12 simple-alien POSTPONE: f byte-array ;
  13
  14 DEFER: pinned-c-ptr?
  15
  16 PREDICATE: pinned-alien < alien underlying>> pinned-c-ptr? ;
  17
  18 UNION: pinned-c-ptr
  19     pinned-alien POSTPONE: f ;
  20
  21 GENERIC: >c-ptr ( obj -- c-ptr )
  22
  23 M: c-ptr >c-ptr ; inline
  24
  25 SLOT: underlying
  26
  27 M: object >c-ptr underlying>> ; inline
  28
  29 GENERIC: expired? ( c-ptr -- ? ) flushable
  30
  31 M: alien expired? expired>> ;
  32
  33 M: f expired? drop t ;
  34
  35 : <alien> ( address -- alien )
  36     f <displaced-alien> { simple-c-ptr } declare ; inline
  37
  38 : <bad-alien> ( -- alien )
  39     -1 <alien> t >>expired ; inline
  40
  41 M: alien equal?
  42     over alien? [
  43         2dup [ expired? ] either? [
  44             [ expired? ] both?
  45         ] [
  46             [ alien-address ] bi@ =
  47         ] if
  48     ] [
  49         2drop f
  50     ] if ;
  51
  52 M: simple-alien hashcode* nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  53
  54 ERROR: alien-callback-error ;
  55
  56 : alien-callback ( return parameters abi quot -- alien )
  57     alien-callback-error ;
  58
  59 ERROR: alien-indirect-error ;
  60
  61 : alien-indirect ( ... funcptr return parameters abi -- )
  62     alien-indirect-error ;
  63
  64 ERROR: alien-invoke-error library symbol ;
  65
  66 : alien-invoke ( ... return library function parameters -- ... )
  67     2over alien-invoke-error ;
  68
  69 ! Callbacks are registered in a global hashtable. If you clear
  70 ! this hashtable, they will all be blown away by code GC, beware.
  71 SYMBOL: callbacks
  72
  73 [ H{ } clone callbacks set-global ] "alien" add-init-hook
  74
  75 <PRIVATE
  76
  77 TUPLE: expiry-check object alien ;
  78
  79 : recompute-value? ( check -- ? )
  80     dup [ alien>> expired? ] [ drop t ] if ;
  81
  82 PRIVATE>
  83
  84 : initialize-alien ( symbol quot -- )
  85     swap dup get-global dup recompute-value?
  86     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
  87     [ 2nip object>> ] if ; inline