core/locals/rewrite/sugar/sugar.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, Eduardo Cavazos.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes classes.tuple fry
   4 sequences.generalizations hashtables kernel locals locals.backend
   5 locals.errors locals.types make math quotations sequences vectors
   6 words ;
   7 IN: locals.rewrite.sugar
   8
   9 ! Step 1: rewrite [| into :> forms, turn
  10 ! literals with locals in them into code which constructs
  11 ! the literal after pushing locals on the stack
  12
  13 GENERIC: rewrite-sugar* ( obj -- )
  14
  15 : (rewrite-sugar) ( form -- form' )
  16     [ rewrite-sugar* ] [ ] make ;
  17
  18 GENERIC: quotation-rewrite ( form -- form' )
  19
  20 M: callable quotation-rewrite [ [ rewrite-sugar* ] each ] [ ] make ;
  21
  22 : var-defs ( vars -- defs )
  23     [ [ ] ] [ <multi-def> 1quotation ] if-empty ;
  24
  25 M: lambda quotation-rewrite
  26     [ body>> ] [ vars>> var-defs ] bi prepend quotation-rewrite ;
  27
  28 M: callable rewrite-sugar* quotation-rewrite , ;
  29
  30 M: lambda rewrite-sugar* quotation-rewrite , ;
  31
  32 GENERIC: rewrite-literal? ( obj -- ? )
  33
  34 M: special rewrite-literal? drop t ;
  35
  36 M: array rewrite-literal? [ rewrite-literal? ] any? ;
  37
  38 M: quotation rewrite-literal? [ rewrite-literal? ] any? ;
  39
  40 M: vector rewrite-literal? [ rewrite-literal? ] any? ;
  41
  42 M: wrapper rewrite-literal? wrapped>> rewrite-literal? ;
  43
  44 M: hashtable rewrite-literal? >alist rewrite-literal? ;
  45
  46 M: tuple rewrite-literal? tuple>array rewrite-literal? ;
  47
  48 M: object rewrite-literal? drop f ;
  49
  50 GENERIC: rewrite-element ( obj -- )
  51
  52 : rewrite-elements ( seq -- )
  53     [ rewrite-element ] each ;
  54
  55 : rewrite-sequence ( seq -- )
  56     [ rewrite-elements ] [ length ] [ 0 head ] tri '[ _ _ nsequence ] % ;
  57
  58 M: array rewrite-element
  59     dup rewrite-literal? [ rewrite-sequence ] [ , ] if ;
  60
  61 M: vector rewrite-element
  62     dup rewrite-literal? [ rewrite-sequence ] [ , ] if ;
  63
  64 M: hashtable rewrite-element
  65     dup rewrite-literal? [ >alist rewrite-sequence \ >hashtable , ] [ , ] if ;
  66
  67 M: tuple rewrite-element
  68     dup rewrite-literal? [
  69         [ tuple-slots rewrite-elements ] [ class-of ] bi '[ _ boa ] %
  70     ] [ , ] if ;
  71
  72 M: quotation rewrite-element rewrite-sugar* ;
  73
  74 M: lambda rewrite-element rewrite-sugar* ;
  75
  76 M: let rewrite-element let-form-in-literal-error ;
  77
  78 M: local rewrite-element , ;
  79
  80 M: local-reader rewrite-element , ;
  81
  82 M: local-writer rewrite-element
  83     local-writer-in-literal-error ;
  84
  85 M: word rewrite-element <wrapper> , ;
  86
  87 : rewrite-wrapper ( wrapper -- )
  88     dup rewrite-literal? [ wrapped>> rewrite-element ] [ , ] if ;
  89
  90 M: wrapper rewrite-element
  91     rewrite-wrapper \ <wrapper> , ;
  92
  93 M: object rewrite-element , ;
  94
  95 M: array rewrite-sugar* rewrite-element ;
  96
  97 M: vector rewrite-sugar* rewrite-element ;
  98
  99 M: tuple rewrite-sugar* rewrite-element ;
 100
 101 M: multi-def rewrite-sugar* , ;
 102
 103 M: hashtable rewrite-sugar* rewrite-element ;
 104
 105 M: wrapper rewrite-sugar*
 106     rewrite-wrapper ;
 107
 108 M: word rewrite-sugar*
 109     dup { load-locals get-local drop-locals } member-eq?
 110     [ >r/r>-in-lambda-error ] [ call-next-method ] if ;
 111
 112 M: object rewrite-sugar* , ;
 113
 114 M: let rewrite-sugar*
 115     body>> quotation-rewrite % ;