core/io/streams/c/c.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel kernel.private namespaces make io io.encodings sequences
   4 math generic threads.private classes io.backend io.files
   5 io.encodings.utf8 alien.strings continuations destructors byte-arrays
   6 accessors combinators ;
   7 IN: io.streams.c
   8
   9 TUPLE: c-stream < disposable handle ;
  10
  11 : new-c-stream ( handle class -- c-stream )
  12     new-disposable swap >>handle ; inline
  13
  14 M: c-stream dispose* handle>> fclose ;
  15
  16 M: c-stream stream-seek
  17     handle>> swap {
  18         { seek-absolute [ 0 ] }
  19         { seek-relative [ 1 ] }
  20         { seek-end [ 2 ] }
  21         [ bad-seek-type ]
  22     } case fseek ;
  23
  24 TUPLE: c-writer < c-stream ;
  25
  26 : <c-writer> ( handle -- stream ) c-writer new-c-stream ;
  27
  28 M: c-writer stream-element-type drop +byte+ ;
  29
  30 M: c-writer stream-write1 dup check-disposed handle>> fputc ;
  31
  32 M: c-writer stream-write dup check-disposed handle>> fwrite ;
  33
  34 M: c-writer stream-flush dup check-disposed handle>> fflush ;
  35
  36 TUPLE: c-reader < c-stream ;
  37
  38 : <c-reader> ( handle -- stream ) c-reader new-c-stream ;
  39
  40 M: c-reader stream-element-type drop +byte+ ;
  41
  42 M: c-reader stream-read dup check-disposed handle>> fread ;
  43
  44 M: c-reader stream-read-partial stream-read ;
  45
  46 M: c-reader stream-read1 dup check-disposed handle>> fgetc ;
  47
  48 : read-until-loop ( stream delim -- ch )
  49     over stream-read1 dup [
  50         dup pick memq? [ 2nip ] [ , read-until-loop ] if
  51     ] [
  52         2nip
  53     ] if ;
  54
  55 M: c-reader stream-read-until
  56     dup check-disposed
  57     [ swap read-until-loop ] B{ } make swap
  58     over empty? over not and [ 2drop f f ] when ;
  59
  60 M: c-io-backend init-io ;
  61
  62 : stdin-handle ( -- alien ) 11 getenv ;
  63 : stdout-handle ( -- alien ) 12 getenv ;
  64 : stderr-handle ( -- alien ) 61 getenv ;
  65
  66 : init-c-stdio ( -- )
  67     stdin-handle <c-reader>
  68     stdout-handle <c-writer>
  69     stderr-handle <c-writer>
  70     set-stdio ;
  71
  72 M: c-io-backend init-stdio init-c-stdio ;
  73
  74 M: c-io-backend io-multiplex 60 60 * 1000 * 1000 * or (sleep) ;
  75
  76 : fopen ( path mode -- alien )
  77     [ utf8 string>alien ] bi@ (fopen) ;
  78
  79 M: c-io-backend (file-reader)
  80     "rb" fopen <c-reader> ;
  81
  82 M: c-io-backend (file-writer)
  83     "wb" fopen <c-writer> ;
  84
  85 M: c-io-backend (file-appender)
  86     "ab" fopen <c-writer> ;
  87
  88 : show ( msg -- )
  89     #! A word which directly calls primitives. It is used to
  90     #! print stuff from contexts where the I/O system would
  91     #! otherwise not work (tools.deploy.shaker, the I/O
  92     #! multiplexer thread).
  93     "\n" append >byte-array
  94     stdout-handle fwrite
  95     stdout-handle fflush ;