core/arrays/arrays.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel math sequences sequences.private ;
   4 IN: arrays
   5
   6 M: array clone (clone) ; inline
   7 M: array length length>> ; inline
   8 M: array nth-unsafe [ integer>fixnum ] dip array-nth ; inline
   9 M: array set-nth-unsafe [ integer>fixnum ] dip set-array-nth ; inline
  10 M: array resize resize-array ; inline
  11 M: array equal? over array? [ sequence= ] [ 2drop f ] if ;
  12 M: object new-sequence drop 0 <array> ; inline
  13 M: f new-sequence drop [ f ] [ 0 <array> ] if-zero ; inline
  14
  15 INSTANCE: array sequence
  16
  17 : >array ( seq -- array ) { } clone-like ;
  18 : 1array ( x -- array ) 1 swap <array> ; inline
  19 : 2array ( x y -- array ) { } 2sequence ; inline
  20 : 3array ( x y z -- array ) { } 3sequence ; inline
  21 : 4array ( w x y z -- array ) { } 4sequence ; inline
  22
  23 PREDICATE: pair < array length 2 number= ;