core/classes/classes.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays definitions assocs kernel kernel.private
   4 slots.private namespaces make sequences strings words vectors
   5 math quotations combinators sorting effects graphs vocabs sets ;
   6 IN: classes
   7
   8 SYMBOL: class<=-cache
   9 SYMBOL: class-not-cache
  10 SYMBOL: classes-intersect-cache
  11 SYMBOL: class-and-cache
  12 SYMBOL: class-or-cache
  13 SYMBOL: next-method-quot-cache
  14
  15 : init-caches ( -- )
  16     H{ } clone class<=-cache set
  17     H{ } clone class-not-cache set
  18     H{ } clone classes-intersect-cache set
  19     H{ } clone class-and-cache set
  20     H{ } clone class-or-cache set
  21     H{ } clone next-method-quot-cache set ;
  22
  23 : reset-caches ( -- )
  24     class<=-cache get clear-assoc
  25     class-not-cache get clear-assoc
  26     classes-intersect-cache get clear-assoc
  27     class-and-cache get clear-assoc
  28     class-or-cache get clear-assoc
  29     next-method-quot-cache get clear-assoc ;
  30
  31 SYMBOL: update-map
  32
  33 SYMBOL: implementors-map
  34
  35 PREDICATE: class < word
  36     "class" word-prop ;
  37
  38 : classes ( -- seq ) implementors-map get keys ;
  39
  40 : predicate-word ( word -- predicate )
  41     [ name>> "?" append ] [ vocabulary>> ] bi create ;
  42
  43 PREDICATE: predicate < word "predicating" word-prop >boolean ;
  44
  45 : define-predicate ( class quot -- )
  46     >r "predicate" word-prop first
  47     r> (( object -- ? )) define-declared ;
  48
  49 : superclass ( class -- super )
  50     #! Output f for non-classes to work with algebra code
  51     dup class? [ "superclass" word-prop ] [ drop f ] if ;
  52
  53 : superclasses ( class -- supers )
  54     [ superclass ] follow reverse ;
  55
  56 : members ( class -- seq )
  57     #! Output f for non-classes to work with algebra code
  58     dup class? [ "members" word-prop ] [ drop f ] if ;
  59
  60 : participants ( class -- seq )
  61     #! Output f for non-classes to work with algebra code
  62     dup class? [ "participants" word-prop ] [ drop f ] if ;
  63
  64 GENERIC: rank-class ( class -- n )
  65
  66 GENERIC: reset-class ( class -- )
  67
  68 M: class reset-class
  69     {
  70         "class"
  71         "metaclass"
  72         "superclass"
  73         "members"
  74         "participants"
  75         "predicate"
  76     } reset-props ;
  77
  78 M: word reset-class drop ;
  79
  80 GENERIC: implementors ( class/classes -- seq )
  81
  82 ! update-map
  83 : class-uses ( class -- seq )
  84     [
  85         [ members % ]
  86         [ participants % ]
  87         [ superclass [ , ] when* ]
  88         tri
  89     ] { } make ;
  90
  91 : class-usage ( class -- seq ) update-map get at ;
  92
  93 : class-usages ( class -- seq ) [ class-usage ] closure keys ;
  94
  95 <PRIVATE
  96
  97 : update-map+ ( class -- )
  98     dup class-uses update-map get add-vertex ;
  99
 100 : update-map- ( class -- )
 101     dup class-uses update-map get remove-vertex ;
 102
 103 M: class implementors implementors-map get at keys ;
 104
 105 M: sequence implementors [ implementors ] gather ;
 106
 107 : implementors-map+ ( class -- )
 108     H{ } clone swap implementors-map get set-at ;
 109
 110 : implementors-map- ( class -- )
 111     implementors-map get delete-at ;
 112
 113 : make-class-props ( superclass members participants metaclass -- assoc )
 114     [
 115         {
 116             [ dup [ bootstrap-word ] when "superclass" set ]
 117             [ [ bootstrap-word ] map "members" set ]
 118             [ [ bootstrap-word ] map "participants" set ]
 119             [ "metaclass" set ]
 120         } spread
 121     ] H{ } make-assoc ;
 122
 123 : (define-class) ( word props -- )
 124     >r
 125     dup class? [ dup [ implementors-map+ ] [ new-class ] bi ] unless
 126     dup reset-class
 127     dup deferred? [ dup define-symbol ] when
 128     dup redefined
 129     dup props>>
 130     r> assoc-union >>props
 131     dup predicate-word
 132     [ 1quotation "predicate" set-word-prop ]
 133     [ swap "predicating" set-word-prop ]
 134     [ drop t "class" set-word-prop ]
 135     2tri ;
 136
 137 PRIVATE>
 138
 139 GENERIC: update-class ( class -- )
 140
 141 M: class update-class drop ;
 142
 143 GENERIC: update-methods ( class seq -- )
 144
 145 : update-classes ( class -- )
 146     dup class-usages
 147     [ nip [ update-class ] each ] [ update-methods ] 2bi ;
 148
 149 : define-class ( word superclass members participants metaclass -- )
 150     #! If it was already a class, update methods after.
 151     reset-caches
 152     make-class-props
 153     [ drop update-map- ]
 154     [ (define-class) ]
 155     [ drop update-map+ ]
 156     2tri ;
 157
 158 : forget-predicate ( class -- )
 159     dup "predicate" word-prop
 160     dup length 1 = [
 161         first
 162         tuck "predicating" word-prop =
 163         [ forget ] [ drop ] if
 164     ] [ 2drop ] if ;
 165
 166 : forget-methods ( class -- )
 167     [ implementors ] [ [ swap 2array ] curry ] bi map forget-all ;
 168
 169 GENERIC: class-forgotten ( use class -- )
 170
 171 : forget-class ( class -- )
 172     {
 173         [ dup class-usage keys [ class-forgotten ] with each ]
 174         [ forget-predicate ]
 175         [ forget-methods ]
 176         [ implementors-map- ]
 177         [ update-map- ]
 178         [ reset-class ]
 179     } cleave ;
 180
 181 M: class class-forgotten
 182     nip forget-class ;
 183
 184 M: class forget* ( class -- )
 185     [ call-next-method ] [ forget-class ] bi ;
 186
 187 GENERIC: class ( object -- class )
 188
 189 GENERIC: instance? ( object class -- ? ) flushable