core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2010 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math sequences sequences.private
   4 vectors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: value-at* ( value assoc -- key/f ? )
  11 GENERIC: set-at ( value key assoc -- )
  12 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  13 GENERIC: delete-at ( key assoc -- )
  14 GENERIC: clear-assoc ( assoc -- )
  15 GENERIC: assoc-size ( assoc -- n )
  16 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  17 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  18 GENERIC: >alist ( assoc -- newassoc )
  19
  20 M: assoc assoc-like drop ; inline
  21
  22 : ?at ( key assoc -- value/key ? )
  23     2dup at* [ 2nip t ] [ 2drop f ] if ; inline
  24
  25 : maybe-set-at ( value key assoc -- changed? )
  26     3dup at* [ = [ 3drop f ] [ set-at t ] if ] [ 2drop set-at t ] if ;
  27
  28 <PRIVATE
  29
  30 : (assoc-each) ( assoc quot -- seq quot' )
  31     [ >alist ] dip [ first2 ] prepose ; inline
  32
  33 : (assoc-stack) ( key i seq -- value )
  34     over 0 < [
  35         3drop f
  36     ] [
  37         3dup nth-unsafe at*
  38         [ [ 3drop ] dip ] [ drop [ 1 - ] dip (assoc-stack) ] if
  39     ] if ; inline recursive
  40
  41 : search-alist ( key alist -- pair/f i/f )
  42     [ first = ] with find swap ; inline
  43
  44 : substituter ( assoc -- quot )
  45     [ ?at drop ] curry ; inline
  46
  47 : with-assoc ( assoc quot: ( ..a value key assoc -- ..b ) -- quot: ( ..a key value -- ..b ) )
  48     curry [ swap ] prepose ; inline
  49
  50 PRIVATE>
  51
  52 : assoc-find ( ... assoc quot: ( ... key value -- ... ? ) -- ... key value ? )
  53     (assoc-each) find swap [ first2 t ] [ drop f f f ] if ; inline
  54
  55 : key? ( key assoc -- ? ) at* nip ; inline
  56
  57 : assoc-each ( ... assoc quot: ( ... key value -- ... ) -- ... )
  58     (assoc-each) each ; inline
  59
  60 : assoc>map ( ... assoc quot: ( ... key value -- ... elt ) exemplar -- ... seq )
  61     [ >alist ] 2dip [ [ first2 ] prepose ] dip map-as ; inline
  62
  63 : assoc-map-as ( ... assoc quot: ( ... key value -- ... newkey newvalue ) exemplar -- ... newassoc )
  64     [ [ 2array ] compose { } assoc>map ] dip assoc-like ; inline
  65
  66 : assoc-map ( ... assoc quot: ( ... key value -- ... newkey newvalue ) -- ... newassoc )
  67     over assoc-map-as ; inline
  68
  69 : assoc-filter-as ( ... assoc quot: ( ... key value -- ... ? ) exemplar -- ... subassoc )
  70     [ (assoc-each) filter ] dip assoc-like ; inline
  71
  72 : assoc-filter ( ... assoc quot: ( ... key value -- ... ? ) -- ... subassoc )
  73     over assoc-filter-as ; inline
  74
  75 : assoc-filter! ( ... assoc quot: ( ... key value -- ... ? ) -- ... assoc )
  76     [
  77         over [ [ [ drop ] 2bi ] dip [ delete-at ] 2curry unless ] 2curry
  78         assoc-each
  79     ] [ drop ] 2bi ; inline
  80
  81 : sift-keys ( assoc -- assoc' )
  82     [ drop ] assoc-filter ; inline
  83
  84 : sift-values ( assoc -- assoc' )
  85     [ nip ] assoc-filter ; inline
  86
  87 : assoc-partition ( ... assoc quot: ( ... key value -- ... ? ) -- ... true-assoc false-assoc )
  88     [ (assoc-each) partition ] [ drop ] 2bi
  89     [ assoc-like ] curry bi@ ; inline
  90
  91 : assoc-any? ( ... assoc quot: ( ... key value -- ... ? ) -- ... ? )
  92     assoc-find 2nip ; inline
  93
  94 : assoc-all? ( ... assoc quot: ( ... key value -- ... ? ) -- ... ? )
  95     [ not ] compose assoc-any? not ; inline
  96
  97 : at ( key assoc -- value/f )
  98     at* drop ; inline
  99
 100 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
 101     [ dup assoc-size ] dip new-assoc
 102     [ [ set-at ] with-assoc assoc-each ] keep ; inline
 103
 104 : keys ( assoc -- keys )
 105     [ drop ] { } assoc>map ;
 106
 107 : values ( assoc -- values )
 108     [ nip ] { } assoc>map ;
 109
 110 : delete-at* ( key assoc -- old ? )
 111     [ at* ] 2keep delete-at ;
 112
 113 : rename-at ( newkey key assoc -- )
 114     [ delete-at* ] keep [ set-at ] with-assoc [ 2drop ] if ;
 115
 116 : assoc-empty? ( assoc -- ? )
 117     assoc-size 0 = ; inline
 118
 119 : assoc-stack ( key seq -- value )
 120     [ length 1 - ] keep (assoc-stack) ; flushable
 121
 122 : assoc-subset? ( assoc1 assoc2 -- ? )
 123     [ at* [ = ] [ 2drop f ] if ] with-assoc assoc-all? ;
 124
 125 : assoc= ( assoc1 assoc2 -- ? )
 126     2dup [ assoc-size ] bi@ eq? [ assoc-subset? ] [ 2drop f ] if ;
 127
 128 : assoc-hashcode ( n assoc -- code )
 129     >alist hashcode* ;
 130
 131 : assoc-intersect ( assoc1 assoc2 -- intersection )
 132     swap [ nip key? ] curry assoc-filter ;
 133
 134 : assoc-union! ( assoc1 assoc2 -- assoc1 )
 135     over [ set-at ] with-assoc assoc-each ;
 136
 137 : assoc-union ( assoc1 assoc2 -- union )
 138     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 139     [ assoc-union! ] bi@ ;
 140
 141 : assoc-combine ( seq -- union )
 142     H{ } clone [ assoc-union! ] reduce ;
 143
 144 : assoc-refine ( seq -- assoc )
 145     [ f ] [ [ ] [ assoc-intersect ] map-reduce ] if-empty ;
 146
 147 : assoc-differ ( key -- quot )
 148     [ nip key? not ] curry ; inline
 149
 150 : assoc-diff ( assoc1 assoc2 -- diff )
 151     assoc-differ assoc-filter ;
 152
 153 : assoc-diff! ( assoc1 assoc2 -- assoc1 )
 154     assoc-differ assoc-filter! ;
 155
 156 : substitute ( seq assoc -- newseq )
 157     substituter map ;
 158
 159 : cache ( ... key assoc quot: ( ... key -- ... value ) -- ... value )
 160     [ [ at* ] 2keep ] dip
 161     [ [ nip call dup ] [ drop ] 3bi set-at ] 3curry
 162     [ drop ] prepose
 163     unless ; inline
 164
 165 : 2cache ( ... key1 key2 assoc quot: ( ... key1 key2 -- ... value ) -- ... value )
 166     [ 2array ] 2dip [ first2 ] prepose cache ; inline
 167
 168 : change-at ( ..a key assoc quot: ( ..a value -- ..b newvalue ) -- ..b )
 169     [ [ at ] dip call ] [ drop ] 3bi set-at ; inline
 170
 171 : at+ ( n key assoc -- ) [ 0 or + ] change-at ; inline
 172
 173 : inc-at ( key assoc -- ) [ 1 ] 2dip at+ ; inline
 174
 175 : map>assoc ( ... seq quot: ( ... elt -- ... key value ) exemplar -- ... assoc )
 176     dup sequence? [
 177         [ [ 2array ] compose ] dip map-as
 178     ] [
 179         [ over assoc-size ] dip new-assoc
 180         [ [ swapd set-at ] curry compose each ] keep
 181     ] if ; inline
 182
 183 : extract-keys ( seq assoc -- subassoc )
 184     [ [ dupd at ] curry ] keep map>assoc ;
 185
 186 M: assoc value-at* swap [ = nip ] curry assoc-find nip ;
 187
 188 : value-at ( value assoc -- key/f ) value-at* drop ;
 189
 190 : value? ( value assoc -- ? ) value-at* nip ;
 191
 192 : push-at ( value key assoc -- )
 193     [ ?push ] change-at ;
 194
 195 : zip ( keys values -- alist )
 196     [ 2array ] { } 2map-as ; inline
 197
 198 : unzip ( assoc -- keys values )
 199     dup assoc-empty? [ drop { } { } ] [ >alist flip first2 ] if ;
 200
 201 M: sequence at*
 202     search-alist [ second t ] [ f ] if ;
 203
 204 M: sequence set-at
 205     2dup search-alist
 206     [ 2nip set-second ]
 207     [ drop [ swap 2array ] dip push ] if ;
 208
 209 M: sequence new-assoc drop <vector> ; inline
 210
 211 M: sequence clear-assoc delete-all ; inline
 212
 213 M: sequence delete-at
 214     [ nip ] [ search-alist nip ] 2bi
 215     [ swap remove-nth! drop ] [ drop ] if* ;
 216
 217 M: sequence assoc-size length ; inline
 218
 219 M: sequence assoc-clone-like
 220     [ >alist ] dip clone-like ; inline
 221
 222 M: sequence assoc-like
 223     [ >alist ] dip like ; inline
 224
 225 M: sequence >alist ; inline
 226
 227 ! Override sequence => assoc instance for f
 228 M: f at* 2drop f f ; inline
 229
 230 M: f assoc-size drop 0 ; inline
 231
 232 M: f clear-assoc drop ; inline
 233
 234 M: f assoc-like drop dup assoc-empty? [ drop f ] when ; inline
 235
 236 INSTANCE: sequence assoc
 237
 238 TUPLE: enum { seq read-only } ;
 239
 240 C: <enum> enum
 241
 242 M: enum at*
 243     seq>> 2dup bounds-check?
 244     [ nth-unsafe t ] [ 2drop f f ] if ; inline
 245
 246 M: enum set-at seq>> set-nth ; inline
 247
 248 M: enum delete-at seq>> remove-nth! drop ; inline
 249
 250 M: enum >alist ( enum -- alist )
 251     seq>> [ length iota ] keep zip ; inline
 252
 253 M: enum assoc-size seq>> length ; inline
 254
 255 M: enum clear-assoc seq>> delete-all ; inline
 256
 257 INSTANCE: enum assoc