core/classes/tuple/parser/parser.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel sets namespaces make sequences parser
   4 lexer combinators words classes.parser classes.tuple arrays
   5 slots math assocs parser.notes ;
   6 IN: classes.tuple.parser
   7
   8 : slot-names ( slots -- seq )
   9     [ dup array? [ first ] when ] map ;
  10
  11 : shadowed-slots ( superclass slots -- shadowed )
  12     [ all-slots [ name>> ] map ] [ slot-names ] bi* intersect ;
  13
  14 : check-slot-shadowing ( class superclass slots -- )
  15     shadowed-slots [
  16         [
  17             "Definition of slot ``" %
  18             %
  19             "'' in class ``" %
  20             name>> %
  21             "'' shadows a superclass slot" %
  22         ] "" make note.
  23     ] with each ;
  24
  25 ERROR: duplicate-slot-names names ;
  26
  27 : check-duplicate-slots ( slots -- )
  28     slot-names duplicates
  29     [ duplicate-slot-names ] unless-empty ;
  30
  31 ERROR: invalid-slot-name name ;
  32
  33 : parse-long-slot-name ( -- spec )
  34     [ scan , \ } parse-until % ] { } make ;
  35
  36 : parse-slot-name-delim ( end-delim string/f -- ? )
  37     #! This isn't meant to enforce any kind of policy, just
  38     #! to check for mistakes of this form:
  39     #!
  40     #! TUPLE: blahblah foo bing
  41     #!
  42     #! : ...
  43     {
  44         { [ dup not ] [ unexpected-eof ] }
  45         { [ dup { ":" "(" "<" "\"" "!" } member? ] [ invalid-slot-name ] }
  46         { [ 2dup = ] [ drop f ] }
  47         [ dup "{" = [ drop parse-long-slot-name ] when , t ]
  48     } cond nip ;
  49
  50 : parse-tuple-slots-delim ( end-delim -- )
  51     dup scan parse-slot-name-delim [ parse-tuple-slots-delim ] [ drop ] if ;
  52
  53 : parse-slot-name ( string/f -- ? )
  54     ";" swap parse-slot-name-delim ;
  55
  56 : parse-tuple-slots ( -- )
  57     ";" parse-tuple-slots-delim ;
  58
  59 : parse-tuple-definition ( -- class superclass slots )
  60     CREATE-CLASS
  61     scan {
  62         { ";" [ tuple f ] }
  63         { "<" [ scan-word [ parse-tuple-slots ] { } make ] }
  64         [ tuple swap [ parse-slot-name [ parse-tuple-slots ] when ] { } make ]
  65     } case
  66     dup check-duplicate-slots
  67     3dup check-slot-shadowing ;
  68
  69 ERROR: bad-literal-tuple ;
  70
  71 : parse-slot-value ( -- )
  72     scan scan-object 2array , scan {
  73         { f [ \ } unexpected-eof ] }
  74         { "}" [ ] }
  75         [ bad-literal-tuple ]
  76     } case ;
  77
  78 : (parse-slot-values) ( -- )
  79     parse-slot-value
  80     scan {
  81         { f [ \ } unexpected-eof ] }
  82         { "{" [ (parse-slot-values) ] }
  83         { "}" [ ] }
  84         [ bad-literal-tuple ]
  85     } case ;
  86
  87 : parse-slot-values ( -- values )
  88     [ (parse-slot-values) ] { } make ;
  89
  90 GENERIC# boa>object 1 ( class slots -- tuple )
  91
  92 M: tuple-class boa>object
  93     swap prefix >tuple ;
  94
  95 : assoc>object ( class slots values -- tuple )
  96     [ [ [ initial>> ] map ] keep ] dip
  97     swap [ [ slot-named* drop ] curry dip ] curry assoc-map
  98     [ dup <enum> ] dip update boa>object ;
  99
 100 : parse-tuple-literal-slots ( class slots -- tuple )
 101     scan {
 102         { f [ unexpected-eof ] }
 103         { "f" [ drop \ } parse-until boa>object ] }
 104         { "{" [ parse-slot-values assoc>object ] }
 105         { "}" [ drop new ] }
 106         [ bad-literal-tuple ]
 107     } case ;
 108
 109 : parse-tuple-literal ( -- tuple )
 110     scan-word dup all-slots parse-tuple-literal-slots ;