core/kernel/kernel.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USE: slots.private
   4 USE: kernel.private
   5 USE: math.private
   6 IN: kernel
   7
   8 BUILTIN: callstack ;
   9 BUILTIN: tuple ;
  10 BUILTIN: wrapper { wrapped read-only } ;
  11
  12 PRIMITIVE: -rot ( x y z -- z x y )
  13 PRIMITIVE: dup ( x -- x x )
  14 PRIMITIVE: dupd ( x y -- x x y )
  15 PRIMITIVE: drop ( x -- )
  16 PRIMITIVE: nip ( x y -- y )
  17 PRIMITIVE: over ( x y -- x y x )
  18 PRIMITIVE: pick ( x y z -- x y z x )
  19 PRIMITIVE: rot ( x y z -- y z x )
  20 PRIMITIVE: swap ( x y -- y x )
  21 PRIMITIVE: swapd ( x y z -- y x z )
  22 PRIMITIVE: 2drop ( x y -- )
  23 PRIMITIVE: 2dup ( x y -- x y x y )
  24 PRIMITIVE: 2nip ( x y z -- z )
  25 PRIMITIVE: 3drop ( x y z -- )
  26 PRIMITIVE: 3dup ( x y z -- x y z x y z )
  27 PRIMITIVE: 4drop ( w x y z -- )
  28 PRIMITIVE: 4dup ( w x y z -- w x y z w x y z )
  29
  30 PRIMITIVE: (clone) ( obj -- newobj )
  31 PRIMITIVE: eq? ( obj1 obj2 -- ? )
  32 PRIMITIVE: <wrapper> ( obj -- wrapper )
  33 PRIMITIVE: die ( -- )
  34 PRIMITIVE: callstack>array ( callstack -- array )
  35
  36 <PRIVATE
  37 PRIMITIVE: (call) ( quot -- )
  38 PRIMITIVE: (execute) ( word -- )
  39 PRIMITIVE: (identity-hashcode) ( obj -- code )
  40 PRIMITIVE: become ( old new -- )
  41 PRIMITIVE: c-to-factor ( -- )
  42 PRIMITIVE: callstack-bounds ( -- start end )
  43 PRIMITIVE: check-datastack ( array in# out# -- ? )
  44 PRIMITIVE: compute-identity-hashcode ( obj -- )
  45 PRIMITIVE: context-object ( n -- obj )
  46 PRIMITIVE: fpu-state ( -- )
  47 PRIMITIVE: innermost-frame-executing ( callstack -- obj )
  48 PRIMITIVE: innermost-frame-scan ( callstack -- n )
  49 PRIMITIVE: lazy-jit-compile ( -- )
  50 PRIMITIVE: leaf-signal-handler ( -- )
  51 PRIMITIVE: set-callstack ( callstack -- * )
  52 PRIMITIVE: set-context-object ( obj n -- )
  53 PRIMITIVE: set-datastack ( array -- )
  54 PRIMITIVE: set-fpu-state ( -- )
  55 PRIMITIVE: set-innermost-frame-quotation ( n callstack -- )
  56 PRIMITIVE: set-retainstack ( array -- )
  57 PRIMITIVE: set-special-object ( obj n -- )
  58 PRIMITIVE: signal-handler ( -- )
  59 PRIMITIVE: special-object ( n -- obj )
  60 PRIMITIVE: strip-stack-traces ( -- )
  61 PRIMITIVE: tag ( object -- n )
  62 PRIMITIVE: unwind-native-frames ( -- )
  63 PRIVATE>
  64
  65 DEFER: dip
  66 DEFER: 2dip
  67 DEFER: 3dip
  68
  69 ! Stack stuff
  70 : 2over ( x y z -- x y z x y ) pick pick ; inline
  71
  72 : clear ( -- ) { } set-datastack ;
  73
  74 ! Combinators
  75 GENERIC: call ( callable -- )
  76
  77 GENERIC: execute ( word -- )
  78
  79 DEFER: if
  80
  81 : ? ( ? true false -- true/false )
  82     ! 'if' and '?' can be defined in terms of each other
  83     ! because the JIT special-cases an 'if' preceded by
  84     ! two literal quotations.
  85     rot [ drop ] [ nip ] if ; inline
  86
  87 : if ( ..a ? true: ( ..a -- ..b ) false: ( ..a -- ..b ) -- ..b ) ? call ;
  88
  89 ! Single branch
  90 : unless ( ..a ? false: ( ..a -- ..a ) -- ..a )
  91     swap [ drop ] [ call ] if ; inline
  92
  93 : when ( ..a ? true: ( ..a -- ..a ) -- ..a )
  94     swap [ call ] [ drop ] if ; inline
  95
  96 ! Anaphoric
  97 : if* ( ..a ? true: ( ..a ? -- ..b ) false: ( ..a -- ..b ) -- ..b )
  98     pick [ drop call ] [ 2nip call ] if ; inline
  99
 100 : when* ( ..a ? true: ( ..a ? -- ..a ) -- ..a )
 101     over [ call ] [ 2drop ] if ; inline
 102
 103 : unless* ( ..a ? false: ( ..a -- ..a x ) -- ..a x )
 104     over [ drop ] [ nip call ] if ; inline
 105
 106 ! Dippers.
 107 ! Not declared inline because the compiler special-cases them
 108
 109 : dip ( x quot -- x ) swap [ call ] dip ;
 110
 111 : 2dip ( x y quot -- x y ) swap [ dip ] dip ;
 112
 113 : 3dip ( x y z quot -- x y z ) swap [ 2dip ] dip ;
 114
 115 : 4dip ( w x y z quot -- w x y z ) swap [ 3dip ] dip ; inline
 116
 117 ! Misfits
 118 : tuck ( x y -- y x y ) dup -rot ; inline
 119
 120 : rotd ( w x y z -- x y w z ) [ rot ] dip ; inline
 121
 122 : -rotd ( w x y z -- y w x z ) [ -rot ] dip ; inline
 123
 124 : roll ( w x y z -- x y z w ) rotd swap ; inline
 125
 126 : -roll ( w x y z -- z w x y ) swap -rotd ; inline
 127
 128 : spin ( x y z -- z y x ) -rot swap ; inline
 129
 130 : 4spin ( w x y z -- z y x w ) -roll spin ; inline
 131
 132 : nipd ( x y z -- y z ) [ nip ] dip ; inline
 133
 134 : overd ( x y z -- x y x z ) [ over ] dip ; inline
 135
 136 : pickd ( w x y z -- w x y w z ) [ pick ] dip ; inline
 137
 138 : 2nipd ( w x y z -- y z ) [ 2drop ] 2dip ; inline
 139
 140 : 3nipd ( v w x y z -- y z ) [ 3drop ] 2dip ; inline
 141
 142 : 3nip ( w x y z -- z ) 2nip nip ; inline
 143
 144 : 4nip ( v w x y z -- z ) 2nip 2nip ; inline
 145
 146 : 5nip ( u v w x y z -- z ) 3nip 2nip ; inline
 147
 148 : 5drop ( v w x y z -- ) 4drop drop ; inline
 149
 150 : reach ( w x y z -- w x y z w ) [ pick ] dip swap ; inline
 151
 152 ! Keepers
 153 : keep ( ..a x quot: ( ..a x -- ..b ) -- ..b x )
 154     over [ call ] dip ; inline
 155
 156 : 2keep ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x y )
 157     [ 2dup ] dip 2dip ; inline
 158
 159 : 3keep ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y z )
 160     [ 3dup ] dip 3dip ; inline
 161
 162 : 4keep ( ..a w x y z quot: ( ..a w x y z -- ..b ) -- ..b w x y z )
 163     [ 4dup ] dip 4dip ; inline
 164
 165 : keepd ( ..a x y quot: ( ..a x y -- ..b ) -- ..b x )
 166     2keep drop ; inline
 167
 168 : keepdd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x )
 169     3keep 2drop ; inline
 170
 171 : 2keepd ( ..a x y z quot: ( ..a x y z -- ..b ) -- ..b x y )
 172     3keep drop ; inline
 173
 174 : ?call ( ..a obj/f quot: ( ..a obj -- ..a obj' )  -- ..a obj'/f ) dupd when ; inline
 175
 176 : ?transmute ( old quot: ( old -- new/f ) -- new/old new? )
 177     keep over [ drop t ] [ nip f ] if ; inline
 178
 179 : transmute ( old quot: ( old -- new/f ) -- new/old )
 180     ?transmute drop ; inline
 181
 182 ! Default
 183
 184 : ?when ( ..a default cond: ( ..a default -- ..a new/f ) true: ( ..a new -- ..a x ) -- ..a default/x )
 185     [ ?transmute ] dip when ; inline
 186
 187 : ?unless ( ..a default cond: ( ..a default -- ..a new/f ) false: ( ..a default -- ..a x ) -- ..a default/x )
 188     [ ?transmute ] dip unless ; inline
 189
 190 : ?if ( ..a default cond: ( default -- new/f ) true: ( ..a new -- ..b ) false: ( ..a default -- ..b ) -- ..b )
 191     [ ?transmute ] 2dip if ; inline
 192
 193 ! Cleavers
 194 : bi ( x p q -- )
 195     [ keep ] dip call ; inline
 196
 197 : tri ( x p q r -- )
 198     [ [ keep ] dip keep ] dip call ; inline
 199
 200 ! Double cleavers
 201 : 2bi ( x y p q -- )
 202     [ 2keep ] dip call ; inline
 203
 204 : 2tri ( x y p q r -- )
 205     [ [ 2keep ] dip 2keep ] dip call ; inline
 206
 207 ! Triple cleavers
 208 : 3bi ( x y z p q -- )
 209     [ 3keep ] dip call ; inline
 210
 211 : 3tri ( x y z p q r -- )
 212     [ [ 3keep ] dip 3keep ] dip call ; inline
 213
 214 ! Spreaders
 215 : bi* ( x y p q -- )
 216     [ dip ] dip call ; inline
 217
 218 : tri* ( x y z p q r -- )
 219     [ [ 2dip ] dip dip ] dip call ; inline
 220
 221 ! Double spreaders
 222 : 2bi* ( w x y z p q -- )
 223     [ 2dip ] dip call ; inline
 224
 225 : 2tri* ( u v w x y z p q r -- )
 226     [ 4dip ] 2dip 2bi* ; inline
 227
 228 ! Appliers
 229 : bi@ ( x y quot -- )
 230     dup bi* ; inline
 231
 232 : tri@ ( x y z quot -- )
 233     dup dup tri* ; inline
 234
 235 ! Double appliers
 236 : 2bi@ ( w x y z quot -- )
 237     dup 2bi* ; inline
 238
 239 : 2tri@ ( u v w x y z quot -- )
 240     dup dup 2tri* ; inline
 241
 242 ! Quotation building
 243 : 2curry ( obj1 obj2 quot -- curried )
 244     curry curry ; inline
 245
 246 : 3curry ( obj1 obj2 obj3 quot -- curried )
 247     curry curry curry ; inline
 248
 249 : with ( param obj quot -- obj curried )
 250     swapd [ swapd call ] 2curry ; inline
 251
 252 : 2with ( param1 param2 obj quot -- obj curried )
 253     with with ; inline
 254
 255 : withd ( param obj quot -- obj curried )
 256     swapd [ -rotd call ] 2curry ; inline
 257
 258 : prepose ( quot1 quot2 -- composed )
 259     swap compose ; inline
 260
 261 ! Curried cleavers
 262 <PRIVATE
 263
 264 : currier ( quot -- quot' ) [ curry ] curry ; inline
 265
 266 PRIVATE>
 267
 268 : bi-curry ( x p q -- p' q' ) [ currier ] bi@ bi ; inline
 269
 270 : tri-curry ( x p q r -- p' q' r' ) [ currier ] tri@ tri ; inline
 271
 272 : bi-curry* ( x y p q -- p' q' ) [ currier ] bi@ bi* ; inline
 273
 274 : tri-curry* ( x y z p q r -- p' q' r' ) [ currier ] tri@ tri* ; inline
 275
 276 : bi-curry@ ( x y q -- p' q' ) currier bi@ ; inline
 277
 278 : tri-curry@ ( x y z q -- p' q' r' ) currier tri@ ; inline
 279
 280 ! Booleans
 281 UNION: boolean POSTPONE: t POSTPONE: f ;
 282
 283 : >boolean ( obj -- ? ) [ t ] [ f ] if ; inline
 284
 285 : not ( obj -- ? ) [ f ] [ t ] if ; inline
 286
 287 : and ( obj1 obj2 -- ? ) over ? ; inline
 288
 289 : or ( obj1 obj2 -- ? ) dupd ? ; inline
 290
 291 : or* ( obj1 obj2 -- obj2/obj1 second? ) [ nip t ] [ f ] if* ; inline
 292
 293 : xor ( obj1 obj2 -- ? ) [ f swap ? ] when* ; inline
 294
 295 : both? ( x y quot -- ? ) bi@ and ; inline
 296
 297 : either? ( x y quot -- ? ) bi@ or ; inline
 298
 299 : most ( x y quot -- z ) 2keep ? ; inline
 300
 301 : negate ( quot -- quot' ) [ not ] compose ; inline
 302
 303 ! Loops
 304 : loop ( ... pred: ( ... -- ... ? ) -- ... )
 305     [ call ] keep [ loop ] curry when ; inline recursive
 306
 307 : do ( pred body -- pred body )
 308     dup 2dip ; inline
 309
 310 : while ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 311     swap do compose [ loop ] curry when ; inline
 312
 313 : while* ( ..a pred: ( ..a -- ..b ? ) body: ( ..b ? -- ..a ) -- ..b )
 314     [ [ dup ] compose ] dip while drop ; inline
 315
 316 : until ( ..a pred: ( ..a -- ..b ? ) body: ( ..b -- ..a ) -- ..b )
 317     [ negate ] dip while ; inline
 318
 319 ! Object protocol
 320 GENERIC: hashcode* ( depth obj -- code ) flushable
 321
 322 M: object hashcode* 2drop 0 ; inline
 323
 324 M: f hashcode* 2drop 31337 ; inline
 325
 326 : hashcode ( obj -- code ) 3 swap hashcode* ; inline
 327
 328 GENERIC: equal? ( obj1 obj2 -- ? )
 329
 330 M: object equal? 2drop f ; inline
 331
 332 TUPLE: identity-tuple ;
 333
 334 M: identity-tuple equal? 2drop f ; inline
 335
 336 : identity-hashcode ( obj -- code )
 337     dup tag 0 eq? [
 338         dup tag 1 eq? [ drop 0 ] [
 339             dup (identity-hashcode) dup 0 eq? [
 340                 drop dup compute-identity-hashcode
 341                 (identity-hashcode)
 342             ] [ nip ] if
 343         ] if
 344     ] unless ; inline
 345
 346 M: identity-tuple hashcode* nip identity-hashcode ; inline
 347
 348 : = ( obj1 obj2 -- ? )
 349     2dup eq? [ 2drop t ] [
 350         2dup both-fixnums? [ 2drop f ] [ equal? ] if
 351     ] if ; inline
 352
 353 : same? ( x y quot -- ? ) bi@ = ; inline
 354
 355 GENERIC: clone ( obj -- cloned )
 356
 357 M: object clone ; inline
 358
 359 M: callstack clone (clone) ; inline
 360
 361 ! Tuple construction
 362 GENERIC: new ( class -- tuple )
 363
 364 GENERIC: boa ( slots... class -- tuple )
 365
 366 ! Error handling -- defined early so that other files can
 367 ! throw errors before continuations are loaded
 368 GENERIC: throw ( error -- * )
 369
 370 ERROR: assert got expect ;
 371
 372 : assert= ( a b -- ) 2dup = [ 2drop ] [ assert ] if ;
 373
 374 <PRIVATE
 375
 376 : declare ( spec -- ) drop ;
 377
 378 : do-primitive ( number -- ) "Improper primitive call" throw ;
 379
 380 ! Special object count and identifiers must be kept in sync with:
 381 !   vm/objects.hpp
 382 CONSTANT: special-object-count 85
 383
 384 CONSTANT: OBJ-WALKER-HOOK 3
 385
 386 CONSTANT: OBJ-CALLCC-1 4
 387
 388 CONSTANT: ERROR-HANDLER-QUOT 5
 389
 390 CONSTANT: OBJ-CELL-SIZE 7
 391 CONSTANT: OBJ-CPU 8
 392 CONSTANT: OBJ-OS 9
 393
 394 CONSTANT: OBJ-ARGS 10
 395 CONSTANT: OBJ-STDIN 11
 396 CONSTANT: OBJ-STDOUT 12
 397
 398 CONSTANT: OBJ-IMAGE 13
 399 CONSTANT: OBJ-EXECUTABLE 14
 400
 401 CONSTANT: OBJ-EMBEDDED 15
 402 CONSTANT: OBJ-EVAL-CALLBACK 16
 403 CONSTANT: OBJ-YIELD-CALLBACK 17
 404 CONSTANT: OBJ-SLEEP-CALLBACK 18
 405
 406 CONSTANT: OBJ-STARTUP-QUOT 20
 407 CONSTANT: OBJ-GLOBAL 21
 408 CONSTANT: OBJ-SHUTDOWN-QUOT 22
 409
 410 CONSTANT: JIT-PROLOG 23
 411 CONSTANT: JIT-PRIMITIVE-WORD 24
 412 CONSTANT: JIT-PRIMITIVE 25
 413 CONSTANT: JIT-WORD-JUMP 26
 414 CONSTANT: JIT-WORD-CALL 27
 415 CONSTANT: JIT-IF-WORD 28
 416 CONSTANT: JIT-IF 29
 417 CONSTANT: JIT-SAFEPOINT 30
 418 CONSTANT: JIT-EPILOG 31
 419 CONSTANT: JIT-RETURN 32
 420 CONSTANT: JIT-UNUSED 33
 421 CONSTANT: JIT-PUSH-LITERAL 34
 422 CONSTANT: JIT-DIP-WORD 35
 423 CONSTANT: JIT-DIP 36
 424 CONSTANT: JIT-2DIP-WORD 37
 425 CONSTANT: JIT-2DIP 38
 426 CONSTANT: JIT-3DIP-WORD 39
 427 CONSTANT: JIT-3DIP 40
 428 CONSTANT: JIT-EXECUTE 41
 429 CONSTANT: JIT-DECLARE-WORD 42
 430
 431 CONSTANT: C-TO-FACTOR-WORD 43
 432 CONSTANT: LAZY-JIT-COMPILE-WORD 44
 433 CONSTANT: UNWIND-NATIVE-FRAMES-WORD 45
 434 CONSTANT: GET-FPU-STATE-WORD 46
 435 CONSTANT: SET-FPU-STATE-WORD 47
 436 CONSTANT: SIGNAL-HANDLER-WORD 48
 437 CONSTANT: LEAF-SIGNAL-HANDLER-WORD 49
 438 CONSTANT: WIN-EXCEPTION-HANDLER 50
 439
 440 CONSTANT: OBJ-SAMPLE-CALLSTACKS 51
 441
 442 CONSTANT: REDEFINITION-COUNTER 52
 443
 444 CONSTANT: CALLBACK-STUB 53
 445
 446 CONSTANT: PIC-LOAD 54
 447 CONSTANT: PIC-TAG 55
 448 CONSTANT: PIC-TUPLE 56
 449 CONSTANT: PIC-CHECK-TAG 57
 450 CONSTANT: PIC-CHECK-TUPLE 58
 451 CONSTANT: PIC-HIT 59
 452 CONSTANT: PIC-MISS-WORD 60
 453 CONSTANT: PIC-MISS-TAIL-WORD 61
 454
 455 CONSTANT: MEGA-LOOKUP 62
 456 CONSTANT: MEGA-LOOKUP-WORD 63
 457 CONSTANT: MEGA-MISS-WORD 64
 458
 459 CONSTANT: OBJ-UNDEFINED 65
 460
 461 CONSTANT: OBJ-STDERR 66
 462
 463 CONSTANT: OBJ-STAGE2 67
 464
 465 CONSTANT: OBJ-CURRENT-THREAD 68
 466
 467 CONSTANT: OBJ-THREADS 69
 468 CONSTANT: OBJ-RUN-QUEUE 70
 469 CONSTANT: OBJ-SLEEP-QUEUE 71
 470
 471 CONSTANT: OBJ-VM-COMPILER 72
 472
 473 CONSTANT: OBJ-WAITING-CALLBACKS 73
 474
 475 CONSTANT: OBJ-SIGNAL-PIPE 74
 476
 477 CONSTANT: OBJ-VM-COMPILE-TIME 75
 478
 479 CONSTANT: OBJ-VM-VERSION 76
 480 CONSTANT: OBJ-VM-GIT-LABEL 77
 481
 482 CONSTANT: OBJ-CANONICAL-TRUE 78
 483
 484 CONSTANT: OBJ-BIGNUM-ZERO 79
 485 CONSTANT: OBJ-BIGNUM-POS-ONE 80
 486 CONSTANT: OBJ-BIGNUM-NEG-ONE 81
 487
 488 ! Context object count and identifiers must be kept in sync with:
 489 !   vm/contexts.hpp
 490
 491 CONSTANT: context-object-count 4
 492
 493 CONSTANT: CONTEXT-OBJ-NAMESTACK 0
 494 CONSTANT: CONTEXT-OBJ-CATCHSTACK 1
 495 CONSTANT: CONTEXT-OBJ-CONTEXT 2
 496 CONSTANT: CONTEXT-OBJ-IN-CALLBACK-P 3
 497
 498 ! Runtime errors must be kept in sync with:
 499 !   basis/debugger/debugger.factor
 500 !   vm/errors.hpp
 501
 502 ! VM adds this to kernel errors, so that user-space can identify them.
 503 CONSTANT: KERNEL-ERROR 0xfac7
 504
 505 CONSTANT: kernel-error-count 20
 506
 507 CONSTANT: ERROR-EXPIRED 0
 508 CONSTANT: ERROR-IO      1
 509 CONSTANT: ERROR-NOT-IMPLEMENTED 2
 510 CONSTANT: ERROR-TYPE 3
 511 CONSTANT: ERROR-DIVIDE-BY-ZERO 4
 512 CONSTANT: ERROR-SIGNAL 5
 513 CONSTANT: ERROR-ARRAY-SIZE 6
 514 CONSTANT: ERROR-OUT-OF-FIXNUM-RANGE 7
 515 CONSTANT: ERROR-FFI 8
 516 CONSTANT: ERROR-UNDEFINED-SYMBOL 9
 517 CONSTANT: ERROR-DATASTACK-UNDERFLOW 10
 518 CONSTANT: ERROR-DATASTACK-OVERFLOW 11
 519 CONSTANT: ERROR-RETAINSTACK-UNDERFLOW 12
 520 CONSTANT: ERROR-RETAINSTACK-OVERFLOW 13
 521 CONSTANT: ERROR-CALLSTACK-UNDERFLOW 14
 522 CONSTANT: ERROR-CALLSTACK-OVERFLOW 15
 523 CONSTANT: ERROR-MEMORY 16
 524 CONSTANT: ERROR-FP-TRAP 17
 525 CONSTANT: ERROR-INTERRUPT 18
 526 CONSTANT: ERROR-CALLBACK-SPACE-OVERFLOW 19
 527
 528 PRIMITIVE: callstack-for ( context -- array )
 529 PRIMITIVE: retainstack-for ( context -- array )
 530 PRIMITIVE: datastack-for ( context -- array )
 531
 532 : context ( -- context )
 533     CONTEXT-OBJ-CONTEXT context-object ; inline
 534
 535 PRIVATE>
 536
 537 : get-callstack ( -- callstack )
 538     context callstack-for ; inline
 539
 540 : get-datastack ( -- array )
 541     context datastack-for ; inline
 542
 543 : get-retainstack ( -- array )
 544     context retainstack-for ; inline