core/classes/tuple/parser/parser.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel sets namespaces sequences parser
   4 lexer combinators words classes.parser classes.tuple arrays
   5 slots math assocs ;
   6 IN: classes.tuple.parser
   7
   8 : slot-names ( slots -- seq )
   9     [ dup array? [ first ] when ] map ;
  10
  11 : shadowed-slots ( superclass slots -- shadowed )
  12     [ all-slots [ name>> ] map ] [ slot-names ] bi* intersect ;
  13
  14 : check-slot-shadowing ( class superclass slots -- )
  15     shadowed-slots [
  16         [
  17             "Definition of slot ``" %
  18             %
  19             "'' in class ``" %
  20             name>> %
  21             "'' shadows a superclass slot" %
  22         ] "" make note.
  23     ] with each ;
  24
  25 ERROR: duplicate-slot-names names ;
  26
  27 : check-duplicate-slots ( slots -- )
  28     slot-names duplicates
  29     [ duplicate-slot-names ] unless-empty ;
  30
  31 ERROR: invalid-slot-name name ;
  32
  33 : parse-long-slot-name ( -- )
  34     [ scan , \ } parse-until % ] { } make ;
  35
  36 : parse-slot-name ( string/f -- ? )
  37     #! This isn't meant to enforce any kind of policy, just
  38     #! to check for mistakes of this form:
  39     #!
  40     #! TUPLE: blahblah foo bing
  41     #!
  42     #! : ...
  43     {
  44         { [ dup not ] [ unexpected-eof ] }
  45         { [ dup { ":" "(" "<" "\"" "!" } member? ] [ invalid-slot-name ] }
  46         { [ dup ";" = ] [ drop f ] }
  47         [ dup "{" = [ drop parse-long-slot-name ] when , t ]
  48     } cond ;
  49
  50 : parse-tuple-slots ( -- )
  51     scan parse-slot-name [ parse-tuple-slots ] when ;
  52
  53 : parse-tuple-definition ( -- class superclass slots )
  54     CREATE-CLASS
  55     scan {
  56         { ";" [ tuple f ] }
  57         { "<" [ scan-word [ parse-tuple-slots ] { } make ] }
  58         [ tuple swap [ parse-slot-name [ parse-tuple-slots ] when ] { } make ]
  59     } case
  60     dup check-duplicate-slots
  61     3dup check-slot-shadowing ;
  62
  63 : parse-slot-value ( -- )
  64     scan scan-object 2array , scan "}" assert= ;
  65
  66 : (parse-slot-values) ( -- )
  67     parse-slot-value
  68     scan {
  69         { "{" [ (parse-slot-values) ] }
  70         { "}" [ ] }
  71     } case ;
  72
  73 : parse-slot-values ( -- )
  74     [ (parse-slot-values) ] { } make ;
  75
  76 : boa>tuple ( class slots -- tuple )
  77     swap prefix >tuple ;
  78
  79 : assoc>tuple ( class slots -- tuple )
  80     [ [ ] [ initial-values ] [ all-slots ] tri ] dip
  81     swap [ [ slot-named offset>> 2 - ] curry dip ] curry assoc-map
  82     [ dup <enum> ] dip update boa>tuple ;
  83
  84 : parse-tuple-literal ( -- tuple )
  85     scan-word scan {
  86         { "f" [ \ } parse-until boa>tuple ] }
  87         { "{" [ parse-slot-values assoc>tuple ] }
  88         { "}" [ new ] }
  89     } case ;