core/hash-sets/hash-sets.factor

   1 ! Copyright (C) 2010 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs hashtables kernel sequences sets
   4 sets.private ;
   5 IN: hash-sets
   6
   7 ! In a better implementation, less memory would be used
   8 TUPLE: hash-set { table hashtable read-only } ;
   9
  10 : <hash-set> ( capacity -- hash-set )
  11     <hashtable> hash-set boa ; inline
  12
  13 : >hash-set ( members -- hash-set )
  14     unique hash-set boa ; inline
  15
  16 INSTANCE: hash-set set
  17 M: hash-set in? table>> key? ; inline
  18 M: hash-set adjoin table>> dupd set-at ; inline
  19 M: hash-set delete table>> delete-at ; inline
  20 M: hash-set members table>> keys ; inline
  21 M: hash-set set-like drop dup hash-set? [ ?members >hash-set ] unless ;
  22 M: hash-set clone table>> clone hash-set boa ;
  23 M: hash-set null? table>> assoc-empty? ;
  24 M: hash-set cardinality table>> assoc-size ;
  25 M: hash-set intersect small/large sequence/tester filter >hash-set ;
  26 M: hash-set union (union) >hash-set ;
  27 M: hash-set diff sequence/tester [ not ] compose filter >hash-set ;
  28
  29 M: sequence fast-set >hash-set ;
  30 M: f fast-set drop H{ } clone hash-set boa ;
  31
  32 M: sequence duplicates
  33     dup length <hash-set> [ ?adjoin not ] curry filter ;
  34
  35 <PRIVATE
  36
  37 : (all-unique?) ( elt hash -- ? )
  38     2dup in? [ 2drop f ] [ adjoin t ] if ; inline
  39
  40 PRIVATE>
  41
  42 M: sequence all-unique?
  43     dup length <hash-set> [ (all-unique?) ] curry all? ;