core/effects/effects.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes combinators kernel make math
   4 math.order math.parser sequences sequences.private strings words ;
   5 IN: effects
   6
   7 TUPLE: effect
   8 { in array read-only }
   9 { out array read-only }
  10 { terminated? read-only }
  11 { in-var read-only }
  12 { out-var read-only } ;
  13
  14 : ?terminated ( out -- out terminated? )
  15     dup { "*" } = [ drop { } t ] [ f ] if ;
  16
  17 : <effect> ( in out -- effect )
  18     ?terminated f f effect boa ;
  19
  20 : <terminated-effect> ( in out terminated? -- effect )
  21     f f effect boa ; inline
  22
  23 : <variable-effect> ( in-var in out-var out -- effect )
  24     swap rotd [ ?terminated ] 2dip effect boa ;
  25
  26 : effect-height ( effect -- n )
  27     [ out>> length ] [ in>> length ] bi - ; inline
  28
  29 : variable-effect? ( effect -- ? )
  30     dup in-var>> [ drop t ] [ out-var>> ] if ;
  31
  32 : bivariable-effect? ( effect -- ? )
  33     [ in-var>> ] [ out-var>> ] bi = not ;
  34
  35 : effect<= ( effect1 effect2 -- ? )
  36     {
  37         { [ over terminated?>> ] [ t ] }
  38         { [ dup terminated?>> ] [ f ] }
  39         { [ 2dup [ bivariable-effect? ] either? ] [ f ] }
  40         { [ 2dup [ variable-effect? ] [ variable-effect? not ] bi* and ] [ f ] }
  41         { [ 2dup [ in>> length ] bi@ > ] [ f ] }
  42         { [ 2dup [ effect-height ] same? not ] [ f ] }
  43         [ t ]
  44     } cond 2nip ; inline
  45
  46 : effect= ( effect1 effect2 -- ? )
  47     2dup [ in>> length ] same? [
  48         2dup [ out>> length ] same? [
  49             [ terminated?>> ] same?
  50         ] [ 2drop f ] if
  51     ] [ 2drop f ] if ;
  52
  53 GENERIC: effect>string ( obj -- str )
  54 M: string effect>string ;
  55 M: object effect>string drop "object" ;
  56 M: word effect>string name>> ;
  57 M: integer effect>string number>string ;
  58 M: pair effect>string
  59     first2-unsafe over [
  60         [ effect>string ] bi@ ": " glue
  61     ] [
  62         nip effect>string ":" prepend
  63     ] if ;
  64
  65 <PRIVATE
  66
  67 : stack-picture% ( seq -- )
  68     [ effect>string % CHAR: \s , ] each ;
  69
  70 : var-picture% ( var -- )
  71     [ ".." % % CHAR: \s , ] when* ;
  72
  73 PRIVATE>
  74
  75 M: effect effect>string
  76     [
  77         "( " %
  78         dup in-var>> var-picture%
  79         dup in>> stack-picture% "-- " %
  80         dup out-var>> var-picture%
  81         dup out>> stack-picture%
  82         dup terminated?>> [ "* " % ] when
  83         drop
  84         ")" %
  85     ] "" make ;
  86
  87 GENERIC: effect>type ( obj -- type )
  88 M: object effect>type drop object ;
  89 M: word effect>type ;
  90 M: pair effect>type second-unsafe effect>type ;
  91 M: classoid effect>type ;
  92
  93 : effect-in-types ( effect -- input-types )
  94     in>> [ effect>type ] map ;
  95
  96 : effect-out-types ( effect -- input-types )
  97     out>> [ effect>type ] map ;
  98
  99 GENERIC: stack-effect ( word -- effect/f )
 100
 101 M: word stack-effect
 102     dup "declared-effect" word-prop [ nip ] [
 103         parent-word dup [ stack-effect ] when
 104     ] if* ;
 105
 106 M: deferred stack-effect call-next-method ( -- * ) or ;
 107
 108 M: effect clone
 109     (clone) [ clone ] change-in [ clone ] change-out ;
 110
 111 : stack-height ( word -- n )
 112     stack-effect effect-height ; inline
 113
 114 : shuffle-mapping ( effect -- mapping )
 115     [ out>> ] [ in>> ] bi [ index ] curry map ;
 116
 117 : shuffle ( stack shuffle -- newstack )
 118     shuffle-mapping swap nths ;
 119
 120 : add-effect-input ( effect -- effect' )
 121     [ in>> "obj" suffix ] [ out>> ] [ terminated?>> ] tri
 122     <terminated-effect> ;
 123
 124 : compose-effects ( effect1 effect2 -- effect' )
 125     over terminated?>> [
 126         drop
 127     ] [
 128         [ [ [ in>> length ] [ out>> length ] bi ] [ in>> length ] bi* swap [-] + ]
 129         [ [ out>> length ] [ [ in>> length ] [ out>> length ] bi ] bi* [ [-] ] dip + ]
 130         [ nip terminated?>> ] 2tri
 131         [ [ "x" <array> ] bi@ ] dip
 132         <terminated-effect>
 133     ] if ; inline
 134
 135 : curry-effect ( effect -- effect' )
 136     [ in>> length ] [ out>> length ] [ terminated?>> ] tri
 137     pick 0 = [ [ 1 + ] dip ] [ [ 1 - ] 2dip ] if
 138     [ [ "x" <array> ] bi@ ] dip <terminated-effect> ;
 139
 140 ERROR: bad-stack-effect word got expected ;
 141
 142 : check-stack-effect ( word effect -- )
 143     over stack-effect 2dup effect=
 144     [ 3drop ] [ bad-stack-effect ] if ;