core/math/floats/floats.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math math.private math.order ;
   4 IN: math.floats.private
   5
   6 : float-unordered? ( x y -- ? ) [ fp-nan? ] bi@ or ;
   7 : float-min ( x y -- z ) [ float< ] most ; foldable
   8 : float-max ( x y -- z ) [ float> ] most ; foldable
   9
  10 M: fixnum >float fixnum>float ; inline
  11 M: bignum >float bignum>float ; inline
  12
  13 M: float >fixnum float>fixnum ; inline
  14 M: float >bignum float>bignum ; inline
  15 M: float >float ; inline
  16
  17 M: float hashcode* nip float>bits ; inline
  18 M: float equal? over float? [ float= ] [ 2drop f ] if ; inline
  19 M: float number= float= ; inline
  20
  21 M: float <  float< ; inline
  22 M: float <= float<= ; inline
  23 M: float >  float> ; inline
  24 M: float >= float>= ; inline
  25
  26 M: float unordered? float-unordered? ; inline
  27 M: float u<  float-u< ; inline
  28 M: float u<= float-u<= ; inline
  29 M: float u>  float-u> ; inline
  30 M: float u>= float-u>= ; inline
  31
  32 M: float min over float? [ float-min ] [ call-next-method ] if ; inline
  33 M: float max over float? [ float-max ] [ call-next-method ] if ; inline
  34
  35 M: float + float+ ; inline
  36 M: float - float- ; inline
  37 M: float * float* ; inline
  38 M: float / float/f ; inline
  39 M: float /f float/f ; inline
  40 M: float /i float/f >integer ; inline
  41 M: float mod float-mod ; inline
  42
  43 M: real abs dup 0 < [ neg ] when ; inline
  44
  45 M: float fp-special?
  46     double>bits -52 shift HEX: 7ff [ bitand ] keep = ; inline
  47
  48 M: float fp-nan-payload
  49     double>bits 52 2^ 1 - bitand ; inline
  50
  51 M: float fp-nan?
  52     dup float= not ;
  53
  54 M: float fp-qnan?
  55     dup fp-nan? [ fp-nan-payload 51 2^ bitand zero? not ] [ drop f ] if ; inline
  56
  57 M: float fp-snan?
  58     dup fp-nan? [ fp-nan-payload 51 2^ bitand zero? ] [ drop f ] if ; inline
  59
  60 M: float fp-infinity?
  61     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ; inline
  62
  63 M: float next-float
  64     double>bits
  65     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
  66         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
  67             1 + bits>double ! positive
  68         ] if
  69     ] if ; inline
  70
  71 M: float prev-float
  72     double>bits
  73     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
  74         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
  75             1 - bits>double ! positive non-zero
  76         ] if
  77     ] if ; inline
  78
  79 M: float fp-sign double>bits 63 bit? ; inline
  80
  81 M: float abs double>bits 63 2^ bitnot bitand bits>double ; inline