core/io/encodings/encodings.factor

   1 ! Copyright (C) 2008 Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math kernel sequences sbufs vectors namespaces growable
   4 strings io classes continuations destructors combinators
   5 io.streams.plain splitting byte-arrays
   6 sequences.private accessors ;
   7 IN: io.encodings
   8
   9 ! The encoding descriptor protocol
  10
  11 GENERIC: decode-char ( stream encoding -- char/f )
  12
  13 GENERIC: encode-char ( char stream encoding -- )
  14
  15 GENERIC: <decoder> ( stream encoding -- newstream )
  16
  17 CONSTANT: replacement-char HEX: fffd
  18
  19 TUPLE: decoder stream code cr ;
  20
  21 ERROR: decode-error ;
  22
  23 GENERIC: <encoder> ( stream encoding -- newstream )
  24
  25 TUPLE: encoder stream code ;
  26
  27 ERROR: encode-error ;
  28
  29 ! Decoding
  30
  31 M: object <decoder> f decoder boa ;
  32
  33 <PRIVATE
  34
  35 : cr+ ( stream -- ) t >>cr drop ; inline
  36
  37 : cr- ( stream -- ) f >>cr drop ; inline
  38
  39 : >decoder< ( decoder -- stream encoding )
  40     [ stream>> ] [ code>> ] bi ; inline
  41
  42 : fix-read1 ( stream char -- char )
  43     over cr>> [
  44         over cr-
  45         dup CHAR: \n = [
  46             drop dup stream-read1
  47         ] when
  48     ] when nip ; inline
  49
  50 M: decoder stream-element-type
  51     drop +character+ ;
  52
  53 M: decoder stream-tell stream>> stream-tell ;
  54
  55 M: decoder stream-seek stream>> stream-seek ;
  56
  57 M: decoder stream-read1
  58     dup >decoder< decode-char fix-read1 ;
  59
  60 : fix-read ( stream string -- string )
  61     over cr>> [
  62         over cr-
  63         "\n" ?head [
  64             over stream-read1 [ suffix ] when*
  65         ] when
  66     ] when nip ; inline
  67
  68 : (read) ( n quot -- n string )
  69     over 0 <string> [
  70         [
  71             over [ swapd set-nth-unsafe f ] [ 3drop t ] if
  72         ] curry compose find-integer
  73     ] keep ; inline
  74
  75 : finish-read ( n string -- string/f )
  76     {
  77         { [ over 0 = ] [ 2drop f ] }
  78         { [ over not ] [ nip ] }
  79         [ swap head ]
  80     } cond ; inline
  81
  82 M: decoder stream-read
  83     [ nip ] [ >decoder< [ decode-char ] 2curry (read) finish-read ] 2bi
  84     fix-read ;
  85
  86 M: decoder stream-read-partial stream-read ;
  87
  88 : line-ends/eof ( stream str -- str ) f like swap cr- ; inline
  89
  90 : line-ends\r ( stream str -- str ) swap cr+ ; inline
  91
  92 : line-ends\n ( stream str -- str )
  93     over cr>> over empty? and
  94     [ drop dup cr- stream-readln ] [ swap cr- ] if ; inline
  95
  96 : handle-readln ( stream str ch -- str )
  97     {
  98         { f [ line-ends/eof ] }
  99         { CHAR: \r [ line-ends\r ] }
 100         { CHAR: \n [ line-ends\n ] }
 101     } case ; inline
 102
 103 : ((read-until)) ( buf quot: ( -- char stop? ) -- string/f sep/f )
 104     dup call
 105     [ [ drop "" like ] dip ]
 106     [ pick push ((read-until)) ] if ; inline recursive
 107
 108 : (read-until) ( quot -- string/f sep/f )
 109     100 <sbuf> swap ((read-until)) ; inline
 110
 111 : decoder-read-until ( seps stream encoding -- string/f sep/f )
 112     [ decode-char dup [ dup rot member? ] [ 2drop f t ] if ] 3curry
 113     (read-until) ;
 114
 115 M: decoder stream-read-until >decoder< decoder-read-until ;
 116
 117 : decoder-readln ( stream encoding -- string/f sep/f )
 118     [ decode-char dup [ dup "\r\n" member? ] [ drop f t ] if ] 2curry
 119     (read-until) ;
 120
 121 M: decoder stream-readln dup >decoder< decoder-readln handle-readln ;
 122
 123 M: decoder dispose stream>> dispose ;
 124
 125 ! Encoding
 126 M: object <encoder> encoder boa ;
 127
 128 : >encoder< ( encoder -- stream encoding )
 129     [ stream>> ] [ code>> ] bi ; inline
 130
 131 M: encoder stream-element-type
 132     drop +character+ ;
 133
 134 M: encoder stream-write1
 135     >encoder< encode-char ;
 136
 137 GENERIC# encoder-write 2 ( string stream encoding -- )
 138
 139 M: string encoder-write
 140     [ encode-char ] 2curry each ;
 141
 142 M: encoder stream-write
 143     >encoder< encoder-write ;
 144
 145 M: encoder dispose stream>> dispose ;
 146
 147 M: encoder stream-flush stream>> stream-flush ;
 148
 149 INSTANCE: encoder plain-writer
 150 PRIVATE>
 151
 152 GENERIC# re-encode 1 ( stream encoding -- newstream )
 153
 154 M: object re-encode <encoder> ;
 155
 156 M: encoder re-encode [ stream>> ] dip re-encode ;
 157
 158 : encode-output ( encoding -- )
 159     output-stream [ swap re-encode ] change ;
 160
 161 : with-encoded-output ( encoding quot -- )
 162     [ [ output-stream get ] dip re-encode ] dip
 163     with-output-stream* ; inline
 164
 165 GENERIC# re-decode 1 ( stream encoding -- newstream )
 166
 167 M: object re-decode <decoder> ;
 168
 169 M: decoder re-decode [ stream>> ] dip re-decode ;
 170
 171 : decode-input ( encoding -- )
 172     input-stream [ swap re-decode ] change ;
 173
 174 : with-decoded-input ( encoding quot -- )
 175     [ [ input-stream get ] dip re-decode ] dip
 176     with-input-stream* ; inline