core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2008 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences arrays math sequences.private vectors
   4 accessors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: set-at ( value key assoc -- )
  11 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  12 GENERIC: delete-at ( key assoc -- )
  13 GENERIC: clear-assoc ( assoc -- )
  14 GENERIC: assoc-size ( assoc -- n )
  15 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  16
  17 M: assoc assoc-like drop ;
  18
  19 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  20
  21 GENERIC: >alist ( assoc -- newassoc )
  22
  23 : (assoc-each) ( assoc quot -- seq quot' )
  24     >r >alist r> [ first2 ] prepose ; inline
  25
  26 : assoc-find ( assoc quot -- key value ? )
  27     (assoc-each) find swap [ first2 t ] [ drop f f f ] if ; inline
  28
  29 : key? ( key assoc -- ? ) at* nip ; inline
  30
  31 : assoc-each ( assoc quot -- )
  32     (assoc-each) each ; inline
  33
  34 : assoc>map ( assoc quot exemplar -- seq )
  35     >r accumulator >r assoc-each r> r> like ; inline
  36
  37 : assoc-map-as ( assoc quot exemplar -- newassoc )
  38     >r [ 2array ] compose V{ } assoc>map r> assoc-like ; inline
  39
  40 : assoc-map ( assoc quot -- newassoc )
  41     over assoc-map-as ; inline
  42
  43 : assoc-push-if ( key value quot accum -- )
  44     >r 2keep r> roll
  45     [ >r 2array r> push ] [ 3drop ] if ; inline
  46
  47 : assoc-pusher ( quot -- quot' accum )
  48     V{ } clone [ [ assoc-push-if ] 2curry ] keep ; inline
  49
  50 : assoc-filter ( assoc quot -- subassoc )
  51     over >r assoc-pusher >r assoc-each r> r> assoc-like ; inline
  52
  53 : assoc-contains? ( assoc quot -- ? )
  54     assoc-find 2nip ; inline
  55
  56 : assoc-all? ( assoc quot -- ? )
  57     [ not ] compose assoc-contains? not ; inline
  58
  59 : at ( key assoc -- value/f )
  60     at* drop ; inline
  61
  62 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
  63     over assoc-size swap new-assoc
  64     swap [ swap pick set-at ] assoc-each ;
  65
  66 : keys ( assoc -- keys )
  67     [ drop ] { } assoc>map ;
  68
  69 : values ( assoc -- values )
  70     [ nip ] { } assoc>map ;
  71
  72 : delete-at* ( key assoc -- old ? )
  73     [ at* ] 2keep delete-at ;
  74
  75 : rename-at ( newkey key assoc -- )
  76     tuck delete-at* [ -rot set-at ] [ 3drop ] if ;
  77
  78 : assoc-empty? ( assoc -- ? )
  79     assoc-size zero? ;
  80
  81 : (assoc-stack) ( key i seq -- value )
  82     over 0 < [
  83         3drop f
  84     ] [
  85         3dup nth-unsafe at*
  86         [ >r 3drop r> ] [ drop >r 1- r> (assoc-stack) ] if
  87     ] if ; inline recursive
  88
  89 : assoc-stack ( key seq -- value )
  90     dup length 1- swap (assoc-stack) ;
  91
  92 : assoc-subset? ( assoc1 assoc2 -- ? )
  93     [ swapd at* [ = ] [ 2drop f ] if ] curry assoc-all? ;
  94
  95 : assoc= ( assoc1 assoc2 -- ? )
  96     [ assoc-subset? ] [ swap assoc-subset? ] 2bi and ;
  97
  98 : assoc-hashcode ( n assoc -- code )
  99     [
 100         >r over r> hashcode* 2/ >r dupd hashcode* r> bitxor
 101     ] { } assoc>map hashcode* ;
 102
 103 : assoc-intersect ( assoc1 assoc2 -- intersection )
 104     swap [ nip key? ] curry assoc-filter ;
 105
 106 : update ( assoc1 assoc2 -- )
 107     swap [ swapd set-at ] curry assoc-each ;
 108
 109 : assoc-union ( assoc1 assoc2 -- union )
 110     2dup [ assoc-size ] bi@ + pick new-assoc
 111     [ rot update ] keep [ swap update ] keep ;
 112
 113 : assoc-combine ( seq -- union )
 114     H{ } clone [ dupd update ] reduce ;
 115
 116 : assoc-diff ( assoc1 assoc2 -- diff )
 117     [ nip key? not ] curry assoc-filter ;
 118
 119 : remove-all ( assoc seq -- subseq )
 120     swap [ key? not ] curry filter ;
 121
 122 : (substitute)
 123     [ dupd at* [ nip ] [ drop ] if ] curry ; inline
 124
 125 : substitute-here ( seq assoc -- )
 126     (substitute) change-each ;
 127
 128 : substitute ( seq assoc -- newseq )
 129     (substitute) map ;
 130
 131 : cache ( key assoc quot -- value )
 132     2over at* [
 133         >r 3drop r>
 134     ] [
 135         drop pick rot >r >r call dup r> r> set-at
 136     ] if ; inline
 137
 138 : change-at ( key assoc quot -- )
 139     [ >r at r> call ] 3keep drop set-at ; inline
 140
 141 : at+ ( n key assoc -- )
 142     [ 0 or + ] change-at ;
 143
 144 : map>assoc ( seq quot exemplar -- assoc )
 145     >r [ 2array ] compose { } map-as r> assoc-like ; inline
 146
 147 : extract-keys ( seq assoc -- subassoc )
 148     [ [ dupd at ] curry ] keep map>assoc ;
 149
 150 GENERIC: value-at* ( value assoc -- key/f ? )
 151
 152 M: assoc value-at* swap [ = nip ] curry assoc-find nip ;
 153
 154 : value-at ( value assoc -- key/f ) value-at* drop ;
 155
 156 : value? ( value assoc -- ? ) value-at* nip ;
 157
 158 : push-at ( value key assoc -- )
 159     [ ?push ] change-at ;
 160
 161 : zip ( keys values -- alist )
 162     2array flip ; inline
 163
 164 : unzip ( assoc -- keys values )
 165     dup assoc-empty? [ drop { } { } ] [ >alist flip first2 ] if ;
 166
 167 : search-alist ( key alist -- pair/f i/f )
 168     [ first = ] with find swap ; inline
 169
 170 M: sequence at*
 171     search-alist [ second t ] [ f ] if ;
 172
 173 M: sequence set-at
 174     2dup search-alist
 175     [ 2nip set-second ]
 176     [ drop >r swap 2array r> push ] if ;
 177
 178 M: sequence new-assoc drop <vector> ;
 179
 180 M: sequence clear-assoc delete-all ;
 181
 182 M: sequence delete-at
 183     tuck search-alist nip
 184     [ swap delete-nth ] [ drop ] if* ;
 185
 186 M: sequence assoc-size length ;
 187
 188 M: sequence assoc-clone-like
 189     >r >alist r> clone-like ;
 190
 191 M: sequence assoc-like
 192     >r >alist r> like ;
 193
 194 M: sequence >alist ;
 195
 196 ! Override sequence => assoc instance for f
 197 M: f clear-assoc drop ;
 198
 199 M: f assoc-like drop dup assoc-empty? [ drop f ] when ;
 200
 201 INSTANCE: sequence assoc
 202
 203 TUPLE: enum seq ;
 204
 205 C: <enum> enum
 206
 207 M: enum at*
 208     seq>> 2dup bounds-check?
 209     [ nth t ] [ 2drop f f ] if ;
 210
 211 M: enum set-at seq>> set-nth ;
 212
 213 M: enum delete-at seq>> delete-nth ;
 214
 215 M: enum >alist ( enum -- alist )
 216     seq>> [ length ] keep zip ;
 217
 218 M: enum assoc-size seq>> length ;
 219
 220 M: enum clear-assoc seq>> delete-all ;
 221
 222 INSTANCE: enum assoc