core/effects/effects.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes combinators kernel make math
   4 math.order math.parser sequences strings words ;
   5 IN: effects
   6
   7 TUPLE: effect
   8 { in array read-only }
   9 { out array read-only }
  10 { terminated? read-only }
  11 { in-var read-only }
  12 { out-var read-only } ;
  13
  14 : ?terminated ( out -- out terminated? )
  15     dup { "*" } = [ drop { } t ] [ f ] if ;
  16
  17 : <effect> ( in out -- effect )
  18     ?terminated f f effect boa ;
  19
  20 : <terminated-effect> ( in out terminated? -- effect )
  21     f f effect boa ; inline
  22
  23 : <variable-effect> ( in-var in out-var out -- effect )
  24     swap [ rot ] dip [ ?terminated ] 2dip effect boa ;
  25
  26 : effect-height ( effect -- n )
  27     [ out>> length ] [ in>> length ] bi - ; inline
  28
  29 : variable-effect? ( effect -- ? )
  30     [ in-var>> ] [ out-var>> ] bi or ;
  31 : bivariable-effect? ( effect -- ? )
  32     [ in-var>> ] [ out-var>> ] bi = not ;
  33
  34 : effect<= ( effect1 effect2 -- ? )
  35     {
  36         { [ over terminated?>> ] [ t ] }
  37         { [ dup terminated?>> ] [ f ] }
  38         { [ 2dup [ bivariable-effect? ] either? ] [ f ] }
  39         { [ 2dup [ variable-effect? ] [ variable-effect? not ] bi* and ] [ f ] }
  40         { [ 2dup [ in>> length ] bi@ > ] [ f ] }
  41         { [ 2dup [ effect-height ] same? not ] [ f ] }
  42         [ t ]
  43     } cond 2nip ; inline
  44
  45 : effect= ( effect1 effect2 -- ? )
  46     [ [ in>> length ] same? ]
  47     [ [ out>> length ] same? ]
  48     [ [ terminated?>> ] same? ]
  49     2tri and and ;
  50
  51 GENERIC: effect>string ( obj -- str )
  52 M: string effect>string ;
  53 M: object effect>string drop "object" ;
  54 M: word effect>string name>> ;
  55 M: integer effect>string number>string ;
  56 M: pair effect>string first2 [ effect>string ] bi@ ": " glue ;
  57
  58 : stack-picture ( seq -- string )
  59     [ [ effect>string % CHAR: \s , ] each ] "" make ;
  60
  61 : var-picture ( var -- string )
  62     [ ".." " " surround ]
  63     [ "" ] if* ;
  64
  65 M: effect effect>string ( effect -- string )
  66     [
  67         "( " %
  68         dup in-var>> var-picture %
  69         dup in>> stack-picture % "-- " %
  70         dup out-var>> var-picture %
  71         dup out>> stack-picture %
  72         dup terminated?>> [ "* " % ] when
  73         drop
  74         ")" %
  75     ] "" make ;
  76
  77 GENERIC: effect>type ( obj -- type )
  78 M: object effect>type drop object ;
  79 M: word effect>type ;
  80 M: pair effect>type second effect>type ;
  81 M: classoid effect>type ;
  82
  83 : effect-in-types ( effect -- input-types )
  84     in>> [ effect>type ] map ;
  85
  86 : effect-out-types ( effect -- input-types )
  87     out>> [ effect>type ] map ;
  88
  89 GENERIC: stack-effect ( word -- effect/f )
  90
  91 M: word stack-effect
  92     [ "declared-effect" word-prop ]
  93     [ parent-word dup [ stack-effect ] when ] bi or ;
  94
  95 M: deferred stack-effect call-next-method ( -- * ) or ;
  96
  97 M: effect clone
  98     [ in>> clone ] [ out>> clone ] bi <effect> ;
  99
 100 : stack-height ( word -- n )
 101     stack-effect effect-height ; inline
 102
 103 : shuffle-mapping ( effect -- mapping )
 104     [ out>> ] [ in>> ] bi [ index ] curry map ;
 105
 106 : shuffle ( stack shuffle -- newstack )
 107     shuffle-mapping swap nths ;
 108
 109 : add-effect-input ( effect -- effect' )
 110     [ in>> "obj" suffix ] [ out>> ] [ terminated?>> ] tri <terminated-effect> ;
 111
 112 : compose-effects ( effect1 effect2 -- effect' )
 113     over terminated?>> [
 114         drop
 115     ] [
 116         [ [ [ in>> length ] [ out>> length ] bi ] [ in>> length ] bi* swap [-] + ]
 117         [ [ out>> length ] [ [ in>> length ] [ out>> length ] bi ] bi* [ [-] ] dip + ]
 118         [ nip terminated?>> ] 2tri
 119         [ [ "x" <array> ] bi@ ] dip
 120         <terminated-effect>
 121     ] if ; inline
 122
 123 : curry-effect ( effect -- effect' )
 124     [ in>> length ] [ out>> length ] [ terminated?>> ] tri
 125     pick 0 = [ [ 1 + ] dip ] [ [ 1 - ] 2dip ] if
 126     [ [ "x" <array> ] bi@ ] dip <terminated-effect> ;