core/classes/classes.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays definitions assocs kernel kernel.private
   4 slots.private namespaces sequences strings words vectors math
   5 quotations combinators sorting effects graphs vocabs sets ;
   6 IN: classes
   7
   8 SYMBOL: class<=-cache
   9 SYMBOL: class-not-cache
  10 SYMBOL: classes-intersect-cache
  11 SYMBOL: class-and-cache
  12 SYMBOL: class-or-cache
  13
  14 : init-caches ( -- )
  15     H{ } clone class<=-cache set
  16     H{ } clone class-not-cache set
  17     H{ } clone classes-intersect-cache set
  18     H{ } clone class-and-cache set
  19     H{ } clone class-or-cache set ;
  20
  21 : reset-caches ( -- )
  22     class<=-cache get clear-assoc
  23     class-not-cache get clear-assoc
  24     classes-intersect-cache get clear-assoc
  25     class-and-cache get clear-assoc
  26     class-or-cache get clear-assoc ;
  27
  28 SYMBOL: update-map
  29
  30 SYMBOL: implementors-map
  31
  32 PREDICATE: class < word
  33     "class" word-prop ;
  34
  35 PREDICATE: tuple-class < class
  36     "metaclass" word-prop tuple-class eq? ;
  37
  38 : classes ( -- seq ) implementors-map get keys ;
  39
  40 : predicate-word ( word -- predicate )
  41     [ word-name "?" append ] keep word-vocabulary create ;
  42
  43 PREDICATE: predicate < word "predicating" word-prop >boolean ;
  44
  45 : define-predicate ( class quot -- )
  46     >r "predicate" word-prop first
  47     r> (( object -- ? )) define-declared ;
  48
  49 : superclass ( class -- super )
  50     #! Output f for non-classes to work with algebra code
  51     dup class? [ "superclass" word-prop ] [ drop f ] if ;
  52
  53 : superclasses ( class -- supers )
  54     [ superclass ] follow reverse ;
  55
  56 : members ( class -- seq )
  57     #! Output f for non-classes to work with algebra code
  58     dup class? [ "members" word-prop ] [ drop f ] if ;
  59
  60 : participants ( class -- seq )
  61     #! Output f for non-classes to work with algebra code
  62     dup class? [ "participants" word-prop ] [ drop f ] if ;
  63
  64 GENERIC: rank-class ( class -- n )
  65
  66 GENERIC: reset-class ( class -- )
  67
  68 M: class reset-class
  69     {
  70         "class"
  71         "metaclass"
  72         "superclass"
  73         "members"
  74         "participants"
  75     } reset-props ;
  76
  77 M: word reset-class drop ;
  78
  79 GENERIC: implementors ( class/classes -- seq )
  80
  81 ! update-map
  82 : class-uses ( class -- seq )
  83     [
  84         [ members % ]
  85         [ participants % ]
  86         [ superclass [ , ] when* ]
  87         tri
  88     ] { } make ;
  89
  90 : class-usages ( class -- seq )
  91     [ update-map get at ] closure keys ;
  92
  93 <PRIVATE
  94
  95 : update-map+ ( class -- )
  96     dup class-uses update-map get add-vertex ;
  97
  98 : update-map- ( class -- )
  99     dup class-uses update-map get remove-vertex ;
 100
 101 M: class implementors implementors-map get at keys ;
 102
 103 M: sequence implementors [ implementors ] gather ;
 104
 105 : implementors-map+ ( class -- )
 106     H{ } clone swap implementors-map get set-at ;
 107
 108 : implementors-map- ( class -- )
 109     implementors-map get delete-at ;
 110
 111 : make-class-props ( superclass members participants metaclass -- assoc )
 112     [
 113         {
 114             [ dup [ bootstrap-word ] when "superclass" set ]
 115             [ [ bootstrap-word ] map "members" set ]
 116             [ [ bootstrap-word ] map "participants" set ]
 117             [ "metaclass" set ]
 118         } spread
 119     ] H{ } make-assoc ;
 120
 121 : (define-class) ( word props -- )
 122     >r
 123     dup class? [ dup [ implementors-map+ ] [ new-class ] bi ] unless
 124     dup reset-class
 125     dup deferred? [ dup define-symbol ] when
 126     dup word-props
 127     r> assoc-union over set-word-props
 128     dup predicate-word
 129     [ 1quotation "predicate" set-word-prop ]
 130     [ swap "predicating" set-word-prop ]
 131     [ drop t "class" set-word-prop ]
 132     2tri ;
 133
 134 PRIVATE>
 135
 136 GENERIC: update-class ( class -- )
 137
 138 M: class update-class drop ;
 139
 140 GENERIC: update-methods ( class seq -- )
 141
 142 : update-classes ( class -- )
 143     dup class-usages
 144     [ nip [ update-class ] each ] [ update-methods ] 2bi ;
 145
 146 : define-class ( word superclass members participants metaclass -- )
 147     #! If it was already a class, update methods after.
 148     reset-caches
 149     make-class-props
 150     [ drop update-map- ]
 151     [ (define-class) ]
 152     [ drop update-map+ ]
 153     2tri ;
 154
 155 : forget-predicate ( class -- )
 156     dup "predicate" word-prop
 157     dup length 1 = [
 158         first
 159         tuck "predicating" word-prop =
 160         [ forget ] [ drop ] if
 161     ] [ 2drop ] if ;
 162
 163 : forget-methods ( class -- )
 164     [ implementors ] [ [ swap 2array ] curry ] bi map forget-all ;
 165
 166 : forget-class ( class -- )
 167     class-usages [
 168         {
 169             [ forget-predicate ]
 170             [ forget-methods ]
 171             [ implementors-map- ]
 172             [ update-map- ]
 173             [ reset-class ]
 174         } cleave
 175     ] each ;
 176
 177 M: class forget* ( class -- )
 178     [ forget-class ] [ call-next-method ] bi ;
 179
 180 GENERIC: class ( object -- class )
 181
 182 : instance? ( obj class -- ? )
 183     "predicate" word-prop call ;