core/compiler/units/units.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel continuations assocs namespaces
   4 sequences words vocabs definitions hashtables init sets math
   5 math.order classes classes.private classes.algebra classes.tuple
   6 classes.tuple.private generic source-files.errors kernel.private ;
   7 IN: compiler.units
   8
   9 SYMBOL: old-definitions
  10 SYMBOL: new-definitions
  11
  12 TUPLE: redefine-error def ;
  13
  14 : redefine-error ( definition -- )
  15     \ redefine-error boa
  16     { { "Continue" t } } throw-restarts drop ;
  17
  18 <PRIVATE
  19
  20 : add-once ( key assoc -- )
  21     2dup key? [ over redefine-error ] when conjoin ;
  22
  23 : (remember-definition) ( definition loc assoc -- )
  24     [ over set-where ] dip add-once ;
  25
  26 PRIVATE>
  27
  28 : remember-definition ( definition loc -- )
  29     new-definitions get first (remember-definition) ;
  30
  31 : fake-definition ( definition -- )
  32     old-definitions get [ delete-at ] with each ;
  33
  34 : remember-class ( class loc -- )
  35     [ dup new-definitions get first key? [ dup redefine-error ] when ] dip
  36     new-definitions get second (remember-definition) ;
  37
  38 : forward-reference? ( word -- ? )
  39     dup old-definitions get assoc-stack
  40     [ new-definitions get assoc-stack not ]
  41     [ drop f ] if ;
  42
  43 SYMBOL: compiler-impl
  44
  45 HOOK: update-call-sites compiler-impl ( class generic -- words )
  46
  47 : changed-call-sites ( class generic -- )
  48     update-call-sites [ changed-definition ] each ;
  49
  50 M: generic update-generic ( class generic -- )
  51     [ changed-call-sites ]
  52     [ remake-generic drop ]
  53     [ changed-conditionally drop ]
  54     2tri ;
  55
  56 M: sequence update-methods ( class seq -- )
  57     implementors [ update-generic ] with each ;
  58
  59 HOOK: recompile compiler-impl ( words -- alist )
  60
  61 HOOK: to-recompile compiler-impl ( -- words )
  62
  63 HOOK: process-forgotten-words compiler-impl ( words -- )
  64
  65 : compile ( words -- ) recompile modify-code-heap ;
  66
  67 ! Non-optimizing compiler
  68 M: f update-call-sites
  69     2drop { } ;
  70
  71 M: f to-recompile
  72     changed-definitions get [ drop word? ] assoc-filter keys ;
  73
  74 M: f recompile
  75     [ dup def>> ] { } map>assoc ;
  76
  77 M: f process-forgotten-words drop ;
  78
  79 : without-optimizer ( quot -- )
  80     [ f compiler-impl ] dip with-variable ; inline
  81
  82 : <definitions> ( -- pair ) { H{ } H{ } } [ clone ] map ;
  83
  84 SYMBOL: definition-observers
  85
  86 GENERIC: definitions-changed ( assoc obj -- )
  87
  88 [ V{ } clone definition-observers set-global ]
  89 "compiler.units" add-startup-hook
  90
  91 ! This goes here because vocabs cannot depend on init
  92 [ V{ } clone vocab-observers set-global ]
  93 "vocabs" add-startup-hook
  94
  95 : add-definition-observer ( obj -- )
  96     definition-observers get push ;
  97
  98 : remove-definition-observer ( obj -- )
  99     definition-observers get remove-eq! drop ;
 100
 101 : notify-definition-observers ( assoc -- )
 102     definition-observers get
 103     [ definitions-changed ] with each ;
 104
 105 ! Incremented each time stack effects potentially changed, used
 106 ! by compiler.tree.propagation.call-effect for call( and execute(
 107 ! inline caching
 108 : effect-counter ( -- n ) 47 special-object ; inline
 109
 110 GENERIC: always-bump-effect-counter? ( defspec -- ? )
 111
 112 M: object always-bump-effect-counter? drop f ;
 113
 114 <PRIVATE
 115
 116 : changed-vocabs ( assoc -- vocabs )
 117     [ drop word? ] assoc-filter
 118     [ drop vocabulary>> dup [ vocab ] when dup ] assoc-map ;
 119
 120 : updated-definitions ( -- assoc )
 121     H{ } clone
 122     dup forgotten-definitions get update
 123     dup new-definitions get first update
 124     dup new-definitions get second update
 125     dup changed-definitions get update
 126     dup maybe-changed get update
 127     dup dup changed-vocabs update ;
 128
 129 : process-forgotten-definitions ( -- )
 130     forgotten-definitions get keys
 131     [ [ word? ] filter process-forgotten-words ]
 132     [ [ delete-definition-errors ] each ]
 133     bi ;
 134
 135 : bump-effect-counter? ( -- ? )
 136     changed-effects get
 137     maybe-changed get
 138     changed-definitions get [ drop always-bump-effect-counter? ] assoc-filter
 139     3array assoc-combine new-words get assoc-diff assoc-empty? not ;
 140
 141 : bump-effect-counter ( -- )
 142     bump-effect-counter? [
 143         47 special-object 0 or
 144         1 +
 145         47 set-special-object
 146     ] when ;
 147
 148 : notify-observers ( -- )
 149     updated-definitions dup assoc-empty?
 150     [ drop ] [ notify-definition-observers notify-error-observers ] if ;
 151
 152 : finish-compilation-unit ( -- )
 153     [ ] [
 154         remake-generics
 155         to-recompile recompile
 156         update-tuples
 157         process-forgotten-definitions
 158         modify-code-heap
 159         bump-effect-counter
 160         notify-observers
 161     ] if-bootstrapping ;
 162
 163 PRIVATE>
 164
 165 : with-nested-compilation-unit ( quot -- )
 166     [
 167         H{ } clone changed-definitions set
 168         H{ } clone maybe-changed set
 169         H{ } clone changed-effects set
 170         H{ } clone outdated-generics set
 171         H{ } clone outdated-tuples set
 172         H{ } clone new-words set
 173         [ finish-compilation-unit ] [ ] cleanup
 174     ] with-scope ; inline
 175
 176 : with-compilation-unit ( quot -- )
 177     [
 178         H{ } clone changed-definitions set
 179         H{ } clone maybe-changed set
 180         H{ } clone changed-effects set
 181         H{ } clone outdated-generics set
 182         H{ } clone forgotten-definitions set
 183         H{ } clone outdated-tuples set
 184         H{ } clone new-words set
 185         <definitions> new-definitions set
 186         <definitions> old-definitions set
 187         [ finish-compilation-unit ] [ ] cleanup
 188     ] with-scope ; inline