core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2008 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences arrays math sequences.private vectors
   4 accessors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: set-at ( value key assoc -- )
  11 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  12 GENERIC: delete-at ( key assoc -- )
  13 GENERIC: clear-assoc ( assoc -- )
  14 GENERIC: assoc-size ( assoc -- n )
  15 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  16
  17 M: assoc assoc-like drop ;
  18
  19 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  20
  21 GENERIC: >alist ( assoc -- newassoc )
  22
  23 GENERIC# assoc-find 1 ( assoc quot -- key value ? ) inline
  24
  25 M: assoc assoc-find
  26     >r >alist [ first2 ] r> compose find swap
  27     [ first2 t ] [ drop f f f ] if ;
  28
  29 : key? ( key assoc -- ? ) at* nip ; inline
  30
  31 : assoc-each ( assoc quot -- )
  32     [ f ] compose assoc-find 3drop ; inline
  33
  34 : (assoc>map) ( quot accum -- quot' )
  35     [ push ] curry compose ; inline
  36
  37 : assoc>map ( assoc quot exemplar -- seq )
  38     >r over assoc-size
  39     <vector> [ (assoc>map) assoc-each ] keep
  40     r> like ; inline
  41
  42 : assoc-map ( assoc quot -- newassoc )
  43     over >r [ 2array ] compose V{ } assoc>map r> assoc-like ;
  44     inline
  45
  46 : assoc-push-if ( key value quot accum -- )
  47     >r 2keep r> roll
  48     [ >r 2array r> push ] [ 3drop ] if ; inline
  49
  50 : assoc-pusher ( quot -- quot' accum )
  51     V{ } clone [ [ assoc-push-if ] 2curry ] keep ; inline
  52
  53 : assoc-filter ( assoc quot -- subassoc )
  54     over >r assoc-pusher >r assoc-each r> r> assoc-like ; inline
  55
  56 : assoc-contains? ( assoc quot -- ? )
  57     assoc-find 2nip ; inline
  58
  59 : assoc-all? ( assoc quot -- ? )
  60     [ not ] compose assoc-contains? not ; inline
  61
  62 : at ( key assoc -- value/f )
  63     at* drop ; inline
  64
  65 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
  66     over assoc-size swap new-assoc
  67     swap [ swap pick set-at ] assoc-each ;
  68
  69 : keys ( assoc -- keys )
  70     [ drop ] { } assoc>map ;
  71
  72 : values ( assoc -- values )
  73     [ nip ] { } assoc>map ;
  74
  75 : delete-at* ( key assoc -- old ? )
  76     [ at* ] 2keep delete-at ;
  77
  78 : rename-at ( newkey key assoc -- )
  79     tuck delete-at* [ -rot set-at ] [ 3drop ] if ;
  80
  81 : delete-any ( assoc -- key value )
  82     [
  83         [ 2drop t ] assoc-find
  84         [ "Assoc is empty" throw ] unless over
  85     ] keep delete-at ;
  86
  87 : assoc-empty? ( assoc -- ? )
  88     assoc-size zero? ;
  89
  90 : (assoc-stack) ( key i seq -- value )
  91     over 0 < [
  92         3drop f
  93     ] [
  94         3dup nth-unsafe at*
  95         [ >r 3drop r> ] [ drop >r 1- r> (assoc-stack) ] if
  96     ] if ; inline
  97
  98 : assoc-stack ( key seq -- value )
  99     dup length 1- swap (assoc-stack) ;
 100
 101 : assoc-subset? ( assoc1 assoc2 -- ? )
 102     [ swapd at* [ = ] [ 2drop f ] if ] curry assoc-all? ;
 103
 104 : assoc= ( assoc1 assoc2 -- ? )
 105     [ assoc-subset? ] [ swap assoc-subset? ] 2bi and ;
 106
 107 : assoc-hashcode ( n assoc -- code )
 108     [
 109         >r over r> hashcode* 2/ >r dupd hashcode* r> bitxor
 110     ] { } assoc>map hashcode* ;
 111
 112 : assoc-intersect ( assoc1 assoc2 -- intersection )
 113     swap [ nip key? ] curry assoc-filter ;
 114
 115 : update ( assoc1 assoc2 -- )
 116     swap [ swapd set-at ] curry assoc-each ;
 117
 118 : assoc-union ( assoc1 assoc2 -- union )
 119     2dup [ assoc-size ] bi@ + pick new-assoc
 120     [ rot update ] keep [ swap update ] keep ;
 121
 122 : assoc-diff ( assoc1 assoc2 -- diff )
 123     [ nip key? not ] curry assoc-filter ;
 124
 125 : remove-all ( assoc seq -- subseq )
 126     swap [ key? not ] curry filter ;
 127
 128 : (substitute)
 129     [ dupd at* [ nip ] [ drop ] if ] curry ; inline
 130
 131 : substitute-here ( seq assoc -- )
 132     (substitute) change-each ;
 133
 134 : substitute ( seq assoc -- newseq )
 135     (substitute) map ;
 136
 137 : cache ( key assoc quot -- value )
 138     2over at* [
 139         >r 3drop r>
 140     ] [
 141         drop pick rot >r >r call dup r> r> set-at
 142     ] if ; inline
 143
 144 : change-at ( key assoc quot -- )
 145     [ >r at r> call ] 3keep drop set-at ; inline
 146
 147 : at+ ( n key assoc -- )
 148     [ 0 or + ] change-at ;
 149
 150 : map>assoc ( seq quot exemplar -- assoc )
 151     >r [ 2array ] compose { } map-as r> assoc-like ; inline
 152
 153 : extract-keys ( seq assoc -- subassoc )
 154     [ [ dupd at ] curry ] keep map>assoc ;
 155
 156 M: assoc >alist [ 2array ] { } assoc>map ;
 157
 158 : value-at ( value assoc -- key/f )
 159     swap [ = nip ] curry assoc-find 2drop ;
 160
 161 : zip ( keys values -- alist )
 162     2array flip ; inline
 163
 164 : search-alist ( key alist -- pair i )
 165     [ first = ] with find swap ; inline
 166
 167 M: sequence at*
 168     search-alist [ second t ] [ f ] if ;
 169
 170 M: sequence set-at
 171     2dup search-alist
 172     [ 2nip set-second ]
 173     [ drop >r swap 2array r> push ] if ;
 174
 175 M: sequence new-assoc drop <vector> ;
 176
 177 M: sequence clear-assoc delete-all ;
 178
 179 M: sequence delete-at
 180     tuck search-alist nip
 181     [ swap delete-nth ] [ drop ] if* ;
 182
 183 M: sequence assoc-size length ;
 184
 185 M: sequence assoc-clone-like
 186     >r >alist r> clone-like ;
 187
 188 M: sequence assoc-like
 189     over sequence? [ like ] [ assoc-clone-like ] if ;
 190
 191 M: sequence >alist ;
 192
 193 ! Override sequence => assoc instance for f
 194 M: f clear-assoc drop ;
 195
 196 M: f assoc-like drop dup assoc-empty? [ drop f ] when ;
 197
 198 INSTANCE: sequence assoc
 199
 200 TUPLE: enum seq ;
 201
 202 C: <enum> enum
 203
 204 M: enum at*
 205     seq>> 2dup bounds-check?
 206     [ nth t ] [ 2drop f f ] if ;
 207
 208 M: enum set-at seq>> set-nth ;
 209
 210 M: enum delete-at enum-seq delete-nth ;
 211
 212 M: enum >alist ( enum -- alist )
 213     seq>> [ length ] keep zip ;
 214
 215 M: enum assoc-size seq>> length ;
 216
 217 M: enum clear-assoc seq>> delete-all ;
 218
 219 INSTANCE: enum assoc