core/classes/classes.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs combinators definitions kernel
   4 make namespaces quotations sequences sets words words.symbol ;
   5 IN: classes
   6
   7 ERROR: bad-inheritance class superclass ;
   8
   9 PREDICATE: class < word "class" word-prop ;
  10
  11 PREDICATE: defining-class < word "defining-class" word-prop ;
  12
  13 MIXIN: classoid
  14 INSTANCE: class classoid
  15 INSTANCE: defining-class classoid
  16
  17 <PRIVATE
  18
  19 SYMBOL: class<=-cache
  20 SYMBOL: class-not-cache
  21 SYMBOL: classes-intersect-cache
  22 SYMBOL: class-and-cache
  23 SYMBOL: class-or-cache
  24 SYMBOL: next-method-quot-cache
  25
  26 : init-caches ( -- )
  27     H{ } clone class<=-cache set
  28     H{ } clone class-not-cache set
  29     H{ } clone classes-intersect-cache set
  30     H{ } clone class-and-cache set
  31     H{ } clone class-or-cache set
  32     H{ } clone next-method-quot-cache set ;
  33
  34 : reset-caches ( -- )
  35     class<=-cache get clear-assoc
  36     class-not-cache get clear-assoc
  37     classes-intersect-cache get clear-assoc
  38     class-and-cache get clear-assoc
  39     class-or-cache get clear-assoc
  40     next-method-quot-cache get clear-assoc ;
  41
  42 SYMBOL: update-map
  43
  44 SYMBOL: implementors-map
  45
  46 GENERIC: class-name ( class -- string )
  47
  48 M: class class-name name>> ;
  49
  50 GENERIC: rank-class ( class -- n )
  51
  52 GENERIC: reset-class ( class -- )
  53
  54 M: class reset-class
  55     {
  56         "defining-class"
  57         "class"
  58         "metaclass"
  59         "superclass"
  60         "members"
  61         "participants"
  62         "predicate"
  63     } remove-word-props ;
  64
  65 M: word reset-class drop ;
  66
  67 PRIVATE>
  68
  69 : classes ( -- seq ) implementors-map get keys ;
  70
  71 PREDICATE: predicate < word "predicating" word-prop >boolean ;
  72
  73 : create-predicate-word ( word -- predicate )
  74     [ name>> "?" append ] [ vocabulary>> ] bi create-word
  75     dup predicate? [ dup reset-generic ] unless ;
  76
  77 GENERIC: class-of ( object -- class )
  78
  79 GENERIC: instance? ( object class -- ? ) flushable
  80
  81 GENERIC: predicate-def ( obj -- quot )
  82
  83 M: word predicate-def
  84     "predicate" word-prop ;
  85
  86 M: object predicate-def
  87     [ instance? ] curry ;
  88
  89 : predicate-word ( word -- predicate )
  90     predicate-def first ;
  91
  92 M: predicate flushable? drop t ;
  93
  94 M: predicate forget*
  95     [ call-next-method ] [ f "predicating" set-word-prop ] bi ;
  96
  97 M: predicate reset-word
  98     [ call-next-method ] [ f "predicating" set-word-prop ] bi ;
  99
 100 : define-predicate ( class quot -- )
 101     [ predicate-word ] dip ( object -- ? ) define-declared ;
 102
 103 : superclass-of ( class -- super )
 104     ! Output f for non-classes to work with algebra code
 105     dup class? [ "superclass" word-prop ] [ drop f ] if ;
 106
 107 : superclasses-of ( class -- supers )
 108     [ superclass-of ] follow reverse! ;
 109
 110 : superclass-of? ( class superclass -- ? )
 111     superclasses-of member-eq? ;
 112
 113 : subclass-of? ( class superclass -- ? )
 114     swap superclass-of? ;
 115
 116 : class-members ( class -- seq )
 117     ! Output f for non-classes to work with algebra code
 118     dup class? [ "members" word-prop ] [ drop f ] if ;
 119
 120 : class-participants ( class -- seq )
 121     ! Output f for non-classes to work with algebra code
 122     dup class? [ "participants" word-prop ] [ drop f ] if ;
 123
 124 GENERIC: implementors ( class/classes -- seq )
 125
 126 ! update-map
 127 : class-uses ( class -- seq )
 128     [
 129         [ class-members % ]
 130         [ class-participants % ]
 131         [ superclass-of [ , ] when* ]
 132         tri
 133     ] { } make ;
 134
 135 : class-usage ( class -- seq )
 136     update-map get at members ;
 137
 138 <PRIVATE
 139
 140 : (closure) ( obj set quot: ( elt -- seq ) -- )
 141     2over ?adjoin [
 142         [ dip ] keep [ (closure) ] 2curry each
 143     ] [ 3drop ] if ; inline recursive
 144
 145 : closure ( obj quot -- set )
 146     HS{ } clone [ swap (closure) ] keep ; inline
 147
 148 PRIVATE>
 149
 150 : class-usages ( class -- seq )
 151     [ class-usage ] closure members ;
 152
 153 M: class implementors implementors-map get at members ;
 154
 155 M: sequence implementors [ implementors ] gather ;
 156
 157 <PRIVATE
 158
 159 : update-map+ ( class -- )
 160     dup class-uses update-map get
 161     [ adjoin-at ] curry with each ;
 162
 163 : update-map- ( class -- )
 164     dup class-uses update-map get
 165     [ at delete ] curry with each ;
 166
 167 : implementors-map+ ( class -- )
 168     [ HS{ } clone ] dip implementors-map get set-at ;
 169
 170 : implementors-map- ( class -- )
 171     implementors-map get delete-at ;
 172
 173 : make-class-props ( superclass members participants metaclass -- assoc )
 174     [
 175         {
 176             [ dup [ bootstrap-word ] when "superclass" ,, ]
 177             [ [ bootstrap-word ] map "members" ,, ]
 178             [ [ bootstrap-word ] map "participants" ,, ]
 179             [ "metaclass" ,, ]
 180         } spread
 181     ] H{ } make ;
 182
 183 GENERIC: metaclass-changed ( use class -- )
 184
 185 : ?metaclass-changed ( class usages/f -- )
 186     [ [ metaclass-changed ] with each ] [ drop ] if* ;
 187
 188 : check-metaclass ( class metaclass -- usages/f )
 189     over class? [
 190         over "metaclass" word-prop eq?
 191         [ drop f ] [ class-usage ] if
 192     ] [ 2drop f ] if ;
 193
 194 : ?define-symbol ( word -- )
 195     dup deferred? [ define-symbol ] [ drop ] if ;
 196
 197 : (define-class) ( word props -- )
 198     reset-caches
 199     2dup "metaclass" of check-metaclass
 200     {
 201         [ 2drop update-map- ]
 202         [ 2drop dup class? [ reset-class ] [ implementors-map+ ] if ]
 203         [ 2drop ?define-symbol ]
 204         [ drop [ assoc-union ] curry change-props drop ]
 205         [
 206             2drop
 207             dup create-predicate-word
 208             [ 1quotation "predicate" set-word-prop ]
 209             [ swap "predicating" set-word-prop ]
 210             2bi
 211         ]
 212         [ 2drop t "class" set-word-prop ]
 213         [ 2drop update-map+ ]
 214         [ nip ?metaclass-changed ]
 215     } 3cleave ;
 216
 217 GENERIC: update-class ( class -- )
 218
 219 M: class update-class drop ;
 220
 221 GENERIC: update-methods ( class seq -- )
 222
 223 : update-classes ( class -- )
 224     dup class-usages
 225     [ nip [ update-class ] each ] [ update-methods ] 2bi ;
 226
 227 : check-inheritance ( subclass superclass -- )
 228     2dup superclass-of? [ bad-inheritance ] [ 2drop ] if ;
 229
 230 : define-class ( word superclass members participants metaclass -- )
 231     [ 2dup check-inheritance ] 3dip
 232     make-class-props [ (define-class) ] [ drop changed-definition ] 2bi ;
 233
 234 : forget-predicate ( class -- )
 235     dup predicate-def
 236     dup length 1 = [
 237         first
 238         [ nip ] [ "predicating" word-prop = ] 2bi
 239         [ forget ] [ drop ] if
 240     ] [ 2drop ] if ;
 241
 242 GENERIC: forget-methods ( class -- )
 243
 244 PRIVATE>
 245
 246 : forget-class ( class -- )
 247     dup f check-metaclass {
 248         [ drop forget-predicate ]
 249         [ drop forget-methods ]
 250         [ drop implementors-map- ]
 251         [ drop update-map- ]
 252         [ drop reset-class ]
 253         [ 2drop reset-caches ]
 254         [ ?metaclass-changed ]
 255     } 2cleave ;
 256
 257 M: class metaclass-changed
 258     swap class? [ drop ] [ forget-class ] if ;
 259
 260 M: class forget* ( class -- )
 261     [ call-next-method ] [ forget-class ] bi ;