core/arrays/arrays.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.private
   4 sequences sequences.private ;
   5 IN: arrays
   6
   7 M: array clone (clone) ; inline
   8 M: array length length>> ; inline
   9 M: array nth-unsafe [ >fixnum ] dip array-nth ; inline
  10 M: array set-nth-unsafe [ >fixnum ] dip set-array-nth ; inline
  11 M: array resize resize-array ; inline
  12 M: array equal? over array? [ sequence= ] [ 2drop f ] if ;
  13 M: object new-sequence drop 0 <array> ; inline
  14 M: f new-sequence drop [ f ] [ 0 <array> ] if-zero ; inline
  15
  16 INSTANCE: array sequence
  17
  18 : >array ( seq -- array ) { } clone-like ;
  19 : 1array ( x -- array ) 1 swap <array> ; inline
  20 : 2array ( x y -- array ) { } 2sequence ; inline
  21 : 3array ( x y z -- array ) { } 3sequence ; inline
  22 : 4array ( w x y z -- array ) { } 4sequence ; inline
  23
  24 PREDICATE: pair < array length 2 number= ;