core/io/streams/c/c.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien alien.strings kernel kernel.private namespaces make
   4 io io.encodings sequences math generic threads.private classes
   5 io.backend io.files io.encodings.utf8 continuations destructors
   6 byte-arrays accessors combinators ;
   7 IN: io.streams.c
   8
   9 TUPLE: c-stream < disposable handle ;
  10
  11 : new-c-stream ( handle class -- c-stream )
  12     new-disposable swap >>handle ; inline
  13
  14 M: c-stream dispose* handle>> fclose ;
  15
  16 M: c-stream stream-tell handle>> ftell ;
  17
  18 M: c-stream stream-seek
  19     [
  20         {
  21             { seek-absolute [ 0 ] }
  22             { seek-relative [ 1 ] }
  23             { seek-end [ 2 ] }
  24             [ bad-seek-type ]
  25         } case
  26     ] [ handle>> ] bi* fseek ;
  27
  28 TUPLE: c-writer < c-stream ;
  29
  30 : <c-writer> ( handle -- stream ) c-writer new-c-stream ;
  31
  32 M: c-writer stream-element-type drop +byte+ ;
  33
  34 M: c-writer stream-write1 dup check-disposed handle>> fputc ;
  35
  36 M: c-writer stream-write
  37     dup check-disposed
  38     [ [ >c-ptr ] [ byte-length ] bi ] [ handle>> ] bi* fwrite ;
  39
  40 M: c-writer stream-flush dup check-disposed handle>> fflush ;
  41
  42 TUPLE: c-reader < c-stream ;
  43
  44 : <c-reader> ( handle -- stream ) c-reader new-c-stream ;
  45
  46 M: c-reader stream-element-type drop +byte+ ;
  47
  48 M: c-reader stream-read dup check-disposed handle>> fread ;
  49
  50 M: c-reader stream-read-partial stream-read ;
  51
  52 M: c-reader stream-read1 dup check-disposed handle>> fgetc ;
  53
  54 : read-until-loop ( stream delim -- ch )
  55     over stream-read1 dup [
  56         dup pick member-eq? [ 2nip ] [ , read-until-loop ] if
  57     ] [
  58         2nip
  59     ] if ;
  60
  61 M: c-reader stream-read-until
  62     dup check-disposed
  63     [ swap read-until-loop ] B{ } make swap
  64     over empty? over not and [ 2drop f f ] when ;
  65
  66 M: c-io-backend init-io ;
  67
  68 : stdin-handle ( -- alien ) 11 special-object ;
  69 : stdout-handle ( -- alien ) 12 special-object ;
  70 : stderr-handle ( -- alien ) 61 special-object ;
  71
  72 : init-c-stdio ( -- )
  73     stdin-handle <c-reader>
  74     stdout-handle <c-writer>
  75     stderr-handle <c-writer>
  76     set-stdio ;
  77
  78 M: c-io-backend init-stdio init-c-stdio ;
  79
  80 M: c-io-backend io-multiplex
  81     dup 0 = [ drop ] [ 60 60 * 1000 * 1000 * or (sleep) ] if ;
  82
  83 : fopen ( path mode -- alien )
  84     [ utf8 string>alien ] bi@ (fopen) ;
  85
  86 M: c-io-backend (file-reader)
  87     "rb" fopen <c-reader> ;
  88
  89 M: c-io-backend (file-writer)
  90     "wb" fopen <c-writer> ;
  91
  92 M: c-io-backend (file-appender)
  93     "ab" fopen <c-writer> ;
  94
  95 : show ( msg -- )
  96     #! A word which directly calls primitives. It is used to
  97     #! print stuff from contexts where the I/O system would
  98     #! otherwise not work (tools.deploy.shaker, the I/O
  99     #! multiplexer thread).
 100     "\n" append >byte-array dup length
 101     stdout-handle fwrite
 102     stdout-handle fflush ;