core/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bit-arrays byte-arrays float-arrays arrays
   4 assocs kernel kernel.private libc math
   5 namespaces parser sequences strings words assocs splitting
   6 math.parser cpu.architecture alien alien.accessors quotations
   7 layouts system compiler.units io.files io.encodings.binary
   8 accessors combinators effects ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: c-type
  17 boxer boxer-quot unboxer unboxer-quot
  18 getter setter
  19 reg-class size align stack-align? ;
  20
  21 : new-c-type ( class -- type )
  22     new
  23         int-regs >>reg-class ;
  24
  25 : <c-type> ( -- type )
  26     \ c-type new-c-type ;
  27
  28 SYMBOL: c-types
  29
  30 global [
  31     c-types [ H{ } assoc-like ] change
  32 ] bind
  33
  34 ERROR: no-c-type name ;
  35
  36 : (c-type) ( name -- type/f )
  37     c-types get-global at dup [
  38         dup string? [ (c-type) ] when
  39     ] when ;
  40
  41 GENERIC: c-type ( name -- type ) foldable
  42
  43 : resolve-pointer-type ( name -- name )
  44     c-types get at dup string?
  45     [ "*" append ] [ drop "void*" ] if
  46     c-type ;
  47
  48 : resolve-typedef ( name -- type )
  49     dup string? [ c-type ] when ;
  50
  51 : parse-array-type ( name -- array )
  52     "[" split unclip
  53     >r [ "]" ?tail drop string>number ] map r> prefix ;
  54
  55 M: string c-type ( name -- type )
  56     CHAR: ] over member? [
  57         parse-array-type
  58     ] [
  59         dup c-types get at [
  60             resolve-typedef
  61         ] [
  62             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  63         ] ?if
  64     ] if ;
  65
  66 : c-type-box ( n type -- )
  67     dup c-type-reg-class
  68     swap c-type-boxer [ "No boxer" throw ] unless*
  69     %box ;
  70
  71 : c-type-unbox ( n ctype -- )
  72     dup c-type-reg-class
  73     swap c-type-unboxer [ "No unboxer" throw ] unless*
  74     %unbox ;
  75
  76 M: string c-type-align c-type c-type-align ;
  77
  78 M: string c-type-stack-align? c-type c-type-stack-align? ;
  79
  80 GENERIC: box-parameter ( n ctype -- )
  81
  82 M: c-type box-parameter c-type-box ;
  83
  84 M: string box-parameter c-type box-parameter ;
  85
  86 GENERIC: box-return ( ctype -- )
  87
  88 M: c-type box-return f swap c-type-box ;
  89
  90 M: string box-return c-type box-return ;
  91
  92 GENERIC: unbox-parameter ( n ctype -- )
  93
  94 M: c-type unbox-parameter c-type-unbox ;
  95
  96 M: string unbox-parameter c-type unbox-parameter ;
  97
  98 GENERIC: unbox-return ( ctype -- )
  99
 100 M: c-type unbox-return f swap c-type-unbox ;
 101
 102 M: string unbox-return c-type unbox-return ;
 103
 104 ! These words being foldable means that words need to be
 105 ! recompiled if a C type is redefined. Even so, folding the
 106 ! size facilitates some optimizations.
 107 GENERIC: heap-size ( type -- size ) foldable
 108
 109 M: string heap-size c-type heap-size ;
 110
 111 M: c-type heap-size c-type-size ;
 112
 113 GENERIC: stack-size ( type -- size ) foldable
 114
 115 M: string stack-size c-type stack-size ;
 116
 117 M: c-type stack-size c-type-size ;
 118
 119 GENERIC: byte-length ( seq -- n ) flushable
 120
 121 M: bit-array byte-length length 7 + -3 shift ;
 122
 123 M: byte-array byte-length length ;
 124
 125 M: float-array byte-length length "double" heap-size * ;
 126
 127 : c-getter ( name -- quot )
 128     c-type c-type-getter [
 129         [ "Cannot read struct fields with type" throw ]
 130     ] unless* ;
 131
 132 : c-setter ( name -- quot )
 133     c-type c-type-setter [
 134         [ "Cannot write struct fields with type" throw ]
 135     ] unless* ;
 136
 137 : <c-array> ( n type -- array )
 138     heap-size * <byte-array> ; inline
 139
 140 : <c-object> ( type -- array )
 141     1 swap <c-array> ; inline
 142
 143 : malloc-array ( n type -- alien )
 144     heap-size calloc ; inline
 145
 146 : malloc-object ( type -- alien )
 147     1 swap malloc-array ; inline
 148
 149 : malloc-byte-array ( byte-array -- alien )
 150     dup length dup malloc [ -rot memcpy ] keep ;
 151
 152 : memory>byte-array ( alien len -- byte-array )
 153     dup <byte-array> [ -rot memcpy ] keep ;
 154
 155 : byte-array>memory ( byte-array base -- )
 156     swap dup length memcpy ;
 157
 158 : (define-nth) ( word type quot -- )
 159     >r heap-size [ rot * ] swap prefix r> append define-inline ;
 160
 161 : nth-word ( name vocab -- word )
 162     >r "-nth" append r> create ;
 163
 164 : define-nth ( name vocab -- )
 165     dupd nth-word swap dup c-getter (define-nth) ;
 166
 167 : set-nth-word ( name vocab -- word )
 168     >r "set-" swap "-nth" 3append r> create ;
 169
 170 : define-set-nth ( name vocab -- )
 171     dupd set-nth-word swap dup c-setter (define-nth) ;
 172
 173 : typedef ( old new -- ) c-types get set-at ;
 174
 175 : define-c-type ( type name vocab -- )
 176     >r tuck typedef r> [ define-nth ] 2keep define-set-nth ;
 177
 178 TUPLE: long-long-type < c-type ;
 179
 180 : <long-long-type> ( -- type )
 181     long-long-type new-c-type ;
 182
 183 M: long-long-type unbox-parameter ( n type -- )
 184     c-type-unboxer %unbox-long-long ;
 185
 186 M: long-long-type unbox-return ( type -- )
 187     f swap unbox-parameter ;
 188
 189 M: long-long-type box-parameter ( n type -- )
 190     c-type-boxer %box-long-long ;
 191
 192 M: long-long-type box-return ( type -- )
 193     f swap box-parameter ;
 194
 195 : define-deref ( name vocab -- )
 196     >r dup CHAR: * prefix r> create
 197     swap c-getter 0 prefix define-inline ;
 198
 199 : define-out ( name vocab -- )
 200     over [ <c-object> tuck 0 ] over c-setter append swap
 201     >r >r constructor-word r> r> prefix define-inline ;
 202
 203 : c-bool> ( int -- ? )
 204     zero? not ;
 205
 206 : >c-array ( seq type word -- )
 207     >r >r dup length dup r> <c-array> dup -roll r>
 208     [ execute ] 2curry 2each ; inline
 209
 210 : >c-array-quot ( type vocab -- quot )
 211     dupd set-nth-word [ >c-array ] 2curry ;
 212
 213 : to-array-word ( name vocab -- word )
 214     >r ">c-" swap "-array" 3append r> create ;
 215
 216 : define-to-array ( type vocab -- )
 217     [ to-array-word ] 2keep >c-array-quot
 218     (( array -- byte-array )) define-declared ;
 219
 220 : c-array>quot ( type vocab -- quot )
 221     [
 222         \ swap ,
 223         nth-word 1quotation ,
 224         [ curry map ] %
 225     ] [ ] make ;
 226
 227 : from-array-word ( name vocab -- word )
 228     >r "c-" swap "-array>" 3append r> create ;
 229
 230 : define-from-array ( type vocab -- )
 231     [ from-array-word ] 2keep c-array>quot
 232     (( c-ptr n -- array )) define-declared ;
 233
 234 : define-primitive-type ( type name -- )
 235     "alien.c-types"
 236     {
 237         [ define-c-type ]
 238         [ define-deref ]
 239         [ define-to-array ]
 240         [ define-from-array ]
 241         [ define-out ]
 242     } 2cleave ;
 243
 244 : expand-constants ( c-type -- c-type' )
 245     #! We use def>> call instead of execute to get around
 246     #! staging violations
 247     dup array? [
 248         unclip >r [ dup word? [ def>> call ] when ] map r> prefix
 249     ] when ;
 250
 251 : malloc-file-contents ( path -- alien len )
 252     binary file-contents dup malloc-byte-array swap length ;
 253
 254 [
 255     <c-type>
 256         [ alien-cell ] >>getter
 257         [ set-alien-cell ] >>setter
 258         bootstrap-cell >>size
 259         bootstrap-cell >>align
 260         "box_alien" >>boxer
 261         "alien_offset" >>unboxer
 262     "void*" define-primitive-type
 263
 264     <long-long-type>
 265         [ alien-signed-8 ] >>getter
 266         [ set-alien-signed-8 ] >>setter
 267         8 >>size
 268         8 >>align
 269         "box_signed_8" >>boxer
 270         "to_signed_8" >>unboxer
 271     "longlong" define-primitive-type
 272
 273     <long-long-type>
 274         [ alien-unsigned-8 ] >>getter
 275         [ set-alien-unsigned-8 ] >>setter
 276         8 >>size
 277         8 >>align
 278         "box_unsigned_8" >>boxer
 279         "to_unsigned_8" >>unboxer
 280     "ulonglong" define-primitive-type
 281
 282     <c-type>
 283         [ alien-signed-cell ] >>getter
 284         [ set-alien-signed-cell ] >>setter
 285         bootstrap-cell >>size
 286         bootstrap-cell >>align
 287         "box_signed_cell" >>boxer
 288         "to_fixnum" >>unboxer
 289     "long" define-primitive-type
 290
 291     <c-type>
 292         [ alien-unsigned-cell ] >>getter
 293         [ set-alien-unsigned-cell ] >>setter
 294         bootstrap-cell >>size
 295         bootstrap-cell >>align
 296         "box_unsigned_cell" >>boxer
 297         "to_cell" >>unboxer
 298     "ulong" define-primitive-type
 299
 300     <c-type>
 301         [ alien-signed-4 ] >>getter
 302         [ set-alien-signed-4 ] >>setter
 303         4 >>size
 304         4 >>align
 305         "box_signed_4" >>boxer
 306         "to_fixnum" >>unboxer
 307     "int" define-primitive-type
 308
 309     <c-type>
 310         [ alien-unsigned-4 ] >>getter
 311         [ set-alien-unsigned-4 ] >>setter
 312         4 >>size
 313         4 >>align
 314         "box_unsigned_4" >>boxer
 315         "to_cell" >>unboxer
 316     "uint" define-primitive-type
 317
 318     <c-type>
 319         [ alien-signed-2 ] >>getter
 320         [ set-alien-signed-2 ] >>setter
 321         2 >>size
 322         2 >>align
 323         "box_signed_2" >>boxer
 324         "to_fixnum" >>unboxer
 325     "short" define-primitive-type
 326
 327     <c-type>
 328         [ alien-unsigned-2 ] >>getter
 329         [ set-alien-unsigned-2 ] >>setter
 330         2 >>size
 331         2 >>align
 332         "box_unsigned_2" >>boxer
 333         "to_cell" >>unboxer
 334     "ushort" define-primitive-type
 335
 336     <c-type>
 337         [ alien-signed-1 ] >>getter
 338         [ set-alien-signed-1 ] >>setter
 339         1 >>size
 340         1 >>align
 341         "box_signed_1" >>boxer
 342         "to_fixnum" >>unboxer
 343     "char" define-primitive-type
 344
 345     <c-type>
 346         [ alien-unsigned-1 ] >>getter
 347         [ set-alien-unsigned-1 ] >>setter
 348         1 >>size
 349         1 >>align
 350         "box_unsigned_1" >>boxer
 351         "to_cell" >>unboxer
 352     "uchar" define-primitive-type
 353
 354     <c-type>
 355         [ alien-unsigned-4 zero? not ] >>getter
 356         [ 1 0 ? set-alien-unsigned-4 ] >>setter
 357         4 >>size
 358         4 >>align
 359         "box_boolean" >>boxer
 360         "to_boolean" >>unboxer
 361     "bool" define-primitive-type
 362
 363     <c-type>
 364         [ alien-float ] >>getter
 365         [ >r >r >float r> r> set-alien-float ] >>setter
 366         4 >>size
 367         4 >>align
 368         "box_float" >>boxer
 369         "to_float" >>unboxer
 370         single-float-regs >>reg-class
 371         [ >float ] >>unboxer-quot
 372     "float" define-primitive-type
 373
 374     <c-type>
 375         [ alien-double ] >>getter
 376         [ >r >r >float r> r> set-alien-double ] >>setter
 377         8 >>size
 378         8 >>align
 379         "box_double" >>boxer
 380         "to_double" >>unboxer
 381         double-float-regs >>reg-class
 382         [ >float ] >>unboxer-quot
 383     "double" define-primitive-type
 384
 385     os winnt? cpu x86.64? and "longlong" "long" ? "ptrdiff_t" typedef
 386
 387     "ulong" "size_t" typedef
 388 ] with-compilation-unit