core/io/streams/sequence/sequence.factor

   1 ! Copyright (C) 2009 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors byte-arrays classes combinators destructors
   4 growable io io.private io.streams.plain kernel math math.order
   5 sequences sequences.private strings ;
   6 IN: io.streams.sequence
   7
   8 ! Readers
   9 SLOT: underlying
  10 SLOT: i
  11
  12 : >sequence-stream< ( stream -- i underlying )
  13     [ i>> ] [ underlying>> ] bi ; inline
  14
  15 : sequence-read1 ( stream -- elt/f )
  16     dup >sequence-stream< dupd ?nth [ 1 + swap i<< ] dip ; inline
  17
  18 <PRIVATE
  19
  20 : (sequence-read-length) ( n buf stream -- buf count )
  21     [ underlying>> length ] [ i>> ] bi - rot min ; inline
  22
  23 : <sequence-copy> ( dst n src-i src dst-i -- n copy )
  24     [ ] curry 3curry dip <copier> ; inline
  25
  26 : sequence-copy-unsafe ( n buf stream offset -- count )
  27     [
  28         [ (sequence-read-length) ]
  29         [ [ dup pick + ] change-i underlying>> ] bi
  30     ] dip [ <sequence-copy> (copy) drop ] 3curry keep ; inline
  31
  32 : (sequence-read-unsafe) ( n buf stream -- count )
  33     [ integer>fixnum ]
  34     [ dup slice? [ [ seq>> ] [ from>> ] bi ] [ 0 ] if ]
  35     [
  36         tuck stream-element-type +byte+ eq?
  37         [ [ byte-array check-instance ] 2dip sequence-copy-unsafe ]
  38         [ [ string check-instance ] 2dip sequence-copy-unsafe ] if
  39     ] tri* ; inline
  40
  41 PRIVATE>
  42
  43 : sequence-read-unsafe ( n buf stream -- count )
  44     dup >sequence-stream< bounds-check?
  45     [ (sequence-read-unsafe) ] [ 3drop 0 ] if ; inline
  46
  47 <PRIVATE
  48
  49 : find-separator ( seps stream -- sep/f n )
  50     >sequence-stream< rot [ member? ] curry
  51     [ find-from swap ] curry 2keep pick
  52     [ drop - ] [ length swap - nip ] if ; inline
  53
  54 : (sequence-read-until) ( seps stream -- seq sep/f )
  55     [ find-separator ] keep
  56     [ [ (sequence-read-unsafe) ] (read-into-new) ]
  57     [ [ 1 + ] change-i drop ]
  58     [ stream-exemplar or ] tri swap ; inline
  59
  60 PRIVATE>
  61
  62 : sequence-read-until ( seps stream -- seq sep/f )
  63     dup >sequence-stream< bounds-check?
  64     [ (sequence-read-until) ] [ 2drop f f ] if ; inline
  65
  66 ! Writers
  67 M: growable dispose drop ;
  68
  69 M: growable stream-write1 push ;
  70 M: growable stream-write push-all ;
  71 M: growable stream-flush drop ;
  72
  73 INSTANCE: growable output-stream
  74 INSTANCE: growable plain-writer
  75
  76 ! Seeking
  77 : sequence-seek ( n seek-type stream -- )
  78     swap {
  79         { seek-absolute [ i<< ] }
  80         { seek-relative [ [ + ] change-i drop ] }
  81         { seek-end [ [ underlying>> length + ] [ i<< ] bi ] }
  82         [ bad-seek-type ]
  83     } case ;