core/classes/tuple/parser/parser.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel sets namespaces make sequences parser
   4 lexer combinators words classes.parser classes.tuple arrays
   5 slots math assocs parser.notes classes classes.algebra ;
   6 IN: classes.tuple.parser
   7
   8 : slot-names ( slots -- seq )
   9     [ dup array? [ first ] when ] map ;
  10
  11 : shadowed-slots ( superclass slots -- shadowed )
  12     [ all-slots [ name>> ] map ] [ slot-names ] bi* intersect ;
  13
  14 : check-slot-shadowing ( class superclass slots -- )
  15     shadowed-slots [
  16         [
  17             "Definition of slot ``" %
  18             %
  19             "'' in class ``" %
  20             name>> %
  21             "'' shadows a superclass slot" %
  22         ] "" make note.
  23     ] with each ;
  24
  25 ERROR: duplicate-slot-names names ;
  26
  27 : check-duplicate-slots ( slots -- )
  28     slot-names duplicates
  29     [ duplicate-slot-names ] unless-empty ;
  30
  31 ERROR: invalid-slot-name name ;
  32
  33 : parse-long-slot-name ( -- spec )
  34     [ scan , \ } parse-until % ] { } make ;
  35
  36 : parse-slot-name-delim ( end-delim string/f -- ? )
  37     #! This isn't meant to enforce any kind of policy, just
  38     #! to check for mistakes of this form:
  39     #!
  40     #! TUPLE: blahblah foo bing
  41     #!
  42     #! : ...
  43     {
  44         { [ dup not ] [ unexpected-eof ] }
  45         { [ dup { ":" "(" "<" "\"" "!" } member? ] [ invalid-slot-name ] }
  46         { [ 2dup = ] [ drop f ] }
  47         [ dup "{" = [ drop parse-long-slot-name ] when , t ]
  48     } cond nip ;
  49
  50 : parse-tuple-slots-delim ( end-delim -- )
  51     dup scan parse-slot-name-delim [ parse-tuple-slots-delim ] [ drop ] if ;
  52
  53 : parse-slot-name ( string/f -- ? )
  54     ";" swap parse-slot-name-delim ;
  55
  56 : parse-tuple-slots ( -- )
  57     ";" parse-tuple-slots-delim ;
  58
  59 : parse-tuple-definition ( -- class superclass slots )
  60     CREATE-CLASS
  61     scan {
  62         { ";" [ tuple f ] }
  63         { "<" [ scan-word [ parse-tuple-slots ] { } make ] }
  64         [ tuple swap [ parse-slot-name [ parse-tuple-slots ] when ] { } make ]
  65     } case
  66     dup check-duplicate-slots
  67     3dup check-slot-shadowing ;
  68
  69 ERROR: bad-literal-tuple ;
  70
  71 ERROR: bad-slot-name class slot ;
  72
  73 : check-slot-name ( class slots name -- name )
  74     2dup swap slot-named* nip [ 2nip ] [ nip bad-slot-name ] if ;
  75
  76 : parse-slot-value ( class slots -- )
  77     scan check-slot-name scan-object 2array , scan {
  78         { f [ \ } unexpected-eof ] }
  79         { "}" [ ] }
  80         [ bad-literal-tuple ]
  81     } case ;
  82
  83 : (parse-slot-values) ( class slots -- )
  84     2dup parse-slot-value
  85     scan {
  86         { f [ 2drop \ } unexpected-eof ] }
  87         { "{" [ (parse-slot-values) ] }
  88         { "}" [ 2drop ] }
  89         [ 2nip bad-literal-tuple ]
  90     } case ;
  91
  92 : parse-slot-values ( class slots -- values )
  93     [ (parse-slot-values) ] { } make ;
  94
  95 GENERIC# boa>object 1 ( class slots -- tuple )
  96
  97 M: tuple-class boa>object
  98     swap prefix >tuple ;
  99
 100 : check-slot-exists ( class initials slot-spec/f index/f name -- class initials slot-spec index )
 101     over [ drop ] [ nip nip nip bad-slot-name ] if ;
 102
 103 : slot-named-checked ( class initials name slots -- class initials slot-spec )
 104     over [ slot-named* ] dip check-slot-exists drop ;
 105
 106 : assoc>object ( class slots values -- tuple )
 107     [ [ [ initial>> ] map <enum> ] keep ] dip
 108     swap [ [ slot-named-checked ] curry dip ] curry assoc-map
 109     assoc-union! seq>> boa>object ;
 110
 111 : parse-tuple-literal-slots ( class slots -- tuple )
 112     scan {
 113         { f [ unexpected-eof ] }
 114         { "f" [ drop \ } parse-until boa>object ] }
 115         { "{" [ 2dup parse-slot-values assoc>object ] }
 116         { "}" [ drop new ] }
 117         [ bad-literal-tuple ]
 118     } case ;
 119
 120 : parse-tuple-literal ( -- tuple )
 121     scan-word dup all-slots parse-tuple-literal-slots ;