core/effects/effects-docs.factor

   1 USING: help.markup help.syntax math strings words ;
   2 IN: effects
   3
   4 ARTICLE: "effect-declaration" "Stack effect declaration"
   5 "It is good practice to declare the stack effects of words using the following syntax:"
   6 { $code ": sq ( x -- y ) dup * ;" }
   7 "A stack effect declaration is written in parentheses and lists word inputs and outputs, separated by " { $snippet "--" } ". Stack effect declarations are read in using a parsing word:"
   8 { $subsection POSTPONE: ( }
   9 "Stack elements in a stack effect are ordered so that the top of the stack is on the right side. Each value can be named by a data type or description. The following are some examples of value names:"
  10 { $table
  11     { { { $snippet "?" } } "a boolean" }
  12     { { { $snippet "elt" } } "an object which is an element of a sequence" }
  13     { { { $snippet "m" } ", " { $snippet "n" } } "an integer" }
  14     { { { $snippet "obj" } } "an object" }
  15     { { { $snippet "quot" } } "a quotation" }
  16     { { { $snippet "seq" } } "a sequence" }
  17     { { { $snippet "assoc" } } "an associative mapping" }
  18     { { { $snippet "str" } } "a string" }
  19     { { { $snippet "x" } ", " { $snippet "y" } ", " { $snippet "z" } } "a number" }
  20     { { $snippet "loc" } "a screen location specified as a two-element array holding x and y co-ordinates" }
  21     { { $snippet "dim" } "a screen dimension specified as a two-element array holding width and height values" }
  22     { { $snippet "*" } "when this symbol appears by itself in the list of outputs, it means the word unconditionally throws an error" }
  23 }
  24 "The stack effect inferencer verifies stack effect comments to ensure the correct number of inputs and outputs is listed. Value names are ignored; only their number matters. An error is thrown if a word's declared stack effect does not match its inferred stack effect."
  25 $nl
  26 "Recursive words must declare a stack effect in order to compile. This includes all generic words, due to how delegation is implemented." ;
  27
  28 ARTICLE: "effects" "Stack effects"
  29 "A " { $emphasis "stack effect declaration" } ", for example " { $snippet "( x y -- z )" } " denotes that an operation takes two inputs, with " { $snippet "y" } " at the top of the stack, and returns one output."
  30 $nl
  31 "Stack effects are first-class, and words for working with them are found in the " { $vocab-link "effects" } " vocabulary."
  32 { $subsection effect }
  33 { $subsection effect? }
  34 "Stack effects of words can be declared."
  35 { $subsection "effect-declaration" }
  36 "Getting a word's declared stack effect:"
  37 { $subsection stack-effect }
  38 "Converting a stack effect to a string form:"
  39 { $subsection effect>string }
  40 "Comparing effects:"
  41 { $subsection effect-height }
  42 { $subsection effect<= } ;
  43
  44 ABOUT: "effects"
  45
  46 HELP: effect
  47 { $class-description "An object representing a stack effect. Holds a sequence of inputs, a sequence of outputs and a flag indicating if an error is thrown unconditionally." } ;
  48
  49 HELP: effect-height
  50 { $values { "effect" effect } { "n" integer } }
  51 { $description "Outputs the number of objects added to the data stack by the stack effect. This will be negative if the stack effect only removes objects from the stack." } ;
  52
  53 HELP: effect<=
  54 { $values { "eff1" effect } { "eff2" effect } { "?" "a boolean" } }
  55 { $description "Tests if " { $snippet "eff1" } " is substitutable for " { $snippet "eff2" } ". What this means is that both stack effects change the stack height by the same amount, the first takes a smaller or equal number of inputs as the second, and either both or neither one terminate execution by throwing an error." } ;
  56
  57 HELP: effect>string
  58 { $values { "effect" effect } { "string" string } }
  59 { $description "Turns a stack effect object into a string mnemonic." }
  60 { $examples
  61     { $example "USING: effects io ;" "1 2 <effect> effect>string print" "( object -- object object )" }
  62 } ;
  63
  64 HELP: stack-effect
  65 { $values { "word" word } { "effect/f" "an " { $link effect } " or " { $link f } } }
  66 { $description "Outputs the stack effect of a word; either a stack effect declared with " { $link POSTPONE: ( } ", or an inferred stack effect (see " { $link "inference" } "." } ;