core/io/encodings/encodings.factor

   1 ! Copyright (C) 2008, 2010 Daniel Ehrenberg, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math kernel sequences sbufs vectors namespaces growable
   4 strings io classes continuations destructors combinators
   5 io.streams.plain splitting byte-arrays
   6 sequences.private accessors ;
   7 IN: io.encodings
   8
   9 ! The encoding descriptor protocol
  10
  11 GENERIC: decode-char ( stream encoding -- char/f )
  12
  13 GENERIC: encode-char ( char stream encoding -- )
  14
  15 GENERIC: encode-string ( string stream encoding -- )
  16
  17 M: object encode-string [ encode-char ] 2curry each ; inline
  18
  19 GENERIC: <decoder> ( stream encoding -- newstream )
  20
  21 CONSTANT: replacement-char HEX: fffd
  22
  23 TUPLE: decoder stream code cr ;
  24
  25 ERROR: decode-error ;
  26
  27 GENERIC: <encoder> ( stream encoding -- newstream )
  28
  29 TUPLE: encoder stream code ;
  30
  31 ERROR: encode-error ;
  32
  33 ! Decoding
  34
  35 M: object <decoder> f decoder boa ;
  36
  37 <PRIVATE
  38
  39 : cr+ ( stream -- ) t >>cr drop ; inline
  40
  41 : cr- ( stream -- ) f >>cr drop ; inline
  42
  43 : >decoder< ( decoder -- stream encoding )
  44     [ stream>> ] [ code>> ] bi ; inline
  45
  46 : fix-read1 ( stream char -- char )
  47     over cr>> [
  48         over cr-
  49         dup CHAR: \n = [
  50             drop dup stream-read1
  51         ] when
  52     ] when nip ; inline
  53
  54 M: decoder stream-element-type
  55     drop +character+ ;
  56
  57 M: decoder stream-tell stream>> stream-tell ;
  58
  59 M: decoder stream-seek stream>> stream-seek ;
  60
  61 M: decoder stream-read1
  62     dup >decoder< decode-char fix-read1 ;
  63
  64 : fix-read ( stream string -- string )
  65     over cr>> [
  66         over cr-
  67         "\n" ?head [
  68             over stream-read1 [ suffix ] when*
  69         ] when
  70     ] when nip ; inline
  71
  72 : (read) ( n quot -- n string )
  73     over 0 <string> [
  74         [
  75             over [ swapd set-nth-unsafe f ] [ 3drop t ] if
  76         ] curry compose find-integer
  77     ] keep ; inline
  78
  79 : finish-read ( n string -- string/f )
  80     {
  81         { [ over 0 = ] [ 2drop f ] }
  82         { [ over not ] [ nip ] }
  83         [ swap head ]
  84     } cond ; inline
  85
  86 M: decoder stream-read
  87     [ nip ] [ >decoder< [ decode-char ] 2curry (read) finish-read ] 2bi
  88     fix-read ;
  89
  90 M: decoder stream-read-partial stream-read ;
  91
  92 : line-ends/eof ( stream str -- str ) f like swap cr- ; inline
  93
  94 : line-ends\r ( stream str -- str ) swap cr+ ; inline
  95
  96 : line-ends\n ( stream str -- str )
  97     over cr>> over empty? and
  98     [ drop dup cr- stream-readln ] [ swap cr- ] if ; inline
  99
 100 : handle-readln ( stream str ch -- str )
 101     {
 102         { f [ line-ends/eof ] }
 103         { CHAR: \r [ line-ends\r ] }
 104         { CHAR: \n [ line-ends\n ] }
 105     } case ; inline
 106
 107 : ((read-until)) ( buf quot: ( -- char stop? ) -- string/f sep/f )
 108     dup call
 109     [ [ drop "" like ] dip ]
 110     [ pick push ((read-until)) ] if ; inline recursive
 111
 112 : (read-until) ( quot -- string/f sep/f )
 113     100 <sbuf> swap ((read-until)) ; inline
 114
 115 : decoder-read-until ( seps stream encoding -- string/f sep/f )
 116     [ decode-char dup [ dup rot member? ] [ 2drop f t ] if ] 3curry
 117     (read-until) ;
 118
 119 M: decoder stream-read-until >decoder< decoder-read-until ;
 120
 121 : decoder-readln ( stream encoding -- string/f sep/f )
 122     [ decode-char dup [ dup "\r\n" member? ] [ drop f t ] if ] 2curry
 123     (read-until) ;
 124
 125 M: decoder stream-readln dup >decoder< decoder-readln handle-readln ;
 126
 127 M: decoder dispose stream>> dispose ;
 128
 129 ! Encoding
 130 M: object <encoder> encoder boa ;
 131
 132 : >encoder< ( encoder -- stream encoding )
 133     [ stream>> ] [ code>> ] bi ; inline
 134
 135 M: encoder stream-element-type
 136     drop +character+ ;
 137
 138 M: encoder stream-write1
 139     >encoder< encode-char ;
 140
 141 M: encoder stream-write
 142     >encoder< encode-string ;
 143
 144 M: encoder dispose stream>> dispose ;
 145
 146 M: encoder stream-flush stream>> stream-flush ;
 147
 148 INSTANCE: encoder plain-writer
 149 PRIVATE>
 150
 151 GENERIC# re-encode 1 ( stream encoding -- newstream )
 152
 153 M: object re-encode <encoder> ;
 154
 155 M: encoder re-encode [ stream>> ] dip re-encode ;
 156
 157 : encode-output ( encoding -- )
 158     output-stream [ swap re-encode ] change ;
 159
 160 : with-encoded-output ( encoding quot -- )
 161     [ [ output-stream get ] dip re-encode ] dip
 162     with-output-stream* ; inline
 163
 164 GENERIC# re-decode 1 ( stream encoding -- newstream )
 165
 166 M: object re-decode <decoder> ;
 167
 168 M: decoder re-decode [ stream>> ] dip re-decode ;
 169
 170 : decode-input ( encoding -- )
 171     input-stream [ swap re-decode ] change ;
 172
 173 : with-decoded-input ( encoding quot -- )
 174     [ [ input-stream get ] dip re-decode ] dip
 175     with-input-stream* ; inline