core/classes/classes.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays definitions assocs kernel kernel.private
   4 slots.private namespaces make sequences strings words words.symbol
   5 vectors math quotations combinators sorting effects graphs
   6 vocabs sets ;
   7 IN: classes
   8
   9 ERROR: bad-inheritance class superclass ;
  10
  11 PREDICATE: class < word "class" word-prop ;
  12
  13 <PRIVATE
  14
  15 SYMBOL: class<=-cache
  16 SYMBOL: class-not-cache
  17 SYMBOL: classes-intersect-cache
  18 SYMBOL: class-and-cache
  19 SYMBOL: class-or-cache
  20 SYMBOL: next-method-quot-cache
  21
  22 : init-caches ( -- )
  23     H{ } clone class<=-cache set
  24     H{ } clone class-not-cache set
  25     H{ } clone classes-intersect-cache set
  26     H{ } clone class-and-cache set
  27     H{ } clone class-or-cache set
  28     H{ } clone next-method-quot-cache set ;
  29
  30 : reset-caches ( -- )
  31     class<=-cache get clear-assoc
  32     class-not-cache get clear-assoc
  33     classes-intersect-cache get clear-assoc
  34     class-and-cache get clear-assoc
  35     class-or-cache get clear-assoc
  36     next-method-quot-cache get clear-assoc ;
  37
  38 SYMBOL: update-map
  39
  40 SYMBOL: implementors-map
  41
  42 GENERIC: rank-class ( class -- n )
  43
  44 GENERIC: reset-class ( class -- )
  45
  46 M: class reset-class
  47     {
  48         "class"
  49         "metaclass"
  50         "superclass"
  51         "members"
  52         "participants"
  53         "predicate"
  54     } reset-props ;
  55
  56 M: word reset-class drop ;
  57
  58 PRIVATE>
  59
  60 : classes ( -- seq ) implementors-map get keys ;
  61
  62 PREDICATE: predicate < word "predicating" word-prop >boolean ;
  63
  64 : create-predicate-word ( word -- predicate )
  65     [ name>> "?" append ] [ vocabulary>> ] bi create
  66     dup predicate? [ dup reset-generic ] unless ;
  67
  68 : predicate-word ( word -- predicate )
  69     "predicate" word-prop first ;
  70
  71 M: predicate flushable? drop t ;
  72
  73 M: predicate forget*
  74     [ call-next-method ] [ f "predicating" set-word-prop ] bi ;
  75
  76 M: predicate reset-word
  77     [ call-next-method ] [ f "predicating" set-word-prop ] bi ;
  78
  79 : define-predicate ( class quot -- )
  80     [ predicate-word ] dip (( object -- ? )) define-declared ;
  81
  82 : superclass ( class -- super )
  83     #! Output f for non-classes to work with algebra code
  84     dup class? [ "superclass" word-prop ] [ drop f ] if ;
  85
  86 : superclasses ( class -- supers )
  87     [ superclass ] follow reverse ;
  88
  89 : superclass-of? ( class superclass -- ? )
  90     superclasses member-eq? ;
  91
  92 : subclass-of? ( class superclass -- ? )
  93     swap superclass-of? ;
  94
  95 : members ( class -- seq )
  96     #! Output f for non-classes to work with algebra code
  97     dup class? [ "members" word-prop ] [ drop f ] if ;
  98
  99 : participants ( class -- seq )
 100     #! Output f for non-classes to work with algebra code
 101     dup class? [ "participants" word-prop ] [ drop f ] if ;
 102
 103 GENERIC: implementors ( class/classes -- seq )
 104
 105 ! update-map
 106 : class-uses ( class -- seq )
 107     [
 108         [ members % ]
 109         [ participants % ]
 110         [ superclass [ , ] when* ]
 111         tri
 112     ] { } make ;
 113
 114 : class-usage ( class -- seq ) update-map get at ;
 115
 116 : class-usages ( class -- seq ) [ class-usage ] closure keys ;
 117
 118 M: class implementors implementors-map get at keys ;
 119
 120 M: sequence implementors [ implementors ] gather ;
 121
 122 <PRIVATE
 123
 124 : update-map+ ( class -- )
 125     dup class-uses update-map get add-vertex ;
 126
 127 : update-map- ( class -- )
 128     dup class-uses update-map get remove-vertex ;
 129
 130 : implementors-map+ ( class -- )
 131     [ H{ } clone ] dip implementors-map get set-at ;
 132
 133 : implementors-map- ( class -- )
 134     implementors-map get delete-at ;
 135
 136 : make-class-props ( superclass members participants metaclass -- assoc )
 137     [
 138         {
 139             [ dup [ bootstrap-word ] when "superclass" set ]
 140             [ [ bootstrap-word ] map "members" set ]
 141             [ [ bootstrap-word ] map "participants" set ]
 142             [ "metaclass" set ]
 143         } spread
 144     ] H{ } make-assoc ;
 145
 146 GENERIC: metaclass-changed ( use class -- )
 147
 148 : ?metaclass-changed ( class usages/f -- )
 149     dup [ [ metaclass-changed ] with each ] [ 2drop ] if ;
 150
 151 : check-metaclass ( class metaclass -- usages/f )
 152     over class? [
 153         over "metaclass" word-prop eq?
 154         [ drop f ] [ class-usage keys ] if
 155     ] [ 2drop f ] if ;
 156
 157 : ?define-symbol ( word -- )
 158     dup deferred? [ define-symbol ] [ drop ] if ;
 159
 160 : (define-class) ( word props -- )
 161     reset-caches
 162     2dup "metaclass" swap at check-metaclass
 163     {
 164         [ 2drop update-map- ]
 165         [ 2drop dup class? [ reset-class ] [ implementors-map+ ] if ]
 166         [ 2drop ?define-symbol ]
 167         [ drop [ assoc-union ] curry change-props drop ]
 168         [
 169             2drop
 170             dup create-predicate-word
 171             [ 1quotation "predicate" set-word-prop ]
 172             [ swap "predicating" set-word-prop ]
 173             2bi
 174         ]
 175         [ 2drop t "class" set-word-prop ]
 176         [ 2drop update-map+ ]
 177         [ nip ?metaclass-changed ]
 178     } 3cleave ;
 179
 180 GENERIC: update-class ( class -- )
 181
 182 M: class update-class drop ;
 183
 184 GENERIC: update-methods ( class seq -- )
 185
 186 : update-classes ( class -- )
 187     dup class-usages
 188     [ nip [ update-class ] each ] [ update-methods ] 2bi ;
 189
 190 : check-inheritance ( subclass superclass -- )
 191     2dup superclass-of? [ bad-inheritance ] [ 2drop ] if ;
 192
 193 : define-class ( word superclass members participants metaclass -- )
 194     [ 2dup check-inheritance ] 3dip
 195     make-class-props [ (define-class) ] [ drop changed-definition ] 2bi ;
 196
 197 : forget-predicate ( class -- )
 198     dup "predicate" word-prop
 199     dup length 1 = [
 200         first
 201         [ nip ] [ "predicating" word-prop = ] 2bi
 202         [ forget ] [ drop ] if
 203     ] [ 2drop ] if ;
 204
 205 GENERIC: forget-methods ( class -- )
 206
 207 PRIVATE>
 208
 209 : forget-class ( class -- )
 210     dup f check-metaclass {
 211         [ drop forget-predicate ]
 212         [ drop forget-methods ]
 213         [ drop implementors-map- ]
 214         [ drop update-map- ]
 215         [ drop reset-class ]
 216         [ 2drop reset-caches ]
 217         [ ?metaclass-changed ]
 218     } 2cleave ;
 219
 220 M: class metaclass-changed
 221     swap class? [ drop ] [ forget-class ] if ;
 222
 223 M: class forget* ( class -- )
 224     [ call-next-method ] [ forget-class ] bi ;
 225
 226 GENERIC: class ( object -- class )
 227
 228 GENERIC: instance? ( object class -- ? ) flushable