core/assocs/assocs-docs.factor

   1 ! Copyright (C) 2007, 2009 Daniel Ehrenberg, Slava Pestov, and Doug Coleman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: help.markup help.syntax kernel sequences
   4 sequences.private namespaces math quotations assocs.private ;
   5 IN: assocs
   6
   7 ARTICLE: "alists" "Association lists"
   8 "An " { $emphasis "association list" } ", abbreviated " { $emphasis "alist" } ", is an association represented as a sequence where all elements are key/value pairs. The " { $link sequence } " mixin is an instance of the " { $link assoc } " mixin, hence all sequences support the " { $link "assocs-protocol" } " in this way."
   9 $nl
  10 "While not an association list, note that " { $link f } " also implements the associative mapping protocol in a trivial way; it is an immutable assoc with no entries."
  11 $nl
  12 "An alist is slower to search than a hashtable for a large set of associations. The main advantage of an association list is that the elements are ordered; also sometimes it is more convenient to construct an association list with sequence words than to construct a hashtable with association words. Much of the time, hashtables are more appropriate. See " { $link "hashtables" } "."
  13 $nl
  14 "There is no special syntax for literal alists since they are just sequences; in practice, literals look like so:"
  15 { $code "{" "    { key1 value1 }" "    { key2 value2 }" "}" }
  16 "To make an assoc into an alist:"
  17 { $subsection >alist } ;
  18
  19 ARTICLE: "enums" "Enumerations"
  20 "An enumeration provides a view of a sequence as an assoc mapping integer indices to elements:"
  21 { $subsection enum }
  22 { $subsection <enum> }
  23 "Inverting a permutation using enumerations:"
  24 { $example "IN: scratchpad" ": invert ( perm -- perm' )" "    <enum> >alist sort-values keys ;" "{ 2 0 4 1 3 } invert ." "{ 1 3 0 4 2 }" } ;
  25
  26 HELP: enum
  27 { $class-description "An associative structure which wraps a sequence and maps integers to the corresponding elements of the sequence."
  28 $nl
  29 "Enumerations are mutable; note that deleting a key calls " { $link delete-nth } ", which results in all subsequent elements being shifted down." } ;
  30
  31 HELP: <enum>
  32 { $values { "seq" sequence } { "enum" enum } }
  33 { $description "Creates a new enumeration." } ;
  34
  35 ARTICLE: "assocs-protocol" "Associative mapping protocol"
  36 "All associative mappings must be instances of a mixin class:"
  37 { $subsection assoc }
  38 { $subsection assoc? }
  39 "All associative mappings must implement methods on the following generic words:"
  40 { $subsection at* }
  41 { $subsection assoc-size }
  42 { $subsection >alist }
  43 "Mutable assocs should implement the following additional words:"
  44 { $subsection set-at }
  45 { $subsection delete-at }
  46 { $subsection clear-assoc }
  47 "The following three words are optional:"
  48 { $subsection value-at* }
  49 { $subsection new-assoc }
  50 { $subsection assoc-like }
  51 "Assocs should also implement methods on the " { $link clone } ", " { $link equal? } " and " { $link hashcode* } " generic words. Two utility words will help with the implementation of the last two:"
  52 { $subsection assoc= }
  53 { $subsection assoc-hashcode }
  54 "Finally, assoc classes should define a word for converting other types of assocs; conventionally, such words are named " { $snippet ">" { $emphasis "class" } } " where " { $snippet { $emphasis "class" } } " is the class name. Such a word can be implemented using a utility:"
  55 { $subsection assoc-clone-like } ;
  56
  57 ARTICLE: "assocs-lookup" "Lookup and querying of assocs"
  58 "Utility operations built up from the " { $link "assocs-protocol" } ":"
  59 { $subsection key? }
  60 { $subsection at }
  61 { $subsection ?at }
  62 { $subsection assoc-empty? }
  63 { $subsection keys }
  64 { $subsection values }
  65 { $subsection assoc-stack }
  66 { $see-also at* assoc-size } ;
  67
  68 ARTICLE: "assocs-values" "Transposed assoc operations"
  69 "default Most assoc words take a key and find the corresponding value. The following words take a value and find the corresponding key:"
  70 { $subsection value-at }
  71 { $subsection value-at* }
  72 { $subsection value? }
  73 "With most assoc implementations, these words runs in linear time, proportional to the number of entries in the assoc. For fast value lookups, use " { $vocab-link "biassocs" } "." ;
  74
  75 ARTICLE: "assocs-sets" "Set-theoretic operations on assocs"
  76 "It is often useful to use the keys of an associative mapping as a set, exploiting the constant or logarithmic lookup time of most implementations (" { $link "alists" } " being a notable exception)."
  77 { $subsection assoc-subset? }
  78 { $subsection assoc-intersect }
  79 { $subsection update }
  80 { $subsection assoc-union }
  81 { $subsection assoc-diff }
  82 { $subsection remove-all }
  83 { $subsection substitute }
  84 { $subsection substitute-here }
  85 { $subsection extract-keys }
  86 { $see-also key? assoc-any? assoc-all? "sets" } ;
  87
  88 ARTICLE: "assocs-mutation" "Storing keys and values in assocs"
  89 "Utility operations built up from the " { $link "assocs-protocol" } ":"
  90 { $subsection delete-at* }
  91 { $subsection rename-at }
  92 { $subsection change-at }
  93 { $subsection at+ }
  94 { $subsection inc-at }
  95 { $see-also set-at delete-at clear-assoc push-at } ;
  96
  97 ARTICLE: "assocs-conversions" "Associative mapping conversions"
  98 "Converting to other assocs:"
  99 { $subsection assoc-clone-like }
 100 "Combining a sequence of assocs into a single assoc:"
 101 { $subsection assoc-combine }
 102 "Creating an assoc from key/value sequences:"
 103 { $subsection zip }
 104 "Creating key/value sequences from an assoc:"
 105 { $subsection unzip }
 106 ;
 107
 108 ARTICLE: "assocs-combinators" "Associative mapping combinators"
 109 "The following combinators can be used on any associative mapping."
 110 $nl
 111 "The " { $link assoc-find } " combinator is part of the " { $link "assocs-protocol" } " and must be implemented once for each class of assoc. All other combinators are implemented in terms of this combinator."
 112 $nl
 113 "The standard functional programming idioms:"
 114 { $subsection assoc-each }
 115 { $subsection assoc-find }
 116 { $subsection assoc-map }
 117 { $subsection assoc-filter }
 118 { $subsection assoc-filter-as }
 119 { $subsection assoc-any? }
 120 { $subsection assoc-all? }
 121 "Additional combinators:"
 122 { $subsection assoc-partition }
 123 { $subsection cache }
 124 { $subsection map>assoc }
 125 { $subsection assoc>map }
 126 { $subsection assoc-map-as } ;
 127
 128 ARTICLE: "assocs" "Associative mapping operations"
 129 "An " { $emphasis "associative mapping" } ", abbreviated " { $emphasis "assoc" } ", is a collection of key/value pairs which provides efficient lookup and storage indexed by key."
 130 $nl
 131 "Words used for working with assocs are in the " { $vocab-link "assocs" } " vocabulary."
 132 $nl
 133 "Associative mappings implement a protocol:"
 134 { $subsection "assocs-protocol" }
 135 "A large set of utility words work on any object whose class implements the associative mapping protocol."
 136 { $subsection "assocs-lookup" }
 137 { $subsection "assocs-values" }
 138 { $subsection "assocs-mutation" }
 139 { $subsection "assocs-combinators" }
 140 { $subsection "assocs-sets" }
 141 { $subsection "assocs-conversions" } ;
 142
 143 ABOUT: "assocs"
 144
 145 HELP: assoc
 146 { $class-description "A mixin class whose instances are associative mappings. Custom implementations of the assoc protocol should be declared as instances of this mixin for all assoc functionality to work correctly:"
 147     { $code "INSTANCE: avl-tree assoc" }
 148 } ;
 149
 150 HELP: at*
 151 { $values { "key" "an object to look up in the assoc" } { "assoc" assoc } { "value/f" "the value associated to the key, or " { $link f } " if the key is not present in the assoc" } { "?" "a boolean indicating if the key was present" } }
 152 { $contract "Looks up the value associated with a key. The boolean flag can decide between the case of a missing value, and a value of " { $link f } "." } ;
 153
 154 HELP: set-at
 155 { $values { "value" "a value" } { "key" "a key to add" } { "assoc" assoc } }
 156 { $contract "Stores the key/value pair into the assoc." }
 157 { $side-effects "assoc" } ;
 158
 159 HELP: new-assoc
 160 { $values { "capacity" "a non-negative integer" } { "exemplar" assoc } { "newassoc" assoc } }
 161 { $contract "Creates a new assoc of the same size as " { $snippet "exemplar" } " which can hold " { $snippet "capacity" } " entries before growing." } ;
 162
 163 HELP: assoc-find
 164 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- ? )" } } { "key" "the successful key, or f" } { "value" "the successful value, or f" } { "?" "a boolean" } }
 165 { $description "Applies a predicate quotation to each entry in the assoc. Returns the key and value that the quotation succeeds on, or " { $link f } " for both if the quotation fails. It also returns a boolean describing whether there was anything found; this can be used to distinguish between a key and a value equal to " { $link f } ", or nothing being found." } ;
 166
 167 HELP: clear-assoc
 168 { $values { "assoc" assoc } }
 169 { $contract "Removes all entries from the assoc."  }
 170 { $side-effects "assoc" } ;
 171
 172 HELP: delete-at
 173 { $values { "key" "a key" } { "assoc" assoc } }
 174 { $contract "Removes an entry from the assoc." }
 175 { $side-effects "assoc" } ;
 176
 177 HELP: assoc-size
 178 { $values { "assoc" assoc } { "n" "a non-negative integer" } }
 179 { $contract "Outputs the number of entries stored in the assoc." } ;
 180
 181 HELP: assoc-like
 182 { $values { "assoc" assoc } { "exemplar" assoc } { "newassoc" "a new assoc" } }
 183 { $contract "Creates a new assoc having the same entries as  "{ $snippet "assoc" } " and the same type as " { $snippet "exemplar" } "." } ;
 184
 185 HELP: assoc-empty?
 186 { $values { "assoc" assoc } { "?" "a boolean" } }
 187 { $description "Tests if the assoc contains no entries." } ;
 188
 189 HELP: key?
 190 { $values { "key" object } { "assoc" assoc } { "?" "a boolean" } }
 191 { $description "Tests if an assoc contains a key." } ;
 192
 193 { at at* key? ?at } related-words
 194
 195 HELP: at
 196 { $values { "key" "an object" } { "assoc" assoc } { "value/f" "the value associated to the key, or " { $link f } " if the key is not present in the assoc" } }
 197 { $description "Looks up the value associated with a key. This word makes no distinction between a missing value and a value set to " { $link f } "; if the difference is important, use " { $link at* } "." } ;
 198
 199 HELP: ?at
 200 { $values { "key" "an object" } { "assoc" assoc } { "value/key" "the value associated to the key, or the key if the key is not present in the assoc" } { "?" "a boolean" } }
 201 { $description "Looks up the value associated with a key. If the key was not present, an error can be thrown without extra stack shuffling. This word handles assocs that store " { $link f } "." } ;
 202
 203 HELP: assoc-each
 204 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- )" } } }
 205 { $description "Applies a quotation to each entry in the assoc." }
 206 { $examples
 207     { $example
 208         "USING: assocs kernel math prettyprint ;"
 209         "H{ { \"bananas\" 5 } { \"apples\" 42 } { \"pears\" 17 } }"
 210         "0 swap [ nip + ] assoc-each ."
 211         "64"
 212     }
 213 } ;
 214
 215 HELP: assoc-map
 216 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- newkey newvalue )" } } { "newassoc" "a new assoc" } }
 217 { $description "Applies the quotation to each entry in the input assoc and collects the results in a new assoc of the same type as the input." }
 218 { $examples
 219     { $unchecked-example
 220         ": discount ( prices n -- newprices )"
 221         "    [ - ] curry assoc-map ;"
 222         "H{ { \"bananas\" 5 } { \"apples\" 42 } { \"pears\" 17 } }"
 223         "2 discount ."
 224         "H{ { \"bananas\" 3 } { \"apples\" 39 } { \"pears\" 15 } }"
 225     }
 226 } ;
 227
 228 { assoc-map assoc-map-as } related-words
 229
 230 HELP: assoc-filter
 231 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- ? )" } } { "subassoc" "a new assoc" } }
 232 { $description "Outputs an assoc of the same type as " { $snippet "assoc" } " consisting of all entries for which the predicate quotation yields true." } ;
 233
 234 HELP: assoc-filter-as
 235 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- ? )" } } { "exemplar" assoc } { "subassoc" "a new assoc" } }
 236 { $description "Outputs an assoc of the same type as " { $snippet "exemplar" } " consisting of all entries for which the predicate quotation yields true." } ;
 237
 238 { assoc-filter assoc-filter-as } related-words
 239
 240 HELP: assoc-any?
 241 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- ? )" } } { "?" "a boolean" } }
 242 { $description "Tests if the assoc contains an entry satisfying a predicate by applying the quotation to each entry in turn. Iteration stops if an entry is found for which the quotation outputs a true value." } ;
 243
 244 HELP: assoc-all?
 245 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- ? )" } } { "?" "a boolean" } }
 246 { $description "Tests if all entries in the assoc satisfy a predicate by applying the quotation to each entry in turn. a predicate quotation to entry in the assoc. Iteration stops if an entry is found for which the quotation outputs " { $link f } ". If the assoc is empty, always outputs " { $link t } "." } ;
 247
 248 HELP: assoc-subset?
 249 { $values { "assoc1" assoc } { "assoc2" assoc } { "?" "a new assoc" } }
 250 { $description "Tests if " { $snippet "assoc2" } " contains all key/value pairs of " { $snippet "assoc1" } "." } ;
 251
 252 HELP: assoc=
 253 { $values { "assoc1" assoc } { "assoc2" assoc } { "?" "a boolean" } }
 254 { $description "Tests if two assocs contain the same entries. Unlike " { $link = } ", the two assocs may be of different types." }
 255 { $notes "Assoc implementations should define a method for the " { $link equal? } " generic word which calls this word after checking that both inputs have the same type." } ;
 256
 257 HELP: assoc-hashcode
 258 { $values { "n" "a non-negative integer" } { "assoc" assoc } { "code" integer } }
 259 { $description "Computes a hashcode for an assoc, such that equal assocs will have the same hashcode." }
 260 { $notes "Custom assoc implementations should use this word to implement a method for the " { $link hashcode* } " generic word." } ;
 261
 262 HELP: assoc-stack
 263 { $values { "key" "a key" } { "seq" "a sequence of assocs" } { "value" "a value or " { $link f } } }
 264 { $description "Searches for the key in successive elements of the sequence, starting from the end. If an assoc containing the key is found, the associated value is output. If no assoc contains the key, outputs " { $link f } "." }
 265 { $notes "This word is used to implement abstractions such as nested scopes; if the sequence is a stack represented by a vector, then the most recently pushed assoc -- the innermost scope -- will be searched first." } ;
 266
 267 HELP: value-at*
 268 { $values { "value" "an object" } { "assoc" assoc } { "key/f" "the key associated to the value, or " { $link f } } { "?" "a boolean" } }
 269 { $description "Looks up the key associated with a value. The boolean flag can decide beteen the case of a missing key, and a key of " { $link f } "." } ;
 270
 271 HELP: value-at
 272 { $values { "value" "an object" } { "assoc" assoc } { "key/f" "the key associated to the value, or " { $link f } } }
 273 { $description "Looks up the key associated with a value. No distinction is made between a missing key and a key set to " { $link f } "." } ;
 274
 275 HELP: value?
 276 { $values { "value" "an object" } { "assoc" assoc } { "?" "a boolean" } }
 277 { $description "Tests if an assoc contains at least one key with the given value." } ;
 278
 279 HELP: delete-at*
 280 { $values { "key" "a key" } { "assoc" assoc } { "old" "the previous value or " { $link f } } { "?" "a boolean" } }
 281 { $description "Removes an entry from the assoc and outputs the previous value together with a boolean indicating whether it was present." }
 282 { $side-effects "assoc" } ;
 283
 284 HELP: rename-at
 285 { $values { "newkey" object } { "key" object } { "assoc" assoc } }
 286 { $description "Removes the values associated to " { $snippet "key" } " and re-adds it as " { $snippet "newkey" } ". Does nothing if the assoc does not contain " { $snippet "key" } "." }
 287 ;
 288
 289 HELP: keys
 290 { $values { "assoc" assoc } { "keys" "an array of keys" } }
 291 { $description "Outputs an array of all keys in the assoc." } ;
 292
 293 HELP: values
 294 { $values { "assoc" assoc } { "values" "an array of values" } }
 295 { $description "Outputs an array of all values in the assoc." } ;
 296
 297 { keys values } related-words
 298
 299 HELP: assoc-intersect
 300 { $values { "assoc1" assoc } { "assoc2" assoc } { "intersection" "a new assoc" } }
 301 { $description "Outputs an assoc consisting of all entries from " { $snippet "assoc2" } " such that the key is also present in " { $snippet "assoc1" } "." }
 302 { $notes "The values of the keys in " { $snippet "assoc1" } " are disregarded, so this word is usually used for set-theoretic calculations where the assoc in question either has dummy sentinels as values, or the values equal the keys." } ;
 303
 304 HELP: update
 305 { $values { "assoc1" assoc } { "assoc2" assoc } }
 306 { $description "Adds all entries from " { $snippet "assoc2" } " to " { $snippet "assoc1" } "." }
 307 { $side-effects "assoc1" } ;
 308
 309 HELP: assoc-union
 310 { $values { "assoc1" assoc } { "assoc2" assoc } { "union" "a new assoc" } }
 311 { $description "Outputs a assoc consisting of all entries from " { $snippet "assoc1" } " and " { $snippet "assoc2" } ", with entries from " { $snippet "assoc2" } " taking precedence in case the corresponding values are not equal." } ;
 312
 313 HELP: assoc-diff
 314 { $values { "assoc1" assoc } { "assoc2" assoc } { "diff" "a new assoc" } }
 315 { $description "Outputs an assoc consisting of all entries from " { $snippet "assoc1" } " whose key is not contained in " { $snippet "assoc2" } "." }
 316 ;
 317 HELP: remove-all
 318 { $values { "assoc" assoc } { "seq" "a sequence" } { "subseq" "a new sequence" } }
 319 { $description "Constructs a sequence consisting of all elements in " { $snippet "seq" } " which do not appear as keys in " { $snippet "assoc" } "." }
 320 { $notes "The values of the keys in the assoc are disregarded, so this word is usually used for set-theoretic calculations where the assoc in question either has dummy sentinels as values, or the values equal the keys." }
 321 { $side-effects "assoc" } ;
 322
 323 HELP: substitute-here
 324 { $values { "seq" "a mutable sequence" } { "assoc" assoc } }
 325 { $description "Replaces elements of " { $snippet "seq" } " which appear as keys in " { $snippet "assoc" } " with the corresponding values, acting as the identity on all other elements." }
 326 { $errors "Throws an error if " { $snippet "assoc" } " contains values whose types are not permissible in " { $snippet "seq" } "." }
 327 { $side-effects "seq" } ;
 328
 329 HELP: substitute
 330 { $values { "seq" sequence } { "assoc" assoc } { "newseq" sequence } }
 331 { $description "Creates a new sequence where elements of " { $snippet "seq" } " which appear as keys in " { $snippet "assoc" } " are replaced by the corresponding values, and all other elements are unchanged." } ;
 332
 333 HELP: cache
 334 { $values { "key" "a key" } { "assoc" assoc } { "quot" { $quotation "( key -- value )" } } { "value" "a previously-retained or freshly-computed value" } }
 335 { $description "If the key is present in the assoc, outputs the associated value, otherwise calls the quotation to produce a value and stores the key/value pair into the assoc." }
 336 { $side-effects "assoc" } ;
 337
 338 HELP: map>assoc
 339 { $values { "seq" "a sequence" } { "quot" { $quotation "( elt -- key value )" } } { "exemplar" assoc } { "assoc" "a new assoc" } }
 340 { $description "Applies the quotation to each element of the sequence, and collects the keys and values into a new assoc having the same type as " { $snippet "exemplar" } "." } ;
 341
 342 HELP: assoc>map
 343 { $values { "assoc" assoc } { "quot" { $quotation "( key value -- elt )" } } { "exemplar" "a sequence" } { "seq" "a new sequence" } }
 344 { $description "Applies the quotation to each entry of the assoc and collects the results into a new sequence of the same type as the exemplar." } ;
 345
 346 HELP: change-at
 347 { $values { "key" object } { "assoc" assoc } { "quot" { $quotation "( value -- newvalue )" } } }
 348 { $description "Applies the quotation to the value associated with " { $snippet "key" } ", storing the new value back in the assoc." }
 349 { $side-effects "assoc" } ;
 350
 351 { change-at change-nth change } related-words
 352
 353 HELP: at+
 354 { $values { "n" number } { "key" object } { "assoc" assoc } }
 355 { $description "Adds " { $snippet "n" } " to the value associated with " { $snippet "key" } "; if there is no value, stores " { $snippet "n" } ", thus behaving as if the value was 0." }
 356 { $side-effects "assoc" } ;
 357
 358 HELP: inc-at
 359 { $values { "key" object } { "assoc" assoc } }
 360 { $description "Adds 1 to the value associated with " { $snippet "key" } "; if there is no value, stores 1." }
 361 { $side-effects "assoc" } ;
 362
 363 HELP: >alist
 364 { $values { "assoc" assoc } { "newassoc" "an array of key/value pairs" } }
 365 { $contract "Converts an associative structure into an association list." } ;
 366
 367 HELP: assoc-clone-like
 368 { $values
 369      { "assoc" assoc } { "exemplar" assoc }
 370      { "newassoc" assoc } }
 371 { $description "Outputs a newly-allocated assoc with the same elements as " { $snippet "assoc" } "." }
 372 { $examples { $example "USING: prettyprint assocs hashtables ;" "H{ { 1 2 } { 3 4 } } { } assoc-clone-like ." "{ { 1 2 } { 3 4 } }" } } ;
 373
 374 HELP: assoc-combine
 375 { $values
 376      { "seq" "a sequence of assocs" }
 377      { "union" assoc } }
 378 { $description "Takes the union of all of the " { $snippet "assocs" } " in " { $snippet "seq" } "." }
 379 { $examples { $example "USING: prettyprint assocs ;" "{ H{ { 1 2 } } H{ { 3 4 } } } assoc-combine ." "H{ { 1 2 } { 3 4 } }" } } ;
 380
 381 HELP: assoc-map-as
 382 { $values
 383      { "assoc" assoc } { "quot" quotation } { "exemplar" assoc }
 384      { "newassoc" assoc } }
 385 { $description "Applies the quotation to each entry in the input assoc and collects the results in a new assoc of the stame type as the exemplar." }
 386 { $examples { $example "USING: prettyprint assocs hashtables math ;" " H{ { 1 2 } { 3 4 } } [ sq ] { } assoc-map-as ." "{ { 1 4 } { 3 16 } }" } } ;
 387
 388 HELP: extract-keys
 389 { $values
 390      { "seq" sequence } { "assoc" assoc }
 391      { "subassoc" assoc } }
 392 { $description "Outputs an new " { $snippet "assoc" } " with key/value pairs whose keys match the elements in the input " { $snippet "seq" } "." }
 393 { $examples
 394     { $example "USING: prettyprint assocs ;"
 395                "{ 1 3 } { { 1 10 } { 2 20 } { 3 30 } } extract-keys ."
 396                "{ { 1 10 } { 3 30 } }"
 397     }
 398 } ;
 399
 400 HELP: push-at
 401 { $values
 402      { "value" object } { "key" object } { "assoc" assoc } }
 403 { $description "Pushes the " { $snippet "value" } " onto a " { $snippet "vector" } " stored at the " { $snippet "key" } " in the " { $snippet "assoc" } ". If the " { $snippet "key" } " does not yet exist, creates a new " { $snippet "vector" } " at that " { $snippet "key" } " and pushes the " { $snippet "value" } "." }
 404 { $examples { $example  "USING: prettyprint assocs kernel ;"
 405 "H{ { \"cats\" V{ \"Mittens\" } } } \"Mew\" \"cats\" pick push-at ."
 406 "H{ { \"cats\" V{ \"Mittens\" \"Mew\" } } }"
 407 } } ;
 408
 409 HELP: search-alist
 410 { $values
 411      { "key" object } { "alist" "an array of key/value pairs" }
 412      { "pair/f" "a key/value pair" } { "i/f" integer } }
 413 { $description "Iterates over " { $snippet "alist" } " and stops when the key is matched or the end of the " { $snippet "alist" } " has been reached. If there is no match, both outputs are " { $link f } "." }
 414 { $notes "This word is used to implement " { $link at* } " and " { $link set-at } " on sequences, and should not be called direclty." }
 415 { $examples { $example "USING: prettyprint assocs.private kernel ;"
 416                         "3 { { 1 2 } { 3 4 } } search-alist [ . ] bi@"
 417                        "{ 3 4 }\n1"
 418             } { $example "USING: prettyprint assocs.private kernel ;"
 419                        "6 { { 1 2 } { 3 4 } } search-alist [ . ] bi@"
 420                        "f\nf"
 421             }
 422 } ;
 423
 424 HELP: unzip
 425 { $values
 426      { "assoc" assoc }
 427      { "keys" sequence } { "values" sequence } }
 428 { $description "Outputs an array of keys and an array of values of the input " { $snippet "assoc" } "." }
 429 { $examples
 430     { $example "USING: prettyprint assocs kernel ;"
 431                "{ { 1 4 } { 2 5 } { 3 6 } } unzip [ . ] bi@"
 432                "{ 1 2 3 }\n{ 4 5 6 }"
 433     }
 434 } ;
 435
 436 HELP: zip
 437 { $values
 438      { "keys" sequence } { "values" sequence }
 439      { "alist" "an array of key/value pairs" } }
 440 { $description "Combines two sequences pairwise into a single sequence of key/value pairs." }
 441 { $examples
 442     { $example "" "USING: prettyprint assocs ;"
 443                "{ 1 2 3 } { 4 5 6 } zip ."
 444                "{ { 1 4 } { 2 5 } { 3 6 } }"
 445     }
 446 } ;
 447 { unzip zip } related-words