core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs byte-arrays byte-vectors continuations
   4 continuations.private init kernel kernel.private math namespaces
   5 sequences ;
   6 IN: alien
   7
   8 BUILTIN: alien { underlying c-ptr read-only initial: f } expired ;
   9 BUILTIN: dll { path byte-array read-only initial: B{ } } ;
  10
  11 PREDICATE: pinned-alien < alien underlying>> not ;
  12
  13 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  14
  15 GENERIC: element-size ( seq -- n ) flushable
  16
  17 M: byte-array element-size drop 1 ; inline
  18
  19 M: byte-vector element-size drop 1 ; inline
  20
  21 M: slice element-size seq>> element-size ; inline
  22
  23 M: f element-size drop 1 ; inline
  24
  25 GENERIC: byte-length ( obj -- n ) flushable
  26
  27 M: object byte-length [ length ] [ element-size ] bi * ; inline
  28
  29 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  30
  31 M: c-ptr >c-ptr ; inline
  32
  33 M: slice >c-ptr
  34     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  35     <displaced-alien> ; inline
  36
  37 SLOT: underlying
  38
  39 M: object >c-ptr underlying>> ; inline
  40
  41 : binary-object ( obj -- c-ptr n )
  42     [ >c-ptr ] [ byte-length ] bi ; inline
  43
  44 GENERIC: expired? ( c-ptr -- ? ) flushable
  45
  46 M: alien expired? expired>> ;
  47
  48 M: f expired? drop t ;
  49
  50 : <alien> ( address -- alien )
  51     f <displaced-alien> { pinned-c-ptr } declare ; inline
  52
  53 : <bad-alien> ( -- alien )
  54     -1 <alien> t >>expired ; inline
  55
  56 M: alien equal?
  57     over alien? [
  58         2dup [ expired? ] either? [
  59             [ expired? ] both?
  60         ] [
  61             [ alien-address ] same?
  62         ] if
  63     ] [
  64         2drop f
  65     ] if ;
  66
  67 M: pinned-alien hashcode*
  68     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  69
  70 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  71
  72 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  73
  74 : callee-cleanup? ( abi -- ? )
  75     { stdcall fastcall thiscall } member? ;
  76
  77 ERROR: alien-callback-error ;
  78
  79 : alien-callback ( return parameters abi quot -- alien )
  80     alien-callback-error ;
  81
  82 ERROR: alien-indirect-error ;
  83
  84 : alien-indirect ( args... funcptr return parameters abi -- return... )
  85     alien-indirect-error ;
  86
  87 ERROR: alien-invoke-error library symbol ;
  88
  89 : alien-invoke ( args... return library function parameters -- return... )
  90     2over alien-invoke-error ;
  91
  92 ERROR: alien-assembly-error code ;
  93
  94 : alien-assembly ( args... return parameters abi quot -- return... )
  95     dup alien-assembly-error ;
  96
  97 <PRIVATE
  98
  99 ! Callbacks are registered in a global hashtable. Note that they
 100 ! are also pinned in a special callback area, so clearing this
 101 ! hashtable will not reclaim callbacks. It should only be
 102 ! cleared on startup.
 103 SYMBOL: callbacks
 104
 105 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 106
 107 ! Used by compiler.codegen to wrap callback bodies
 108 : do-callback ( callback-quot wait-quot: ( callback -- ) -- )
 109     t CONTEXT-OBJ-IN-CALLBACK-P set-context-object
 110     init-namespaces
 111     init-catchstack
 112     current-callback
 113     [ 2drop call ] [ swap call( callback -- ) drop ] 3bi ; inline
 114
 115 ! A utility for defining global variables that are recompiled in
 116 ! every session
 117 TUPLE: expiry-check object alien ;
 118
 119 : recompute-value? ( check -- ? )
 120     dup [ alien>> expired? ] [ drop t ] if ;
 121
 122 : delete-values ( value assoc -- )
 123     [ rot drop = not ] with assoc-filter! drop ;
 124
 125 PRIVATE>
 126
 127 : unregister-and-free-callback ( alien -- )
 128     [ callbacks get delete-values ] [ free-callback ] bi ;
 129
 130 : with-callback ( alien quot -- )
 131     over [ unregister-and-free-callback ] curry [ ] cleanup ; inline
 132
 133 : initialize-alien ( symbol quot -- )
 134     swap dup get-global dup recompute-value?
 135     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 136     [ 2nip object>> ] if ; inline