core/classes/tuple/parser/parser.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel sets namespaces make sequences parser
   4 lexer combinators words classes.parser classes.tuple arrays
   5 slots math assocs parser.notes classes classes.algebra ;
   6 IN: classes.tuple.parser
   7
   8 : slot-names ( slots -- seq )
   9     [ dup array? [ first ] when ] map ;
  10
  11 : shadowed-slots ( superclass slots -- shadowed )
  12     [ all-slots [ name>> ] map ] [ slot-names ] bi* intersect ;
  13
  14 : check-slot-shadowing ( class superclass slots -- )
  15     shadowed-slots [
  16         [
  17             "Definition of slot ``" %
  18             %
  19             "'' in class ``" %
  20             name>> %
  21             "'' shadows a superclass slot" %
  22         ] "" make note.
  23     ] with each ;
  24
  25 ERROR: duplicate-slot-names names ;
  26
  27 : check-duplicate-slots ( slots -- )
  28     slot-names duplicates
  29     [ duplicate-slot-names ] unless-empty ;
  30
  31 ERROR: invalid-slot-name name ;
  32
  33 : parse-long-slot-name ( -- spec )
  34     [ scan , \ } parse-until % ] { } make ;
  35
  36 : parse-slot-name-delim ( end-delim string/f -- ? )
  37     ! Check for mistakes of this form:
  38     !
  39     ! TUPLE: blahblah foo bing
  40     !
  41     ! : ...
  42     {
  43         { [ dup { ":" "(" "<" "\"" "!" } member? ] [ invalid-slot-name ] }
  44         { [ 2dup = ] [ drop f ] }
  45         [ dup "{" = [ drop parse-long-slot-name ] when , t ]
  46     } cond nip ;
  47
  48 : parse-tuple-slots-delim ( end-delim -- )
  49     dup scan-token parse-slot-name-delim [ parse-tuple-slots-delim ] [ drop ] if ;
  50
  51 : parse-slot-name ( string/f -- ? )
  52     ";" swap parse-slot-name-delim ;
  53
  54 : parse-tuple-slots ( -- )
  55     ";" parse-tuple-slots-delim ;
  56
  57 : parse-tuple-definition ( -- class superclass slots )
  58     CREATE-CLASS
  59     scan {
  60         { ";" [ tuple f ] }
  61         { "<" [ scan-word [ parse-tuple-slots ] { } make ] }
  62         [ tuple swap [ parse-slot-name [ parse-tuple-slots ] when ] { } make ]
  63     } case
  64     dup check-duplicate-slots
  65     3dup check-slot-shadowing ;
  66
  67 ERROR: bad-literal-tuple ;
  68
  69 ERROR: bad-slot-name class slot ;
  70
  71 : check-slot-name ( class slots name -- name )
  72     2dup swap slot-named* nip [ 2nip ] [ nip bad-slot-name ] if ;
  73
  74 : parse-slot-value ( class slots -- )
  75     scan check-slot-name scan-object 2array , scan-token {
  76         { "}" [ ] }
  77         [ bad-literal-tuple ]
  78     } case ;
  79
  80 : (parse-slot-values) ( class slots -- )
  81     2dup parse-slot-value
  82     scan-token {
  83         { "{" [ (parse-slot-values) ] }
  84         { "}" [ 2drop ] }
  85         [ 2nip bad-literal-tuple ]
  86     } case ;
  87
  88 : parse-slot-values ( class slots -- values )
  89     [ (parse-slot-values) ] { } make ;
  90
  91 GENERIC# boa>object 1 ( class slots -- tuple )
  92
  93 M: tuple-class boa>object
  94     swap prefix >tuple ;
  95
  96 : check-slot-exists ( class initials slot-spec/f index/f name -- class initials slot-spec index )
  97     over [ drop ] [ nip nip nip bad-slot-name ] if ;
  98
  99 : slot-named-checked ( class initials name slots -- class initials slot-spec )
 100     over [ slot-named* ] dip check-slot-exists drop ;
 101
 102 : assoc>object ( class slots values -- tuple )
 103     [ [ [ initial>> ] map <enum> ] keep ] dip
 104     swap [ [ slot-named-checked ] curry dip ] curry assoc-map
 105     assoc-union! seq>> boa>object ;
 106
 107 : parse-tuple-literal-slots ( class slots -- tuple )
 108     scan-token {
 109         { "f" [ drop \ } parse-until boa>object ] }
 110         { "{" [ 2dup parse-slot-values assoc>object ] }
 111         { "}" [ drop new ] }
 112         [ bad-literal-tuple ]
 113     } case ;
 114
 115 : parse-tuple-literal ( -- tuple )
 116     scan-word dup all-slots parse-tuple-literal-slots ;