core/compiler/units/units.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel continuations assocs namespaces
   4 sequences words vocabs definitions hashtables init sets math
   5 math.order classes classes.private classes.algebra classes.tuple
   6 classes.tuple.private generic source-files.errors kernel.private ;
   7 IN: compiler.units
   8
   9 SYMBOL: old-definitions
  10 SYMBOL: new-definitions
  11
  12 TUPLE: redefine-error def ;
  13
  14 : redefine-error ( definition -- )
  15     \ redefine-error boa
  16     { { "Continue" t } } throw-restarts drop ;
  17
  18 <PRIVATE
  19
  20 : add-once ( key assoc -- )
  21     2dup key? [ over redefine-error ] when conjoin ;
  22
  23 : (remember-definition) ( definition loc assoc -- )
  24     [ over set-where ] dip add-once ;
  25
  26 PRIVATE>
  27
  28 : remember-definition ( definition loc -- )
  29     new-definitions get first (remember-definition) ;
  30
  31 : fake-definition ( definition -- )
  32     old-definitions get [ delete-at ] with each ;
  33
  34 : remember-class ( class loc -- )
  35     [ dup new-definitions get first key? [ dup redefine-error ] when ] dip
  36     new-definitions get second (remember-definition) ;
  37
  38 : forward-reference? ( word -- ? )
  39     dup old-definitions get assoc-stack
  40     [ new-definitions get assoc-stack not ]
  41     [ drop f ] if ;
  42
  43 SYMBOL: compiler-impl
  44
  45 HOOK: update-call-sites compiler-impl ( class generic -- words )
  46
  47 : changed-call-sites ( class generic -- )
  48     update-call-sites [ changed-definition ] each ;
  49
  50 M: generic update-generic ( class generic -- )
  51     [ changed-call-sites ]
  52     [ remake-generic drop ]
  53     [ changed-conditionally drop ]
  54     2tri ;
  55
  56 M: sequence update-methods ( class seq -- )
  57     implementors [ update-generic ] with each ;
  58
  59 HOOK: recompile compiler-impl ( words -- alist )
  60
  61 HOOK: to-recompile compiler-impl ( -- words )
  62
  63 HOOK: process-forgotten-words compiler-impl ( words -- )
  64
  65 : compile ( words -- )
  66     recompile t f modify-code-heap ;
  67
  68 ! Non-optimizing compiler
  69 M: f update-call-sites
  70     2drop { } ;
  71
  72 M: f to-recompile
  73     changed-definitions get [ drop word? ] assoc-filter keys ;
  74
  75 M: f recompile
  76     [ dup def>> ] { } map>assoc ;
  77
  78 M: f process-forgotten-words drop ;
  79
  80 : without-optimizer ( quot -- )
  81     [ f compiler-impl ] dip with-variable ; inline
  82
  83 : <definitions> ( -- pair ) { H{ } H{ } } [ clone ] map ;
  84
  85 SYMBOL: definition-observers
  86
  87 GENERIC: definitions-changed ( assoc obj -- )
  88
  89 [ V{ } clone definition-observers set-global ]
  90 "compiler.units" add-startup-hook
  91
  92 ! This goes here because vocabs cannot depend on init
  93 [ V{ } clone vocab-observers set-global ]
  94 "vocabs" add-startup-hook
  95
  96 : add-definition-observer ( obj -- )
  97     definition-observers get push ;
  98
  99 : remove-definition-observer ( obj -- )
 100     definition-observers get remove-eq! drop ;
 101
 102 : notify-definition-observers ( assoc -- )
 103     definition-observers get
 104     [ definitions-changed ] with each ;
 105
 106 ! Incremented each time stack effects potentially changed, used
 107 ! by compiler.tree.propagation.call-effect for call( and execute(
 108 ! inline caching
 109 : effect-counter ( -- n ) 47 special-object ; inline
 110
 111 GENERIC: always-bump-effect-counter? ( defspec -- ? )
 112
 113 M: object always-bump-effect-counter? drop f ;
 114
 115 <PRIVATE
 116
 117 : changed-vocabs ( assoc -- vocabs )
 118     [ drop word? ] assoc-filter
 119     [ drop vocabulary>> dup [ vocab ] when dup ] assoc-map ;
 120
 121 : updated-definitions ( -- assoc )
 122     H{ } clone
 123     forgotten-definitions get assoc-union!
 124     new-definitions get first assoc-union!
 125     new-definitions get second assoc-union!
 126     changed-definitions get assoc-union!
 127     maybe-changed get assoc-union!
 128     dup changed-vocabs assoc-union! ;
 129
 130 : process-forgotten-definitions ( -- )
 131     forgotten-definitions get keys
 132     [ [ word? ] filter process-forgotten-words ]
 133     [ [ delete-definition-errors ] each ]
 134     bi ;
 135
 136 : bump-effect-counter? ( -- ? )
 137     changed-effects get
 138     maybe-changed get
 139     changed-definitions get [ drop always-bump-effect-counter? ] assoc-filter
 140     3array assoc-combine new-words get assoc-diff assoc-empty? not ;
 141
 142 : bump-effect-counter ( -- )
 143     bump-effect-counter? [
 144         47 special-object 0 or
 145         1 +
 146         47 set-special-object
 147     ] when ;
 148
 149 : notify-observers ( -- )
 150     updated-definitions dup assoc-empty?
 151     [ drop ] [ notify-definition-observers notify-error-observers ] if ;
 152
 153 : update-existing? ( defs -- ? )
 154     new-words get keys diff empty? not ;
 155
 156 : reset-pics? ( -- ? )
 157     outdated-generics get assoc-empty? not ;
 158
 159 : finish-compilation-unit ( -- )
 160     [ ] [
 161         remake-generics
 162         to-recompile [
 163             recompile
 164             update-tuples
 165             process-forgotten-definitions
 166         ] keep update-existing? reset-pics? modify-code-heap
 167         bump-effect-counter
 168         notify-observers
 169     ] if-bootstrapping ;
 170
 171 TUPLE: nesting-observer new-words ;
 172
 173 M: nesting-observer definitions-changed new-words>> swap assoc-diff! drop ;
 174
 175 : add-nesting-observer ( -- )
 176     new-words get nesting-observer boa
 177     [ nesting-observer set ] [ add-definition-observer ] bi ;
 178
 179 : remove-nesting-observer ( -- )
 180     nesting-observer get remove-definition-observer ;
 181
 182 PRIVATE>
 183
 184 : with-nested-compilation-unit ( quot -- )
 185     [
 186         H{ } clone changed-definitions set
 187         H{ } clone maybe-changed set
 188         H{ } clone changed-effects set
 189         H{ } clone outdated-generics set
 190         H{ } clone outdated-tuples set
 191         H{ } clone new-words set
 192         add-nesting-observer
 193         [
 194             remove-nesting-observer
 195             finish-compilation-unit
 196         ] [ ] cleanup
 197     ] with-scope ; inline
 198
 199 : with-compilation-unit ( quot -- )
 200     [
 201         <definitions> new-definitions set
 202         <definitions> old-definitions set
 203         H{ } clone forgotten-definitions set
 204         with-nested-compilation-unit
 205     ] with-scope ; inline