core/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bit-arrays byte-arrays float-arrays arrays
   4 assocs kernel kernel.private libc math
   5 namespaces parser sequences strings words assocs splitting
   6 math.parser cpu.architecture alien alien.accessors quotations
   7 layouts system compiler.units io.files io.encodings.binary
   8 accessors combinators effects ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: c-type
  17 boxer boxer-quot unboxer unboxer-quot
  18 getter setter
  19 reg-class size align stack-align? ;
  20
  21 : new-c-type ( class -- type )
  22     new
  23         int-regs >>reg-class ;
  24
  25 : <c-type> ( -- type )
  26     \ c-type new-c-type ;
  27
  28 SYMBOL: c-types
  29
  30 global [
  31     c-types [ H{ } assoc-like ] change
  32 ] bind
  33
  34 ERROR: no-c-type name ;
  35
  36 : (c-type) ( name -- type/f )
  37     c-types get-global at dup [
  38         dup string? [ (c-type) ] when
  39     ] when ;
  40
  41 GENERIC: c-type ( name -- type ) foldable
  42
  43 : resolve-pointer-type ( name -- name )
  44     c-types get at dup string?
  45     [ "*" append ] [ drop "void*" ] if
  46     c-type ;
  47
  48 : resolve-typedef ( name -- type )
  49     dup string? [ c-type ] when ;
  50
  51 : parse-array-type ( name -- array )
  52     "[" split unclip
  53     >r [ "]" ?tail drop string>number ] map r> prefix ;
  54
  55 M: string c-type ( name -- type )
  56     CHAR: ] over member? [
  57         parse-array-type
  58     ] [
  59         dup c-types get at [
  60             resolve-typedef
  61         ] [
  62             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  63         ] ?if
  64     ] if ;
  65
  66 : c-type-box ( n type -- )
  67     dup c-type-reg-class
  68     swap c-type-boxer [ "No boxer" throw ] unless*
  69     %box ;
  70
  71 : c-type-unbox ( n ctype -- )
  72     dup c-type-reg-class
  73     swap c-type-unboxer [ "No unboxer" throw ] unless*
  74     %unbox ;
  75
  76 M: string c-type-align c-type c-type-align ;
  77
  78 M: string c-type-stack-align? c-type c-type-stack-align? ;
  79
  80 GENERIC: box-parameter ( n ctype -- )
  81
  82 M: c-type box-parameter c-type-box ;
  83
  84 M: string box-parameter c-type box-parameter ;
  85
  86 GENERIC: box-return ( ctype -- )
  87
  88 M: c-type box-return f swap c-type-box ;
  89
  90 M: string box-return c-type box-return ;
  91
  92 GENERIC: unbox-parameter ( n ctype -- )
  93
  94 M: c-type unbox-parameter c-type-unbox ;
  95
  96 M: string unbox-parameter c-type unbox-parameter ;
  97
  98 GENERIC: unbox-return ( ctype -- )
  99
 100 M: c-type unbox-return f swap c-type-unbox ;
 101
 102 M: string unbox-return c-type unbox-return ;
 103
 104 ! These words being foldable means that words need to be
 105 ! recompiled if a C type is redefined. Even so, folding the
 106 ! size facilitates some optimizations.
 107 GENERIC: heap-size ( type -- size ) foldable
 108
 109 M: string heap-size c-type heap-size ;
 110
 111 M: c-type heap-size c-type-size ;
 112
 113 GENERIC: stack-size ( type -- size ) foldable
 114
 115 M: string stack-size c-type stack-size ;
 116
 117 M: c-type stack-size c-type-size ;
 118
 119 GENERIC: byte-length ( seq -- n ) flushable
 120
 121 M: bit-array byte-length length 7 + -3 shift ;
 122
 123 M: byte-array byte-length length ;
 124
 125 M: float-array byte-length length "double" heap-size * ;
 126
 127 : c-getter ( name -- quot )
 128     c-type c-type-getter [
 129         [ "Cannot read struct fields with type" throw ]
 130     ] unless* ;
 131
 132 : c-setter ( name -- quot )
 133     c-type c-type-setter [
 134         [ "Cannot write struct fields with type" throw ]
 135     ] unless* ;
 136
 137 : <c-array> ( n type -- array )
 138     heap-size * <byte-array> ; inline
 139
 140 : <c-object> ( type -- array )
 141     1 swap <c-array> ; inline
 142
 143 : malloc-array ( n type -- alien )
 144     heap-size calloc ; inline
 145
 146 : malloc-object ( type -- alien )
 147     1 swap malloc-array ; inline
 148
 149 : malloc-byte-array ( byte-array -- alien )
 150     dup length dup malloc [ -rot memcpy ] keep ;
 151
 152 : memory>byte-array ( alien len -- byte-array )
 153     dup <byte-array> [ -rot memcpy ] keep ;
 154
 155 : byte-array>memory ( byte-array base -- )
 156     swap dup length memcpy ;
 157
 158 : (define-nth) ( word type quot -- )
 159     >r heap-size [ rot * ] swap prefix r> append define-inline ;
 160
 161 : nth-word ( name vocab -- word )
 162     >r "-nth" append r> create ;
 163
 164 : define-nth ( name vocab -- )
 165     dupd nth-word swap dup c-getter (define-nth) ;
 166
 167 : set-nth-word ( name vocab -- word )
 168     >r "set-" swap "-nth" 3append r> create ;
 169
 170 : define-set-nth ( name vocab -- )
 171     dupd set-nth-word swap dup c-setter (define-nth) ;
 172
 173 : typedef ( old new -- ) c-types get set-at ;
 174
 175 : define-c-type ( type name vocab -- )
 176     >r tuck typedef r> [ define-nth ] 2keep define-set-nth ;
 177
 178 TUPLE: long-long-type < c-type ;
 179
 180 : <long-long-type> ( -- type )
 181     long-long-type new-c-type ;
 182
 183 M: long-long-type unbox-parameter ( n type -- )
 184     c-type-unboxer %unbox-long-long ;
 185
 186 M: long-long-type unbox-return ( type -- )
 187     f swap unbox-parameter ;
 188
 189 M: long-long-type box-parameter ( n type -- )
 190     c-type-boxer %box-long-long ;
 191
 192 M: long-long-type box-return ( type -- )
 193     f swap box-parameter ;
 194
 195 : define-deref ( name vocab -- )
 196     >r dup CHAR: * prefix r> create
 197     swap c-getter 0 prefix define-inline ;
 198
 199 : define-out ( name vocab -- )
 200     over [ <c-object> tuck 0 ] over c-setter append swap
 201     >r >r constructor-word r> r> prefix define-inline ;
 202
 203 : c-bool> ( int -- ? )
 204     zero? not ;
 205
 206 : >c-array ( seq type word -- )
 207     >r >r dup length dup r> <c-array> dup -roll r>
 208     [ execute ] 2curry 2each ; inline
 209
 210 : >c-array-quot ( type vocab -- quot )
 211     dupd set-nth-word [ >c-array ] 2curry ;
 212
 213 : to-array-word ( name vocab -- word )
 214     >r ">c-" swap "-array" 3append r> create ;
 215
 216 : define-to-array ( type vocab -- )
 217     [ to-array-word ] 2keep >c-array-quot
 218     (( array -- byte-array )) define-declared ;
 219
 220 : c-array>quot ( type vocab -- quot )
 221     [
 222         \ swap ,
 223         nth-word 1quotation ,
 224         [ curry map ] %
 225     ] [ ] make ;
 226
 227 : from-array-word ( name vocab -- word )
 228     >r "c-" swap "-array>" 3append r> create ;
 229
 230 : define-from-array ( type vocab -- )
 231     [ from-array-word ] 2keep c-array>quot
 232     (( c-ptr n -- array )) define-declared ;
 233
 234 : define-primitive-type ( type name -- )
 235     "alien.c-types"
 236     {
 237         [ define-c-type ]
 238         [ define-deref ]
 239         [ define-to-array ]
 240         [ define-from-array ]
 241         [ define-out ]
 242     } 2cleave ;
 243
 244 : expand-constants ( c-type -- c-type' )
 245     #! We use word-def call instead of execute to get around
 246     #! staging violations
 247     dup array? [
 248         unclip >r [ dup word? [ word-def call ] when ] map
 249         r> prefix
 250     ] when ;
 251
 252 : malloc-file-contents ( path -- alien len )
 253     binary file-contents dup malloc-byte-array swap length ;
 254
 255 [
 256     <c-type>
 257         [ alien-cell ] >>getter
 258         [ set-alien-cell ] >>setter
 259         bootstrap-cell >>size
 260         bootstrap-cell >>align
 261         "box_alien" >>boxer
 262         "alien_offset" >>unboxer
 263     "void*" define-primitive-type
 264
 265     <long-long-type>
 266         [ alien-signed-8 ] >>getter
 267         [ set-alien-signed-8 ] >>setter
 268         8 >>size
 269         8 >>align
 270         "box_signed_8" >>boxer
 271         "to_signed_8" >>unboxer
 272     "longlong" define-primitive-type
 273
 274     <long-long-type>
 275         [ alien-unsigned-8 ] >>getter
 276         [ set-alien-unsigned-8 ] >>setter
 277         8 >>size
 278         8 >>align
 279         "box_unsigned_8" >>boxer
 280         "to_unsigned_8" >>unboxer
 281     "ulonglong" define-primitive-type
 282
 283     <c-type>
 284         [ alien-signed-cell ] >>getter
 285         [ set-alien-signed-cell ] >>setter
 286         bootstrap-cell >>size
 287         bootstrap-cell >>align
 288         "box_signed_cell" >>boxer
 289         "to_fixnum" >>unboxer
 290     "long" define-primitive-type
 291
 292     <c-type>
 293         [ alien-unsigned-cell ] >>getter
 294         [ set-alien-unsigned-cell ] >>setter
 295         bootstrap-cell >>size
 296         bootstrap-cell >>align
 297         "box_unsigned_cell" >>boxer
 298         "to_cell" >>unboxer
 299     "ulong" define-primitive-type
 300
 301     <c-type>
 302         [ alien-signed-4 ] >>getter
 303         [ set-alien-signed-4 ] >>setter
 304         4 >>size
 305         4 >>align
 306         "box_signed_4" >>boxer
 307         "to_fixnum" >>unboxer
 308     "int" define-primitive-type
 309
 310     <c-type>
 311         [ alien-unsigned-4 ] >>getter
 312         [ set-alien-unsigned-4 ] >>setter
 313         4 >>size
 314         4 >>align
 315         "box_unsigned_4" >>boxer
 316         "to_cell" >>unboxer
 317     "uint" define-primitive-type
 318
 319     <c-type>
 320         [ alien-signed-2 ] >>getter
 321         [ set-alien-signed-2 ] >>setter
 322         2 >>size
 323         2 >>align
 324         "box_signed_2" >>boxer
 325         "to_fixnum" >>unboxer
 326     "short" define-primitive-type
 327
 328     <c-type>
 329         [ alien-unsigned-2 ] >>getter
 330         [ set-alien-unsigned-2 ] >>setter
 331         2 >>size
 332         2 >>align
 333         "box_unsigned_2" >>boxer
 334         "to_cell" >>unboxer
 335     "ushort" define-primitive-type
 336
 337     <c-type>
 338         [ alien-signed-1 ] >>getter
 339         [ set-alien-signed-1 ] >>setter
 340         1 >>size
 341         1 >>align
 342         "box_signed_1" >>boxer
 343         "to_fixnum" >>unboxer
 344     "char" define-primitive-type
 345
 346     <c-type>
 347         [ alien-unsigned-1 ] >>getter
 348         [ set-alien-unsigned-1 ] >>setter
 349         1 >>size
 350         1 >>align
 351         "box_unsigned_1" >>boxer
 352         "to_cell" >>unboxer
 353     "uchar" define-primitive-type
 354
 355     <c-type>
 356         [ alien-unsigned-4 zero? not ] >>getter
 357         [ 1 0 ? set-alien-unsigned-4 ] >>setter
 358         4 >>size
 359         4 >>align
 360         "box_boolean" >>boxer
 361         "to_boolean" >>unboxer
 362     "bool" define-primitive-type
 363
 364     <c-type>
 365         [ alien-float ] >>getter
 366         [ >r >r >float r> r> set-alien-float ] >>setter
 367         4 >>size
 368         4 >>align
 369         "box_float" >>boxer
 370         "to_float" >>unboxer
 371         single-float-regs >>reg-class
 372         [ >float ] >>unboxer-quot
 373     "float" define-primitive-type
 374
 375     <c-type>
 376         [ alien-double ] >>getter
 377         [ >r >r >float r> r> set-alien-double ] >>setter
 378         8 >>size
 379         8 >>align
 380         "box_double" >>boxer
 381         "to_double" >>unboxer
 382         double-float-regs >>reg-class
 383         [ >float ] >>unboxer-quot
 384     "double" define-primitive-type
 385
 386     os winnt? cpu x86.64? and "longlong" "long" ? "ptrdiff_t" typedef
 387
 388     "ulong" "size_t" typedef
 389 ] with-compilation-unit