core/kernel/kernel.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USE: slots.private
   4 USE: kernel.private
   5 USE: math.private
   6 IN: kernel
   7
   8 BUILTIN: callstack ;
   9 BUILTIN: tuple ;
  10 BUILTIN: wrapper { wrapped read-only } ;
  11
  12 PRIMITIVE: -rot ( x y z -- z x y )
  13 PRIMITIVE: dup ( x -- x x )
  14 PRIMITIVE: dupd ( x y -- x x y )
  15 PRIMITIVE: drop ( x -- )
  16 PRIMITIVE: nip ( x y -- y )
  17 PRIMITIVE: over ( x y -- x y x )
  18 PRIMITIVE: pick ( x y z -- x y z x )
  19 PRIMITIVE: rot ( x y z -- y z x )
  20 PRIMITIVE: swap ( x y -- y x )
  21 PRIMITIVE: swapd ( x y z -- y x z )
  22 PRIMITIVE: 2drop ( x y -- )
  23 PRIMITIVE: 2dup ( x y -- x y x y )
  24 PRIMITIVE: 2nip ( x y z -- z )
  25 PRIMITIVE: 3drop ( x y z -- )
  26 PRIMITIVE: 3dup ( x y z -- x y z x y z )
  27 PRIMITIVE: 4drop ( w x y z -- )
  28 PRIMITIVE: 4dup ( w x y z -- w x y z w x y z )
  29
  30 PRIMITIVE: (clone) ( obj -- newobj )
  31 PRIMITIVE: eq? ( obj1 obj2 -- ? )
  32 PRIMITIVE: <wrapper> ( obj -- wrapper )
  33 PRIMITIVE: die ( -- )
  34 PRIMITIVE: callstack>array ( callstack -- array )
  35
  36 <PRIVATE
  37 PRIMITIVE: (call) ( quot -- )
  38 PRIMITIVE: (execute) ( word -- )
  39 PRIMITIVE: (identity-hashcode) ( obj -- code )
  40 PRIMITIVE: become ( old new -- )
  41 PRIMITIVE: c-to-factor ( -- )
  42 PRIMITIVE: callstack-bounds ( -- start end )
  43 PRIMITIVE: check-datastack ( array in# out# -- ? )
  44 PRIMITIVE: compute-identity-hashcode ( obj -- )
  45 PRIMITIVE: context-object ( n -- obj )
  46 PRIMITIVE: fpu-state ( -- )
  47 PRIMITIVE: innermost-frame-executing ( callstack -- obj )
  48 PRIMITIVE: innermost-frame-scan ( callstack -- n )
  49 PRIMITIVE: lazy-jit-compile ( -- )
  50 PRIMITIVE: leaf-signal-handler ( -- )
  51 PRIMITIVE: set-callstack ( callstack -- * )
  52 PRIMITIVE: set-context-object ( obj n -- )
  53 PRIMITIVE: set-datastack ( array -- )
  54 PRIMITIVE: set-fpu-state ( -- )
  55 PRIMITIVE: set-innermost-frame-quotation ( n callstack -- )
  56 PRIMITIVE: set-retainstack ( array -- )
  57 PRIMITIVE: set-special-object ( obj n -- )
  58 PRIMITIVE: signal-handler ( -- )
  59 PRIMITIVE: special-object ( n -- obj )
  60 PRIMITIVE: strip-stack-traces ( -- )
  61 PRIMITIVE: tag ( object -- n )
  62 PRIMITIVE: unwind-native-frames ( -- )
  63 PRIVATE>
  64
  65 DEFER: dip
  66 DEFER: 2dip
  67 DEFER: 3dip
  68
  69 ! Stack stuff
  70 : 2over ( x y z -- x y z x y ) pick pick ; inline
  71
  72 : clear ( -- ) { } set-datastack ;
  73
  74 ! Combinators
  75 GENERIC: call ( callable -- )
  76
  77 GENERIC: execute ( word -- )
  78
  79 DEFER: if
  80
  81 : ? ( ? true false -- true/false )
  82     ! 'if' and '?' can be defined in terms of each other
  83     ! because the JIT special-cases an 'if' preceded by
  84     ! two literal quotations.
  85     rot [ drop ] [ nip ] if ; inline
  86
  87 : if ( ..a ? true: ( ..a -- ..b ) false: ( ..a -- ..b ) -- ..b ) ? call ;
  88
  89 ! Single branch
  90 : unless ( ..a ? false: ( ..a -- ..a ) -- ..a )
  91     swap [ drop ] [ call ] if ; inline
  92
  93 : when ( ..a ? true: ( ..a -- ..a ) -- ..a )
  94     swap [ call ] [ drop ] if ; inline
  95
  96 ! Anaphoric
  97 : if* ( ..a ? true: ( ..a ? -- ..b ) false: ( ..a -- ..b ) -- ..b )
  98     pick [ drop call ] [ 2nip call ] if ; inline
  99
 100 : when* ( ..a ? true: ( ..a ? -- ..a ) -- ..a )
 101     over [ call ] [ 2drop ] if ; inline
 102
 103 : unless* ( ..a ? false: ( ..a -- ..a x ) -- ..a x )
 104     over [ drop ] [ nip call ] if ; inline
 105
 106 : transmute* ( obj quot: ( obj -- obj/f ) -- new/old changed? )
 107     over [ call ] dip over [ drop t ] [ nip f ] if ; inline
 108
 109 : transmute ( obj quot: ( obj -- new/old ) -- new/old ) transmute* drop ; inline
 110
 111 : ?transmute ( obj/f quot -- obj' ) dupd when ; inline
 112
 113 ! Default
 114
 115 : ?if-old ( ..a obj cond true: ( ..a cond -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 116     pick [ drop [ drop ] 2dip call ] [ 2nip call ] if ; inline
 117
 118 : ?when ( ..a obj cond: ( ..a obj -- obj/f ) true: ( ..a cond -- ..b ) -- ..b )
 119     [ transmute* ] dip when ; inline
 120
 121 : ?unless ( ..a obj cond: ( ..a obj -- obj/f ) false: ( ..a default -- ..b ) -- ..b )
 122     [ transmute* ] dip unless ; inline
 123
 124 : ??if ( ..a obj cond: ( ..a obj -- obj/f ) true: ( ..a cond -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 125     [ transmute* ] 2dip if ; inline
 126
 127 : ?if ( ..a obj cond true: ( ..a cond -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 128     [ transmute* ] 2dip if ; inline
 129
 130 ! Dippers.
 131 ! Not declared inline because the compiler special-cases them
 132
 133 : dip ( x quot -- x ) swap [ call ] dip ;
 134
 135 : 2dip ( x y quot -- x y ) swap [ dip ] dip ;
 136
 137 : 3dip ( x y z quot -- x y z ) swap [ 2dip ] dip ;
 138
 139 : 4dip ( w x y z quot -- w x y z ) swap [ 3dip ] dip ; inline
 140
 141 ! Misfits
 142 : tuck ( x y -- y x y ) dup -rot ; inline
 143
 144 : spin ( x y z -- z y x ) -rot swap ; inline
 145
 146 : rotd ( w x y z -- x y w z ) [ rot ] dip ; inline
 147
 148 : -rotd ( w x y z -- y w x z ) [ -rot ] dip ; inline
 149
 150 : roll ( w x y z -- x y z w ) rotd swap ; inline
 151
 152 : -roll ( w x y z -- z w x y ) swap -rotd ; inline
 153
 154 : nipd ( x y z -- y z ) [ nip ] dip ; inline
 155
 156 : overd ( x y z -- x y x z ) [ over ] dip ; inline
 157
 158 : pickd ( w x y z -- w x y w z ) [ pick ] dip ; inline
 159
 160 : 2nipd ( w x y z -- y z ) [ 2drop ] 2dip ; inline
 161
 162 : 3nipd ( v w x y z -- y z ) [ 3drop ] 2dip ; inline
 163
 164 : 3nip ( w x y z -- z ) 2nip nip ; inline
 165
 166 : 4nip ( v w x y z -- z ) 2nip 2nip ; inline
 167
 168 : 5nip ( u v w x y z -- z ) 3nip 2nip ; inline
 169
 170 : 5drop ( v w x y z -- ) 4drop drop ; inline
 171
 172 : reach ( w x y z -- w x y z w ) [ pick ] dip swap ; inline
 173
 174 ! Keepers
 175 : keep ( ..a x quot: ( ..a x -- ..b ) -- ..b x )
 176     over [ call ] dip ; inline
 177
 178 : 2keep ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x y )
 179     [ 2dup ] dip 2dip ; inline
 180
 181 : 3keep ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y z )
 182     [ 3dup ] dip 3dip ; inline
 183
 184 : 4keep ( ..a w x y z quot: ( ..a w x y z -- ..b ) -- ..b w x y z )
 185     [ 4dup ] dip 4dip ; inline
 186
 187 : keepd ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x )
 188     2keep drop ; inline
 189
 190 : keepdd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x )
 191     3keep 2drop ; inline
 192
 193 : 2keepd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y )
 194     3keep drop ; inline
 195
 196 ! Cleavers
 197 : bi ( x p q -- )
 198     [ keep ] dip call ; inline
 199
 200 : tri ( x p q r -- )
 201     [ [ keep ] dip keep ] dip call ; inline
 202
 203 ! Double cleavers
 204 : 2bi ( x y p q -- )
 205     [ 2keep ] dip call ; inline
 206
 207 : 2tri ( x y p q r -- )
 208     [ [ 2keep ] dip 2keep ] dip call ; inline
 209
 210 ! Triple cleavers
 211 : 3bi ( x y z p q -- )
 212     [ 3keep ] dip call ; inline
 213
 214 : 3tri ( x y z p q r -- )
 215     [ [ 3keep ] dip 3keep ] dip call ; inline
 216
 217 ! Spreaders
 218 : bi* ( x y p q -- )
 219     [ dip ] dip call ; inline
 220
 221 : tri* ( x y z p q r -- )
 222     [ [ 2dip ] dip dip ] dip call ; inline
 223
 224 ! Double spreaders
 225 : 2bi* ( w x y z p q -- )
 226     [ 2dip ] dip call ; inline
 227
 228 : 2tri* ( u v w x y z p q r -- )
 229     [ 4dip ] 2dip 2bi* ; inline
 230
 231 ! Appliers
 232 : bi@ ( x y quot -- )
 233     dup bi* ; inline
 234
 235 : tri@ ( x y z quot -- )
 236     dup dup tri* ; inline
 237
 238 ! Double appliers
 239 : 2bi@ ( w x y z quot -- )
 240     dup 2bi* ; inline
 241
 242 : 2tri@ ( u v w x y z quot -- )
 243     dup dup 2tri* ; inline
 244
 245 ! Quotation building
 246 : 2curry ( obj1 obj2 quot -- curried )
 247     curry curry ; inline
 248
 249 : 3curry ( obj1 obj2 obj3 quot -- curried )
 250     curry curry curry ; inline
 251
 252 : with ( param obj quot -- obj curried )
 253     swapd [ swapd call ] 2curry ; inline
 254
 255 : 2with ( param1 param2 obj quot -- obj curried )
 256     with with ; inline
 257
 258 : withd ( param obj quot -- obj curried )
 259     swapd [ -rotd call ] 2curry ; inline
 260
 261 : prepose ( quot1 quot2 -- composed )
 262     swap compose ; inline
 263
 264 ! Curried cleavers
 265 <PRIVATE
 266
 267 : currier ( quot -- quot' ) [ curry ] curry ; inline
 268
 269 PRIVATE>
 270
 271 : bi-curry ( x p q -- p' q' ) [ currier ] bi@ bi ; inline
 272
 273 : tri-curry ( x p q r -- p' q' r' ) [ currier ] tri@ tri ; inline
 274
 275 : bi-curry* ( x y p q -- p' q' ) [ currier ] bi@ bi* ; inline
 276
 277 : tri-curry* ( x y z p q r -- p' q' r' ) [ currier ] tri@ tri* ; inline
 278
 279 : bi-curry@ ( x y q -- p' q' ) currier bi@ ; inline
 280
 281 : tri-curry@ ( x y z q -- p' q' r' ) currier tri@ ; inline
 282
 283 ! Booleans
 284 UNION: boolean POSTPONE: t POSTPONE: f ;
 285
 286 : >boolean ( obj -- ? ) [ t ] [ f ] if ; inline
 287
 288 : not ( obj -- ? ) [ f ] [ t ] if ; inline
 289
 290 : and ( obj1 obj2 -- ? ) over ? ; inline
 291
 292 : or ( obj1 obj2 -- ? ) dupd ? ; inline
 293
 294 : xor ( obj1 obj2 -- ? ) [ f swap ? ] when* ; inline
 295
 296 : both? ( x y quot -- ? ) bi@ and ; inline
 297
 298 : either? ( x y quot -- ? ) bi@ or ; inline
 299
 300 : most ( x y quot -- z ) 2keep ? ; inline
 301
 302 : negate ( quot -- quot' ) [ not ] compose ; inline
 303
 304 ! Loops
 305 : loop ( ... pred: ( ... -- ... ? ) -- ... )
 306     [ call ] keep [ loop ] curry when ; inline recursive
 307
 308 : do ( pred body -- pred body )
 309     dup 2dip ; inline
 310
 311 : while ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 312     swap do compose [ loop ] curry when ; inline
 313
 314 : while* ( ..a pred: ( ..a -- ..b ? ) body: ( ..b ? -- ..a ) -- ..b )
 315     [ [ dup ] compose ] dip while drop ; inline
 316
 317 : until ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 318     [ negate ] dip while ; inline
 319
 320 ! Object protocol
 321 GENERIC: hashcode* ( depth obj -- code ) flushable
 322
 323 M: object hashcode* 2drop 0 ; inline
 324
 325 M: f hashcode* 2drop 31337 ; inline
 326
 327 : hashcode ( obj -- code ) 3 swap hashcode* ; inline
 328
 329 GENERIC: equal? ( obj1 obj2 -- ? )
 330
 331 M: object equal? 2drop f ; inline
 332
 333 TUPLE: identity-tuple ;
 334
 335 M: identity-tuple equal? 2drop f ; inline
 336
 337 : identity-hashcode ( obj -- code )
 338     dup tag 0 eq? [
 339         dup tag 1 eq? [ drop 0 ] [
 340             dup (identity-hashcode) dup 0 eq? [
 341                 drop dup compute-identity-hashcode
 342                 (identity-hashcode)
 343             ] [ nip ] if
 344         ] if
 345     ] unless ; inline
 346
 347 M: identity-tuple hashcode* nip identity-hashcode ; inline
 348
 349 : = ( obj1 obj2 -- ? )
 350     2dup eq? [ 2drop t ] [
 351         2dup both-fixnums? [ 2drop f ] [ equal? ] if
 352     ] if ; inline
 353
 354 : same? ( x y quot -- ? ) bi@ = ; inline
 355
 356 GENERIC: clone ( obj -- cloned )
 357
 358 M: object clone ; inline
 359
 360 M: callstack clone (clone) ; inline
 361
 362 ! Tuple construction
 363 GENERIC: new ( class -- tuple )
 364
 365 GENERIC: boa ( slots... class -- tuple )
 366
 367 ! Error handling -- defined early so that other files can
 368 ! throw errors before continuations are loaded
 369 GENERIC: throw ( error -- * )
 370
 371 ERROR: assert got expect ;
 372
 373 : assert= ( a b -- ) 2dup = [ 2drop ] [ assert ] if ;
 374
 375 <PRIVATE
 376
 377 : declare ( spec -- ) drop ;
 378
 379 : do-primitive ( number -- ) "Improper primitive call" throw ;
 380
 381 ! Special object count and identifiers must be kept in sync with:
 382 !   vm/objects.hpp
 383 CONSTANT: special-object-count 85
 384
 385 CONSTANT: OBJ-WALKER-HOOK 3
 386
 387 CONSTANT: OBJ-CALLCC-1 4
 388
 389 CONSTANT: ERROR-HANDLER-QUOT 5
 390
 391 CONSTANT: OBJ-CELL-SIZE 7
 392 CONSTANT: OBJ-CPU 8
 393 CONSTANT: OBJ-OS 9
 394
 395 CONSTANT: OBJ-ARGS 10
 396 CONSTANT: OBJ-STDIN 11
 397 CONSTANT: OBJ-STDOUT 12
 398
 399 CONSTANT: OBJ-IMAGE 13
 400 CONSTANT: OBJ-EXECUTABLE 14
 401
 402 CONSTANT: OBJ-EMBEDDED 15
 403 CONSTANT: OBJ-EVAL-CALLBACK 16
 404 CONSTANT: OBJ-YIELD-CALLBACK 17
 405 CONSTANT: OBJ-SLEEP-CALLBACK 18
 406
 407 CONSTANT: OBJ-STARTUP-QUOT 20
 408 CONSTANT: OBJ-GLOBAL 21
 409 CONSTANT: OBJ-SHUTDOWN-QUOT 22
 410
 411 CONSTANT: JIT-PROLOG 23
 412 CONSTANT: JIT-PRIMITIVE-WORD 24
 413 CONSTANT: JIT-PRIMITIVE 25
 414 CONSTANT: JIT-WORD-JUMP 26
 415 CONSTANT: JIT-WORD-CALL 27
 416 CONSTANT: JIT-IF-WORD 28
 417 CONSTANT: JIT-IF 29
 418 CONSTANT: JIT-SAFEPOINT 30
 419 CONSTANT: JIT-EPILOG 31
 420 CONSTANT: JIT-RETURN 32
 421 CONSTANT: JIT-UNUSED 33
 422 CONSTANT: JIT-PUSH-LITERAL 34
 423 CONSTANT: JIT-DIP-WORD 35
 424 CONSTANT: JIT-DIP 36
 425 CONSTANT: JIT-2DIP-WORD 37
 426 CONSTANT: JIT-2DIP 38
 427 CONSTANT: JIT-3DIP-WORD 39
 428 CONSTANT: JIT-3DIP 40
 429 CONSTANT: JIT-EXECUTE 41
 430 CONSTANT: JIT-DECLARE-WORD 42
 431
 432 CONSTANT: C-TO-FACTOR-WORD 43
 433 CONSTANT: LAZY-JIT-COMPILE-WORD 44
 434 CONSTANT: UNWIND-NATIVE-FRAMES-WORD 45
 435 CONSTANT: GET-FPU-STATE-WORD 46
 436 CONSTANT: SET-FPU-STATE-WORD 47
 437 CONSTANT: SIGNAL-HANDLER-WORD 48
 438 CONSTANT: LEAF-SIGNAL-HANDLER-WORD 49
 439 CONSTANT: WIN-EXCEPTION-HANDLER 50
 440
 441 CONSTANT: OBJ-SAMPLE-CALLSTACKS 51
 442
 443 CONSTANT: REDEFINITION-COUNTER 52
 444
 445 CONSTANT: CALLBACK-STUB 53
 446
 447 CONSTANT: PIC-LOAD 54
 448 CONSTANT: PIC-TAG 55
 449 CONSTANT: PIC-TUPLE 56
 450 CONSTANT: PIC-CHECK-TAG 57
 451 CONSTANT: PIC-CHECK-TUPLE 58
 452 CONSTANT: PIC-HIT 59
 453 CONSTANT: PIC-MISS-WORD 60
 454 CONSTANT: PIC-MISS-TAIL-WORD 61
 455
 456 CONSTANT: MEGA-LOOKUP 62
 457 CONSTANT: MEGA-LOOKUP-WORD 63
 458 CONSTANT: MEGA-MISS-WORD 64
 459
 460 CONSTANT: OBJ-UNDEFINED 65
 461
 462 CONSTANT: OBJ-STDERR 66
 463
 464 CONSTANT: OBJ-STAGE2 67
 465
 466 CONSTANT: OBJ-CURRENT-THREAD 68
 467
 468 CONSTANT: OBJ-THREADS 69
 469 CONSTANT: OBJ-RUN-QUEUE 70
 470 CONSTANT: OBJ-SLEEP-QUEUE 71
 471
 472 CONSTANT: OBJ-VM-COMPILER 72
 473
 474 CONSTANT: OBJ-WAITING-CALLBACKS 73
 475
 476 CONSTANT: OBJ-SIGNAL-PIPE 74
 477
 478 CONSTANT: OBJ-VM-COMPILE-TIME 75
 479
 480 CONSTANT: OBJ-VM-VERSION 76
 481 CONSTANT: OBJ-VM-GIT-LABEL 77
 482
 483 CONSTANT: OBJ-CANONICAL-TRUE 78
 484
 485 CONSTANT: OBJ-BIGNUM-ZERO 79
 486 CONSTANT: OBJ-BIGNUM-POS-ONE 80
 487 CONSTANT: OBJ-BIGNUM-NEG-ONE 81
 488
 489 ! Context object count and identifiers must be kept in sync with:
 490 !   vm/contexts.hpp
 491
 492 CONSTANT: context-object-count 4
 493
 494 CONSTANT: CONTEXT-OBJ-NAMESTACK 0
 495 CONSTANT: CONTEXT-OBJ-CATCHSTACK 1
 496 CONSTANT: CONTEXT-OBJ-CONTEXT 2
 497 CONSTANT: CONTEXT-OBJ-IN-CALLBACK-P 3
 498
 499 ! Runtime errors must be kept in sync with:
 500 !   basis/debugger/debugger.factor
 501 !   vm/errors.hpp
 502
 503 ! VM adds this to kernel errors, so that user-space can identify them.
 504 CONSTANT: KERNEL-ERROR 0xfac7
 505
 506 CONSTANT: kernel-error-count 20
 507
 508 CONSTANT: ERROR-EXPIRED 0
 509 CONSTANT: ERROR-IO      1
 510 CONSTANT: ERROR-NOT-IMPLEMENTED 2
 511 CONSTANT: ERROR-TYPE 3
 512 CONSTANT: ERROR-DIVIDE-BY-ZERO 4
 513 CONSTANT: ERROR-SIGNAL 5
 514 CONSTANT: ERROR-ARRAY-SIZE 6
 515 CONSTANT: ERROR-OUT-OF-FIXNUM-RANGE 7
 516 CONSTANT: ERROR-FFI 8
 517 CONSTANT: ERROR-UNDEFINED-SYMBOL 9
 518 CONSTANT: ERROR-DATASTACK-UNDERFLOW 10
 519 CONSTANT: ERROR-DATASTACK-OVERFLOW 11
 520 CONSTANT: ERROR-RETAINSTACK-UNDERFLOW 12
 521 CONSTANT: ERROR-RETAINSTACK-OVERFLOW 13
 522 CONSTANT: ERROR-CALLSTACK-UNDERFLOW 14
 523 CONSTANT: ERROR-CALLSTACK-OVERFLOW 15
 524 CONSTANT: ERROR-MEMORY 16
 525 CONSTANT: ERROR-FP-TRAP 17
 526 CONSTANT: ERROR-INTERRUPT 18
 527 CONSTANT: ERROR-CALLBACK-SPACE-OVERFLOW 19
 528
 529 PRIMITIVE: callstack-for ( context -- array )
 530 PRIMITIVE: retainstack-for ( context -- array )
 531 PRIMITIVE: datastack-for ( context -- array )
 532
 533 : context ( -- context )
 534     CONTEXT-OBJ-CONTEXT context-object ; inline
 535
 536 PRIVATE>
 537
 538 : get-callstack ( -- callstack )
 539     context callstack-for ; inline
 540
 541 : get-datastack ( -- array )
 542     context datastack-for ; inline
 543
 544 : get-retainstack ( -- array )
 545     context retainstack-for ; inline