core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2010 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math sequences sequences.private
   4 vectors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: value-at* ( value assoc -- key/f ? )
  11 GENERIC: set-at ( value key assoc -- )
  12 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  13 GENERIC: delete-at ( key assoc -- )
  14 GENERIC: clear-assoc ( assoc -- )
  15 GENERIC: assoc-size ( assoc -- n )
  16 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  17 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  18 GENERIC: >alist ( assoc -- newassoc )
  19 GENERIC: keys ( assoc -- keys )
  20 GENERIC: values ( assoc -- values )
  21
  22 M: assoc assoc-like drop ; inline
  23
  24 : ?at ( key assoc -- value/key ? )
  25     2dup at* [ 2nip t ] [ 2drop f ] if ; inline
  26
  27 : maybe-set-at ( value key assoc -- changed? )
  28     3dup at* [ = [ 3drop f ] [ set-at t ] if ] [ 2drop set-at t ] if ;
  29
  30 <PRIVATE
  31
  32 : (assoc-each) ( assoc quot -- seq quot' )
  33     [ >alist ] dip [ first2 ] prepose ; inline
  34
  35 : (assoc-stack) ( key i seq -- value )
  36     over 0 < [
  37         3drop f
  38     ] [
  39         3dup nth-unsafe at*
  40         [ [ 3drop ] dip ] [ drop [ 1 - ] dip (assoc-stack) ] if
  41     ] if ; inline recursive
  42
  43 : search-alist ( key alist -- pair/f i/f )
  44     [ first = ] with find swap ; inline
  45
  46 : substituter ( assoc -- quot )
  47     [ ?at drop ] curry ; inline
  48
  49 : with-assoc ( assoc quot: ( ..a value key assoc -- ..b ) -- quot: ( ..a key value -- ..b ) )
  50     curry [ swap ] prepose ; inline
  51
  52 PRIVATE>
  53
  54 : assoc-find ( ... assoc quot: ( ... key value -- ... ? ) -- ... key value ? )
  55     (assoc-each) find swap [ first2-unsafe t ] [ drop f f f ] if ; inline
  56
  57 : key? ( key assoc -- ? ) at* nip ; inline
  58
  59 : assoc-each ( ... assoc quot: ( ... key value -- ... ) -- ... )
  60     (assoc-each) each ; inline
  61
  62 : assoc>map ( ... assoc quot: ( ... key value -- ... elt ) exemplar -- ... seq )
  63     [ (assoc-each) ] dip map-as ; inline
  64
  65 : assoc-map-as ( ... assoc quot: ( ... key value -- ... newkey newvalue ) exemplar -- ... newassoc )
  66     [ [ 2array ] compose { } assoc>map ] dip assoc-like ; inline
  67
  68 : assoc-map ( ... assoc quot: ( ... key value -- ... newkey newvalue ) -- ... newassoc )
  69     over assoc-map-as ; inline
  70
  71 : assoc-filter-as ( ... assoc quot: ( ... key value -- ... ? ) exemplar -- ... subassoc )
  72     [ (assoc-each) filter ] dip assoc-like ; inline
  73
  74 : assoc-filter ( ... assoc quot: ( ... key value -- ... ? ) -- ... subassoc )
  75     over assoc-filter-as ; inline
  76
  77 : assoc-reject-as ( ... assoc quot: ( ... key value -- ... ? ) exemplar -- ... subassoc )
  78     [ [ not ] compose ] [ assoc-filter-as ] bi* ; inline
  79
  80 : assoc-reject ( ... assoc quot: ( ... key value -- ... ? ) -- ... subassoc )
  81     over assoc-reject-as ; inline
  82
  83 : assoc-filter! ( ... assoc quot: ( ... key value -- ... ? ) -- ... assoc )
  84     [
  85         over [ [ [ drop ] 2bi ] dip [ delete-at ] 2curry unless ] 2curry
  86         assoc-each
  87     ] [ drop ] 2bi ; inline
  88
  89 : assoc-reject! ( ... assoc quot: ( ... key value -- ... ? ) -- ... assoc )
  90     [ not ] compose assoc-filter! ; inline
  91
  92 : sift-keys ( assoc -- assoc' )
  93     [ drop ] assoc-filter ; inline
  94
  95 : sift-values ( assoc -- assoc' )
  96     [ nip ] assoc-filter ; inline
  97
  98 : harvest-keys ( assoc -- assoc' )
  99     [ drop empty? ] assoc-reject ; inline
 100
 101 : harvest-values ( assoc -- assoc' )
 102     [ nip empty? ] assoc-reject ; inline
 103
 104 : assoc-partition ( ... assoc quot: ( ... key value -- ... ? ) -- ... true-assoc false-assoc )
 105     [ (assoc-each) partition ] [ drop ] 2bi
 106     [ assoc-like ] curry bi@ ; inline
 107
 108 : assoc-any? ( ... assoc quot: ( ... key value -- ... ? ) -- ... ? )
 109     assoc-find 2nip ; inline
 110
 111 : assoc-all? ( ... assoc quot: ( ... key value -- ... ? ) -- ... ? )
 112     [ not ] compose assoc-any? not ; inline
 113
 114 : at ( key assoc -- value/f )
 115     at* drop ; inline
 116
 117 : ?of ( assoc key -- value/key ? )
 118     swap ?at ; inline
 119
 120 : of ( assoc key -- value/f )
 121     swap at ; inline
 122
 123 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
 124     [ dup assoc-size ] dip new-assoc
 125     [ [ set-at ] with-assoc assoc-each ] keep ; inline
 126
 127 M: assoc keys [ drop ] { } assoc>map ;
 128
 129 M: assoc values [ nip ] { } assoc>map ;
 130
 131 : delete-at* ( key assoc -- old ? )
 132     [ at* ] 2keep delete-at ;
 133
 134 : rename-at ( newkey key assoc -- )
 135     [ delete-at* ] keep [ set-at ] with-assoc [ 2drop ] if ;
 136
 137 : assoc-empty? ( assoc -- ? )
 138     assoc-size 0 = ; inline
 139
 140 : assoc-stack ( key seq -- value )
 141     [ length 1 - ] keep (assoc-stack) ; flushable
 142
 143 : assoc-subset? ( assoc1 assoc2 -- ? )
 144     [ at* [ = ] [ 2drop f ] if ] with-assoc assoc-all? ;
 145
 146 : assoc= ( assoc1 assoc2 -- ? )
 147     2dup [ assoc-size ] bi@ eq? [ assoc-subset? ] [ 2drop f ] if ;
 148
 149 : assoc-hashcode ( n assoc -- code )
 150     >alist hashcode* ;
 151
 152 : assoc-intersect ( assoc1 assoc2 -- intersection )
 153     swap [ nip key? ] curry assoc-filter ;
 154
 155 : assoc-union! ( assoc1 assoc2 -- assoc1 )
 156     over [ set-at ] with-assoc assoc-each ;
 157
 158 : assoc-union ( assoc1 assoc2 -- union )
 159     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 160     [ assoc-union! ] bi@ ;
 161
 162 : assoc-combine ( seq -- union )
 163     H{ } clone [ assoc-union! ] reduce ;
 164
 165 : assoc-refine ( seq -- assoc )
 166     [ f ] [ [ ] [ assoc-intersect ] map-reduce ] if-empty ;
 167
 168 : assoc-differ ( key -- quot )
 169     [ nip key? not ] curry ; inline
 170
 171 : assoc-diff ( assoc1 assoc2 -- diff )
 172     assoc-differ assoc-filter ;
 173
 174 : assoc-diff! ( assoc1 assoc2 -- assoc1 )
 175     assoc-differ assoc-filter! ;
 176
 177 : substitute ( seq assoc -- newseq )
 178     substituter map ;
 179
 180 : cache ( ... key assoc quot: ( ... key -- ... value ) -- ... value )
 181     [ [ at* ] 2keep ] dip
 182     [ [ nip call dup ] [ drop ] 3bi set-at ] 3curry
 183     [ drop ] prepose
 184     unless ; inline
 185
 186 : 2cache ( ... key1 key2 assoc quot: ( ... key1 key2 -- ... value ) -- ... value )
 187     [ 2array ] 2dip [ first2-unsafe ] prepose cache ; inline
 188
 189 : change-at ( ..a key assoc quot: ( ..a value -- ..b newvalue ) -- ..b )
 190     [ [ at ] dip call ] [ drop ] 3bi set-at ; inline
 191
 192 : at+ ( n key assoc -- ) [ 0 or + ] change-at ; inline
 193
 194 : inc-at ( key assoc -- ) [ 1 ] 2dip at+ ; inline
 195
 196 : map>assoc ( ... seq quot: ( ... elt -- ... key value ) exemplar -- ... assoc )
 197     dup sequence? [
 198         [ [ 2array ] compose ] dip map-as
 199     ] [
 200         [ over assoc-size ] dip new-assoc
 201         [ [ swapd set-at ] curry compose each ] keep
 202     ] if ; inline
 203
 204 : extract-keys ( seq assoc -- subassoc )
 205     [ [ dupd at ] curry ] keep map>assoc ;
 206
 207 M: assoc value-at* swap [ = nip ] curry assoc-find nip ;
 208
 209 : value-at ( value assoc -- key/f ) value-at* drop ;
 210
 211 : value? ( value assoc -- ? ) value-at* nip ;
 212
 213 : push-at ( value key assoc -- )
 214     [ ?push ] change-at ;
 215
 216 : zip-as ( keys values exemplar -- assoc )
 217     dup sequence? [
 218         [ 2array ] swap 2map-as
 219     ] [
 220         [ 2dup min-length ] dip new-assoc
 221         [ [ set-at ] with-assoc 2each ] keep
 222     ] if ; inline
 223
 224 : zip ( keys values -- alist )
 225      { } zip-as ; inline
 226
 227 : zip-index-as ( values exemplar -- assoc )
 228     [ dup length iota ] dip zip-as ; inline
 229
 230 : zip-index ( values -- alist )
 231     { } zip-index-as ; inline
 232
 233 : unzip ( assoc -- keys values )
 234     dup assoc-empty? [ drop { } { } ] [ >alist flip first2 ] if ;
 235
 236 M: sequence at*
 237     search-alist [ second t ] [ f ] if ;
 238
 239 M: sequence set-at
 240     2dup search-alist
 241     [ 2nip set-second ]
 242     [ drop [ swap 2array ] dip push ] if ;
 243
 244 M: sequence new-assoc drop <vector> ; inline
 245
 246 M: sequence clear-assoc delete-all ; inline
 247
 248 M: sequence delete-at
 249     [ nip ] [ search-alist nip ] 2bi
 250     [ swap remove-nth! drop ] [ drop ] if* ;
 251
 252 M: sequence assoc-size length ; inline
 253
 254 M: sequence assoc-clone-like
 255     [ >alist ] dip clone-like ; inline
 256
 257 M: sequence assoc-like
 258     [ >alist ] dip like ; inline
 259
 260 M: sequence >alist ; inline
 261
 262 ! Override sequence => assoc instance for f
 263 M: f at* 2drop f f ; inline
 264
 265 M: f assoc-size drop 0 ; inline
 266
 267 M: f clear-assoc drop ; inline
 268
 269 M: f assoc-like drop dup assoc-empty? [ drop f ] when ; inline
 270
 271 INSTANCE: sequence assoc
 272
 273 TUPLE: enum { seq read-only } ;
 274
 275 C: <enum> enum
 276
 277 M: enum at*
 278     seq>> 2dup bounds-check?
 279     [ nth-unsafe t ] [ 2drop f f ] if ; inline
 280
 281 M: enum set-at seq>> set-nth ; inline
 282
 283 M: enum delete-at seq>> remove-nth! drop ; inline
 284
 285 M: enum >alist ( enum -- alist )
 286     seq>> [ length iota ] keep zip ; inline
 287
 288 M: enum keys seq>> length iota >array ; inline
 289
 290 M: enum values seq>> >array ; inline
 291
 292 M: enum assoc-size seq>> length ; inline
 293
 294 M: enum clear-assoc seq>> delete-all ; inline
 295
 296 INSTANCE: enum assoc
 297
 298 M: enum length seq>> length ; inline
 299
 300 M: enum nth-unsafe dupd seq>> nth-unsafe 2array ; inline
 301
 302 INSTANCE: enum immutable-sequence