core/io/encodings/encodings.factor

   1 ! Copyright (C) 2008 Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: math kernel sequences sbufs vectors namespaces growable
   4 strings io classes continuations destructors combinators
   5 io.streams.plain splitting byte-arrays
   6 sequences.private accessors ;
   7 IN: io.encodings
   8
   9 ! The encoding descriptor protocol
  10
  11 GENERIC: decode-char ( stream encoding -- char/f )
  12
  13 GENERIC: encode-char ( char stream encoding -- )
  14
  15 GENERIC: <decoder> ( stream encoding -- newstream )
  16
  17 CONSTANT: replacement-char HEX: fffd
  18
  19 TUPLE: decoder stream code cr ;
  20
  21 ERROR: decode-error ;
  22
  23 GENERIC: <encoder> ( stream encoding -- newstream )
  24
  25 TUPLE: encoder stream code ;
  26
  27 ERROR: encode-error ;
  28
  29 ! Decoding
  30
  31 M: object <decoder> f decoder boa ;
  32
  33 <PRIVATE
  34
  35 : cr+ ( stream -- ) t >>cr drop ; inline
  36
  37 : cr- ( stream -- ) f >>cr drop ; inline
  38
  39 : >decoder< ( decoder -- stream encoding )
  40     [ stream>> ] [ code>> ] bi ; inline
  41
  42 : fix-read1 ( stream char -- char )
  43     over cr>> [
  44         over cr-
  45         dup CHAR: \n = [
  46             drop dup stream-read1
  47         ] when
  48     ] when nip ; inline
  49
  50 M: decoder stream-element-type
  51     drop +character+ ;
  52
  53 M: decoder stream-read1
  54     dup >decoder< decode-char fix-read1 ;
  55
  56 : fix-read ( stream string -- string )
  57     over cr>> [
  58         over cr-
  59         "\n" ?head [
  60             over stream-read1 [ suffix ] when*
  61         ] when
  62     ] when nip ; inline
  63
  64 : (read) ( n quot -- n string )
  65     over 0 <string> [
  66         [
  67             over [ swapd set-nth-unsafe f ] [ 3drop t ] if
  68         ] curry compose find-integer
  69     ] keep ; inline
  70
  71 : finish-read ( n string -- string/f )
  72     {
  73         { [ over 0 = ] [ 2drop f ] }
  74         { [ over not ] [ nip ] }
  75         [ swap head ]
  76     } cond ; inline
  77
  78 M: decoder stream-read
  79     [ nip ] [ >decoder< [ decode-char ] 2curry (read) finish-read ] 2bi
  80     fix-read ;
  81
  82 M: decoder stream-read-partial stream-read ;
  83
  84 : line-ends/eof ( stream str -- str ) f like swap cr- ; inline
  85
  86 : line-ends\r ( stream str -- str ) swap cr+ ; inline
  87
  88 : line-ends\n ( stream str -- str )
  89     over cr>> over empty? and
  90     [ drop dup cr- stream-readln ] [ swap cr- ] if ; inline
  91
  92 : handle-readln ( stream str ch -- str )
  93     {
  94         { f [ line-ends/eof ] }
  95         { CHAR: \r [ line-ends\r ] }
  96         { CHAR: \n [ line-ends\n ] }
  97     } case ; inline
  98
  99 : ((read-until)) ( buf quot: ( -- char stop? ) -- string/f sep/f )
 100     dup call
 101     [ [ drop "" like ] dip ]
 102     [ pick push ((read-until)) ] if ; inline recursive
 103
 104 : (read-until) ( quot -- string/f sep/f )
 105     100 <sbuf> swap ((read-until)) ; inline
 106
 107 : decoder-read-until ( seps stream encoding -- string/f sep/f )
 108     [ decode-char dup [ dup rot member? ] [ 2drop f t ] if ] 3curry
 109     (read-until) ;
 110
 111 M: decoder stream-read-until >decoder< decoder-read-until ;
 112
 113 : decoder-readln ( stream encoding -- string/f sep/f )
 114     [ decode-char dup [ dup "\r\n" member? ] [ drop f t ] if ] 2curry
 115     (read-until) ;
 116
 117 M: decoder stream-readln dup >decoder< decoder-readln handle-readln ;
 118
 119 M: decoder dispose stream>> dispose ;
 120
 121 ! Encoding
 122 M: object <encoder> encoder boa ;
 123
 124 : >encoder< ( encoder -- stream encoding )
 125     [ stream>> ] [ code>> ] bi ; inline
 126
 127 M: encoder stream-element-type
 128     drop +character+ ;
 129
 130 M: encoder stream-write1
 131     >encoder< encode-char ;
 132
 133 : encoder-write ( string stream encoding -- )
 134     [ encode-char ] 2curry each ;
 135
 136 M: encoder stream-write
 137     >encoder< encoder-write ;
 138
 139 M: encoder dispose stream>> dispose ;
 140
 141 M: encoder stream-flush stream>> stream-flush ;
 142
 143 INSTANCE: encoder plain-writer
 144 PRIVATE>
 145
 146 GENERIC# re-encode 1 ( stream encoding -- newstream )
 147
 148 M: object re-encode <encoder> ;
 149
 150 M: encoder re-encode [ stream>> ] dip re-encode ;
 151
 152 : encode-output ( encoding -- )
 153     output-stream [ swap re-encode ] change ;
 154
 155 : with-encoded-output ( encoding quot -- )
 156     [ [ output-stream get ] dip re-encode ] dip
 157     with-output-stream* ; inline
 158
 159 GENERIC# re-decode 1 ( stream encoding -- newstream )
 160
 161 M: object re-decode <decoder> ;
 162
 163 M: decoder re-decode [ stream>> ] dip re-decode ;
 164
 165 : decode-input ( encoding -- )
 166     input-stream [ swap re-decode ] change ;
 167
 168 : with-decoded-input ( encoding quot -- )
 169     [ [ input-stream get ] dip re-decode ] dip
 170     with-input-stream* ; inline