core/assocs/assocs.factor

   1 ! Copyright (C) 2007, 2010 Daniel Ehrenberg, Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel sequences arrays math sequences.private vectors
   4 accessors ;
   5 IN: assocs
   6
   7 MIXIN: assoc
   8
   9 GENERIC: at* ( key assoc -- value/f ? )
  10 GENERIC: value-at* ( value assoc -- key/f ? )
  11 GENERIC: set-at ( value key assoc -- )
  12 GENERIC: new-assoc ( capacity exemplar -- newassoc )
  13 GENERIC: delete-at ( key assoc -- )
  14 GENERIC: clear-assoc ( assoc -- )
  15 GENERIC: assoc-size ( assoc -- n )
  16 GENERIC: assoc-like ( assoc exemplar -- newassoc )
  17 GENERIC: assoc-clone-like ( assoc exemplar -- newassoc )
  18 GENERIC: >alist ( assoc -- newassoc )
  19
  20 M: assoc assoc-like drop ; inline
  21
  22 : ?at ( key assoc -- value/key ? )
  23     2dup at* [ 2nip t ] [ 2drop f ] if ; inline
  24
  25 : maybe-set-at ( value key assoc -- changed? )
  26     3dup at* [ = [ 3drop f ] [ set-at t ] if ] [ 2drop set-at t ] if ;
  27
  28 <PRIVATE
  29
  30 : (assoc-each) ( assoc quot -- seq quot' )
  31     [ >alist ] dip [ first2 ] prepose ; inline
  32
  33 : (assoc-stack) ( key i seq -- value )
  34     over 0 < [
  35         3drop f
  36     ] [
  37         3dup nth-unsafe at*
  38         [ [ 3drop ] dip ] [ drop [ 1 - ] dip (assoc-stack) ] if
  39     ] if ; inline recursive
  40
  41 : search-alist ( key alist -- pair/f i/f )
  42     [ first = ] with find swap ; inline
  43
  44 : substituter ( assoc -- quot )
  45     [ ?at drop ] curry ; inline
  46
  47 : with-assoc ( assoc quot: ( ..a value key assoc -- ..b ) -- quot: ( ..a key value -- ..b ) )
  48     curry [ swap ] prepose ; inline
  49
  50 PRIVATE>
  51
  52 : assoc-find ( assoc quot -- key value ? )
  53     (assoc-each) find swap [ first2 t ] [ drop f f f ] if ; inline
  54
  55 : key? ( key assoc -- ? ) at* nip ; inline
  56
  57 : assoc-each ( assoc quot -- )
  58     (assoc-each) each ; inline
  59
  60 : assoc>map ( assoc quot exemplar -- seq )
  61     [ collector-for [ assoc-each ] dip ] [ like ] bi ; inline
  62
  63 : assoc-map-as ( assoc quot exemplar -- newassoc )
  64     [ [ 2array ] compose V{ } assoc>map ] dip assoc-like ; inline
  65
  66 : assoc-map ( assoc quot -- newassoc )
  67     over assoc-map-as ; inline
  68
  69 : assoc-filter-as ( assoc quot exemplar -- subassoc )
  70     [ (assoc-each) filter ] dip assoc-like ; inline
  71
  72 : assoc-filter ( assoc quot -- subassoc )
  73     over assoc-filter-as ; inline
  74
  75 : assoc-filter! ( assoc quot -- assoc )
  76     [
  77         over [ [ [ drop ] 2bi ] dip [ delete-at ] 2curry unless ] 2curry
  78         assoc-each
  79     ] [ drop ] 2bi ; inline
  80
  81 : assoc-partition ( assoc quot -- true-assoc false-assoc )
  82     [ (assoc-each) partition ] [ drop ] 2bi
  83     [ assoc-like ] curry bi@ ; inline
  84
  85 : assoc-any? ( assoc quot -- ? )
  86     assoc-find 2nip ; inline
  87
  88 : assoc-all? ( assoc quot -- ? )
  89     [ not ] compose assoc-any? not ; inline
  90
  91 : at ( key assoc -- value/f )
  92     at* drop ; inline
  93
  94 M: assoc assoc-clone-like ( assoc exemplar -- newassoc )
  95     [ dup assoc-size ] dip new-assoc
  96     [ [ set-at ] with-assoc assoc-each ] keep ; inline
  97
  98 : keys ( assoc -- keys )
  99     [ drop ] { } assoc>map ;
 100
 101 : values ( assoc -- values )
 102     [ nip ] { } assoc>map ;
 103
 104 : delete-at* ( key assoc -- old ? )
 105     [ at* ] 2keep delete-at ;
 106
 107 : rename-at ( newkey key assoc -- )
 108     [ delete-at* ] keep [ set-at ] with-assoc [ 2drop ] if ;
 109
 110 : assoc-empty? ( assoc -- ? )
 111     assoc-size 0 = ;
 112
 113 : assoc-stack ( key seq -- value )
 114     [ length 1 - ] keep (assoc-stack) ; flushable
 115
 116 : assoc-subset? ( assoc1 assoc2 -- ? )
 117     [ at* [ = ] [ 2drop f ] if ] with-assoc assoc-all? ;
 118
 119 : assoc= ( assoc1 assoc2 -- ? )
 120     [ assoc-subset? ] [ swap assoc-subset? ] 2bi and ;
 121
 122 : assoc-hashcode ( n assoc -- code )
 123     >alist hashcode* ;
 124
 125 : assoc-intersect ( assoc1 assoc2 -- intersection )
 126     swap [ nip key? ] curry assoc-filter ;
 127
 128 : assoc-union! ( assoc1 assoc2 -- assoc1 )
 129     over [ set-at ] with-assoc assoc-each ;
 130
 131 : assoc-union ( assoc1 assoc2 -- union )
 132     [ [ [ assoc-size ] bi@ + ] [ drop ] 2bi new-assoc ] 2keep
 133     [ assoc-union! ] bi@ ;
 134
 135 : assoc-combine ( seq -- union )
 136     H{ } clone [ assoc-union! ] reduce ;
 137
 138 : assoc-refine ( seq -- assoc )
 139     [ f ] [ [ ] [ assoc-intersect ] map-reduce ] if-empty ;
 140
 141 : assoc-differ ( key -- quot )
 142     [ nip key? not ] curry ; inline
 143
 144 : assoc-diff ( assoc1 assoc2 -- diff )
 145     assoc-differ assoc-filter ;
 146
 147 : assoc-diff! ( assoc1 assoc2 -- assoc1 )
 148     assoc-differ assoc-filter! ;
 149
 150 : substitute ( seq assoc -- newseq )
 151     substituter map ;
 152
 153 : cache ( key assoc quot -- value )
 154     [ [ at* ] 2keep ] dip
 155     [ [ nip call dup ] [ drop ] 3bi set-at ] 3curry
 156     [ drop ] prepose
 157     unless ; inline
 158
 159 : 2cache ( key1 key2 assoc quot -- value )
 160     [ 2array ] 2dip [ first2 ] prepose cache ; inline
 161
 162 : change-at ( key assoc quot -- )
 163     [ [ at ] dip call ] [ drop ] 3bi set-at ; inline
 164
 165 : at+ ( n key assoc -- ) [ 0 or + ] change-at ; inline
 166
 167 : inc-at ( key assoc -- ) [ 1 ] 2dip at+ ; inline
 168
 169 : map>assoc ( seq quot exemplar -- assoc )
 170     [ [ 2array ] compose { } map-as ] dip assoc-like ; inline
 171
 172 : extract-keys ( seq assoc -- subassoc )
 173     [ [ dupd at ] curry ] keep map>assoc ;
 174
 175 M: assoc value-at* swap [ = nip ] curry assoc-find nip ;
 176
 177 : value-at ( value assoc -- key/f ) value-at* drop ;
 178
 179 : value? ( value assoc -- ? ) value-at* nip ;
 180
 181 : push-at ( value key assoc -- )
 182     [ ?push ] change-at ;
 183
 184 : zip ( keys values -- alist )
 185     2array flip ; inline
 186
 187 : unzip ( assoc -- keys values )
 188     dup assoc-empty? [ drop { } { } ] [ >alist flip first2 ] if ;
 189
 190 M: sequence at*
 191     search-alist [ second t ] [ f ] if ;
 192
 193 M: sequence set-at
 194     2dup search-alist
 195     [ 2nip set-second ]
 196     [ drop [ swap 2array ] dip push ] if ;
 197
 198 M: sequence new-assoc drop <vector> ; inline
 199
 200 M: sequence clear-assoc delete-all ; inline
 201
 202 M: sequence delete-at
 203     [ nip ] [ search-alist nip ] 2bi
 204     [ swap remove-nth! drop ] [ drop ] if* ;
 205
 206 M: sequence assoc-size length ; inline
 207
 208 M: sequence assoc-clone-like
 209     [ >alist ] dip clone-like ; inline
 210
 211 M: sequence assoc-like
 212     [ >alist ] dip like ; inline
 213
 214 M: sequence >alist ; inline
 215
 216 ! Override sequence => assoc instance for f
 217 M: f at* 2drop f f ; inline
 218
 219 M: f assoc-size drop 0 ; inline
 220
 221 M: f clear-assoc drop ; inline
 222
 223 M: f assoc-like drop dup assoc-empty? [ drop f ] when ; inline
 224
 225 INSTANCE: sequence assoc
 226
 227 TUPLE: enum { seq read-only } ;
 228
 229 C: <enum> enum
 230
 231 M: enum at*
 232     seq>> 2dup bounds-check?
 233     [ nth t ] [ 2drop f f ] if ; inline
 234
 235 M: enum set-at seq>> set-nth ; inline
 236
 237 M: enum delete-at seq>> remove-nth! drop ; inline
 238
 239 M: enum >alist ( enum -- alist )
 240     seq>> [ length iota ] keep zip ; inline
 241
 242 M: enum assoc-size seq>> length ; inline
 243
 244 M: enum clear-assoc seq>> delete-all ; inline
 245
 246 INSTANCE: enum assoc