core/math/floats/floats.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math math.private ;
   4 IN: math.floats.private
   5
   6 : float-min ( x y -- z ) [ float< ] most ; foldable
   7 : float-max ( x y -- z ) [ float> ] most ; foldable
   8
   9 M: fixnum >float fixnum>float ; inline
  10 M: bignum >float bignum>float ; inline
  11
  12 M: float >fixnum float>fixnum ; inline
  13 M: float >bignum float>bignum ; inline
  14 M: float >float ; inline
  15
  16 M: float hashcode* nip float>bits ; inline
  17 M: float equal? over float? [ float= ] [ 2drop f ] if ; inline
  18 M: float number= float= ; inline
  19
  20 M: float < float< ; inline
  21 M: float <= float<= ; inline
  22 M: float > float> ; inline
  23 M: float >= float>= ; inline
  24
  25 M: float + float+ ; inline
  26 M: float - float- ; inline
  27 M: float * float* ; inline
  28 M: float / float/f ; inline
  29 M: float /f float/f ; inline
  30 M: float /i float/f >integer ; inline
  31 M: float mod float-mod ; inline
  32
  33 M: real abs dup 0 < [ neg ] when ; inline
  34
  35 M: float fp-special?
  36     double>bits -52 shift HEX: 7ff [ bitand ] keep = ; inline
  37
  38 M: float fp-nan-payload
  39     double>bits 52 2^ 1 - bitand ; inline
  40
  41 M: float fp-nan?
  42     dup float= not ;
  43
  44 M: float fp-qnan?
  45     dup fp-nan? [ fp-nan-payload 51 2^ bitand zero? not ] [ drop f ] if ; inline
  46
  47 M: float fp-snan?
  48     dup fp-nan? [ fp-nan-payload 51 2^ bitand zero? ] [ drop f ] if ; inline
  49
  50 M: float fp-infinity?
  51     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ; inline
  52
  53 M: float next-float ( m -- n )
  54     double>bits
  55     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
  56         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
  57             1 + bits>double ! positive
  58         ] if
  59     ] if ; inline
  60
  61 M: float unordered? [ fp-nan? ] bi@ or ; inline
  62
  63 M: float prev-float ( m -- n )
  64     double>bits
  65     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
  66         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
  67             1 - bits>double ! positive non-zero
  68         ] if
  69     ] if ; inline