core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs kernel math namespaces sequences system
   4 kernel.private byte-arrays byte-vectors arrays init
   5 continuations.private ;
   6 IN: alien
   7
   8 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
   9
  10 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  11
  12 PREDICATE: pinned-alien < alien underlying>> not ;
  13
  14 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  15
  16 GENERIC: element-size ( seq -- n ) flushable
  17
  18 M: byte-array element-size drop 1 ; inline
  19
  20 M: byte-vector element-size drop 1 ; inline
  21
  22 M: slice element-size seq>> element-size ; inline
  23
  24 M: f element-size drop 1 ; inline
  25
  26 GENERIC: byte-length ( obj -- n ) flushable
  27
  28 M: object byte-length [ length ] [ element-size ] bi * ; inline
  29
  30 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  31
  32 M: c-ptr >c-ptr ; inline
  33
  34 M: slice >c-ptr
  35     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  36     <displaced-alien> ; inline
  37
  38 SLOT: underlying
  39
  40 M: object >c-ptr underlying>> ; inline
  41
  42 : binary-object ( obj -- c-ptr n )
  43     [ >c-ptr ] [ byte-length ] bi ; inline
  44
  45 GENERIC: expired? ( c-ptr -- ? ) flushable
  46
  47 M: alien expired? expired>> ;
  48
  49 M: f expired? drop t ;
  50
  51 : <alien> ( address -- alien )
  52     f <displaced-alien> { pinned-c-ptr } declare ; inline
  53
  54 : <bad-alien> ( -- alien )
  55     -1 <alien> t >>expired ; inline
  56
  57 M: alien equal?
  58     over alien? [
  59         2dup [ expired? ] either? [
  60             [ expired? ] both?
  61         ] [
  62             [ alien-address ] bi@ =
  63         ] if
  64     ] [
  65         2drop f
  66     ] if ;
  67
  68 M: pinned-alien hashcode*
  69     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  70
  71 ERROR: alien-callback-error ;
  72
  73 : alien-callback ( return parameters abi quot -- alien )
  74     alien-callback-error ;
  75
  76 ERROR: alien-indirect-error ;
  77
  78 : alien-indirect ( args... funcptr return parameters abi -- return... )
  79     alien-indirect-error ;
  80
  81 ERROR: alien-invoke-error library symbol ;
  82
  83 : alien-invoke ( args... return library function parameters -- return... )
  84     2over alien-invoke-error ;
  85
  86 ERROR: alien-assembly-error code ;
  87
  88 : alien-assembly ( args... return parameters abi quot -- return... )
  89     dup alien-assembly-error ;
  90
  91 <PRIVATE
  92
  93 ! Callbacks are registered in a global hashtable. Note that they
  94 ! are also pinned in a special callback area, so clearing this
  95 ! hashtable will not reclaim callbacks. It should only be
  96 ! cleared on startup.
  97 SYMBOL: callbacks
  98
  99 [ H{ } clone callbacks set-global ] "alien" add-startup-hook
 100
 101 ! Every callback invocation has a unique identifier in the VM.
 102 ! We make sure that the current callback is the right one before
 103 ! returning from it, to avoid a bad interaction between threads
 104 ! and callbacks. See basis/compiler/tests/alien.factor for a
 105 ! test case.
 106 : wait-to-return ( yield-quot callback-id -- )
 107     dup current-callback eq?
 108     [ 2drop ] [ over call( -- ) wait-to-return ] if ;
 109
 110 ! Used by compiler.codegen to wrap callback bodies
 111 : do-callback ( callback-quot yield-quot -- )
 112     init-namespaces
 113     init-catchstack
 114     current-callback
 115     [ 2drop call ] [ wait-to-return drop ] 3bi ; inline
 116
 117 ! A utility for defining global variables that are recompiled in
 118 ! every session
 119 TUPLE: expiry-check object alien ;
 120
 121 : recompute-value? ( check -- ? )
 122     dup [ alien>> expired? ] [ drop t ] if ;
 123
 124 PRIVATE>
 125
 126 : initialize-alien ( symbol quot -- )
 127     swap dup get-global dup recompute-value?
 128     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 129     [ 2nip object>> ] if ; inline