core/io/streams/c/c.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel kernel.private namespaces make io io.encodings sequences
   4 math generic threads.private classes io.backend io.files
   5 io.encodings.utf8 alien.strings continuations destructors byte-arrays
   6 accessors combinators ;
   7 IN: io.streams.c
   8
   9 TUPLE: c-stream < disposable handle ;
  10
  11 : new-c-stream ( handle class -- c-stream )
  12     new-disposable swap >>handle ; inline
  13
  14 M: c-stream dispose* handle>> fclose ;
  15
  16 M: c-stream stream-tell handle>> ftell ;
  17
  18 M: c-stream stream-seek
  19     handle>> swap {
  20         { seek-absolute [ 0 ] }
  21         { seek-relative [ 1 ] }
  22         { seek-end [ 2 ] }
  23         [ bad-seek-type ]
  24     } case fseek ;
  25
  26 TUPLE: c-writer < c-stream ;
  27
  28 : <c-writer> ( handle -- stream ) c-writer new-c-stream ;
  29
  30 M: c-writer stream-element-type drop +byte+ ;
  31
  32 M: c-writer stream-write1 dup check-disposed handle>> fputc ;
  33
  34 M: c-writer stream-write dup check-disposed handle>> fwrite ;
  35
  36 M: c-writer stream-flush dup check-disposed handle>> fflush ;
  37
  38 TUPLE: c-reader < c-stream ;
  39
  40 : <c-reader> ( handle -- stream ) c-reader new-c-stream ;
  41
  42 M: c-reader stream-element-type drop +byte+ ;
  43
  44 M: c-reader stream-read dup check-disposed handle>> fread ;
  45
  46 M: c-reader stream-read-partial stream-read ;
  47
  48 M: c-reader stream-read1 dup check-disposed handle>> fgetc ;
  49
  50 : read-until-loop ( stream delim -- ch )
  51     over stream-read1 dup [
  52         dup pick member-eq? [ 2nip ] [ , read-until-loop ] if
  53     ] [
  54         2nip
  55     ] if ;
  56
  57 M: c-reader stream-read-until
  58     dup check-disposed
  59     [ swap read-until-loop ] B{ } make swap
  60     over empty? over not and [ 2drop f f ] when ;
  61
  62 M: c-io-backend init-io ;
  63
  64 : stdin-handle ( -- alien ) 11 getenv ;
  65 : stdout-handle ( -- alien ) 12 getenv ;
  66 : stderr-handle ( -- alien ) 61 getenv ;
  67
  68 : init-c-stdio ( -- )
  69     stdin-handle <c-reader>
  70     stdout-handle <c-writer>
  71     stderr-handle <c-writer>
  72     set-stdio ;
  73
  74 M: c-io-backend init-stdio init-c-stdio ;
  75
  76 M: c-io-backend io-multiplex 60 60 * 1000 * 1000 * or (sleep) ;
  77
  78 : fopen ( path mode -- alien )
  79     [ utf8 string>alien ] bi@ (fopen) ;
  80
  81 M: c-io-backend (file-reader)
  82     "rb" fopen <c-reader> ;
  83
  84 M: c-io-backend (file-writer)
  85     "wb" fopen <c-writer> ;
  86
  87 M: c-io-backend (file-appender)
  88     "ab" fopen <c-writer> ;
  89
  90 : show ( msg -- )
  91     #! A word which directly calls primitives. It is used to
  92     #! print stuff from contexts where the I/O system would
  93     #! otherwise not work (tools.deploy.shaker, the I/O
  94     #! multiplexer thread).
  95     "\n" append >byte-array
  96     stdout-handle fwrite
  97     stdout-handle fflush ;